@Adám Very nice one, thanks!

> Write a function that, given a right argument which is a character scalar or non-empty vector representing a valid character Excel column identifier between A and XFD, returns the corresponding column number.

{26⊥64-⍨⎕UCS ⍵}

Heh, what if I told you you can make that much shorter?

Nothing to do with this task, btw, just your 64-⍨⎕UCS

26⊥⎕A∘⍳ ?

Yes, indeed.

Or {26⊥⎕A⍳⍵} if you want a dfn.

:)

This one is fun: ⎕A(≢⍤⊣⊥⍳)⊢

As brief as this is, the inverse is non-trivial.

We can leave that as a challenge to the underwhelmed.

Another thing that may be interesting is implementing it without ⊥

⎕UCS 64+{26⊥⍣¯1⊢⍵}

Haha. Nope.

E.g. on 26 it'll give A@

@Adám {i+.×26*¯1+⌽⍳≢i←⎕A⍳⍵} simply implements ⊥ for vectors

The inverse will take significantly more code. Probably at least 5 times as much code, so I think we should call it for this week.

@Adám ⎕A∘dfns.adic :P

Yup.

(26⊥⎕A∘⍳)⍣¯1 also fails on 26 etc. but I'm impressed it works at all

Yes, ⍳⍣¯1 is fun. So too ⌷⍣¯1

Anyway, see you next week for 2020-4: Take a Leap!

Any good example for ⌷⍣¯1 ?

The inverse is fairly trivial of you generate all the possible column names, there are not that many. You can also then use that for the original problem. Bonus is that this technique works for array input directly. In a a production system you can precompute the column names, and if done, I think that might be the fastest solution.

I have {⍵<1:''⋄(∇⌊⍵÷26),⎕ucs 65+26|⍵-1} for the inverse

I guess an alternative way is with computing the three letters separately (assuming the same bounds) and then use /

{⍵<1:'' ⋄ (∇⌊⍵÷26),⎕UCS 65+26|⍵-1}¨24 25 26 27

X  Y  AZ  AA

I was thinking why the upper limit to input is 'XFD'

'27*3' is far less than a signed integer

Oh so in Excel that's the upper limit

Which is '2*14' btw

@RubenVerg It gets tricky every 26

@PaulMansour wat

I thought I tested it

okay this works

 {⍵<1:''⋄(∇¯1+⌈⍵÷26),⎕ucs 65+26|⍵-1}

@RubenVerg Nice.

@LdBeth 27*3? 26=≢⎕A