The APL Orchard

« first day (2585 days earlier) ← previous day next day → last day (64 days later) »

12:01 AM

@Adám, next Dyalog apl will support Vision Pro, first language support spatial computation, all you need just finger to input apl symbols,

Marshall

12:16 AM

Got the historical comparison table together. Easier than I expected since the infoboxes are more complete here.

11 hours later…

Adám

10:56 AM

@Richard Maybe someone else can run a weekly event, tackling e.g. LeetCode problems.

2 hours later…

Adám

1:00 PM

Welcome to APL Quest, 2023-8! Today's quest is Critical Thinking:

> Double critical days can be calculated respectively using multiples of:

      23 23 28∧⍥(÷∘2)28 33 33
322 379.5 462

> The dreaded “triple critical day” only occurs every (∧/23 28 33÷2) or 10,626 days.

> Write a function that:
• takes a 3-element integer left argument representing a valid birthdate
• takes a 3-element integer right argument representing a valid date occurring on or after the left argument
• returns a 3-element integer array representing the date of the next double or triple critical day occurring on or after the date represented by the right argument.

Interestingly, the info about the triple critical day is actually a red herring. Any triple critical day is of course also a double critical day, so we just need to find the next double critical day.

RubenVerg

for the contest I had (3∘↑⍤⊃¯1∘⎕dt)(⌊/⊢+322 379.5 462∘|⍤-)⍥(1⎕dt⊂)

Adám

> Note: All the dates in this specification are to be in the form year month day

And we also have this competition entry:

19 hours ago, by Richard

{d←1⎕DT⍺⍵ ⋄ m←322 379.5 462 ⋄ 3↑⊃¯1⎕DT ⌊/d[1]+m×⌈m÷⍨--/d}

RubenVerg

I remember I didn't really like this problem since all the ⎕dt stuff makes parsing & serializing about as long as the actual core of the solution

I assume there's no other way to do the parsing and formatting?

Adám

Not really.

We can, however, move parts around a little in your solution to shorten it overall.

rabbitgrowth

I had (3↑∘⊃¯1⎕DT⊣+322 379.5 462(⌊/⊣×∘⌈÷⍨)-⍨)⍥(1⎕DT⊂), which looks like basically the same thing as Richard's

Adám

1:09 PM

But again can be shortened/simplified a bit.

(3∘↑⍤⊃¯1∘⎕dt)(⌊/⊢+322 379.5 462∘|⍤-)⍥(1⎕dt⊂)
(3∘↑⍤⊃¯1∘⎕dt)(⌊/⊢+322 379.5 462|-)⍥(1⎕dt⊂)
(3∘↑⍤⊃¯1∘⎕dt)(⊢+322 379.5 462(⌊/|)-)⍥(1⎕dt⊂)
(3∘↑⍤⊃¯1∘⎕dt)(⊢+322 379.5 462⌊.|-)⍥(1⎕dt⊂)
(3∘↑)(⊃¯1⎕dt⊢+322 379.5 462⌊.|-)⍥(1⎕dt⊂)
3↑(⊃¯1⎕dt⊢+322 379.5 462⌊.|-)⍥(1⎕dt⊂)

RubenVerg

right, of course it's a .!

Adám

@rabbitgrowth Do you want the progress to the same solution too?

RubenVerg

should've taken the time to work on this a bit more instead of just giving the sol i had for the contest

rabbitgrowth

Oh I see how the | works with the negative number now, that's pretty nice

@Adám You mean the step-by-step simplification?

Adám

Yes.

rabbitgrowth