The APL Orchard

12:07 AM

I've been messing around trying to make some python generator expressions and this doesn't work:
({x←⍵*3}⍣{20<x}⍬)⍳5
the intended output is:
0 1 8

i do have some working code though but close your eyes:

 num_list←⍳5
 output←⍬
 :For x :In num_list
     :If 20<y←cube x ⋄ :Leave ⋄ :EndIf
     output,←y
 :EndFor
 output

oh and sorry, cube function is simply:
cube←3*⍨⊢

Adám

7:58 AM

@BrianBED I don't even see how your dfn-based solution is supposed to work.

RikedyP

9:21 AM

@BrianBED ⎕←{cubed⌿⍨20>cubed←⍵*⍳5}¯1+⍳5

TryAPL

@RikedyP 0 1 8

Brian BED

12:33 PM

@Adám i tried very hard :(

⍣ confuses me a lot

@RikedyP thank you so much you are a guinius :D

imma analize it

dzaima

@RikedyP that ⍵*⍳5 should be just ⍵*3

Fawn Locke

⎕← ⌿⍨∘(20∘>)⍨3*⍨¯1+⍳5

TryAPL

@FawnLocke 0 1 8

Fawn Locke

uh

Ah

Adám

@RikedyP @BrianBED But this is very different. It generates all possibilities and filters, rather than generating just enough.

Brian BED

12:44 PM

ah true

yea i noticed it after a bit

he did get it smaller than my version though ¯\_(ツ)_/¯

Adám

@FawnLocke I want back-compose: 20∘>⍛⌿⍨3*⍨¯1+⍳5

Fawn Locke

Yeah

Brian BED

ah you guys are wizards. so is there no way of using ⍣ as a generator expression?

dzaima

not very pretty ways at least

i have x←⍬ ⋄ {x,←⍵*3 ⋄ 1+⍵}⍣{20<⍺*3}0 ⋄ x

Brian BED

num_list = [0,1,2,3,4]
[cube(x) for x in num_list if cube(x)<20]

the reason i'm doing this is im talking to a python programmer and he gave me this expresion to translate for fun. actually not arguing this time just him looking at the language and i was actually not able to translate it to a smaller expresion without using all the ifs and fors

@dzaima oooo ill have a look

dzaima

12:49 PM

@BrianBED that's precisely the replicate solution

Brian BED

wait oh i took wrong snippet

one second

num_list = [0,1,2,3,4]
[y for x in num_list if (y:= cube(x))<20]

this is the one sorry

dzaima

that's still the replicate solution

Brian BED

god wait it is? well like, as far as i was told, like im not a python programmer but this apparently stops after the first false value of the if statement... badly explained but yea

dzaima

if num_list was [0,8,1,9,2,10, 1], you'd get a result of 0 1 2 1*3, but short-circuiting with ⍣ would stop at the 8

@BrianBED TIO - it does not stop at the first false value

Brian BED

I need a chat with my friend lol

thanks for all the help

Fawn Locke

12:54 PM

@Adám What do you suggest for monadic ⍛, I had (F y) G y as the sensible option, meaning you could remove that ⍨ too.

Adám

@FawnLocke Ah, yes, that.

Fawn Locke

Ah okay

Brian BED

he said this in one message. flew by me but is probably important in this::
"
Actually, sorry! That is the case for a generator expression if we assumed the elements were sorted...which they might not be
But it is more efficient still as you iterate over the list once, not twice as you would using filter."

dzaima

@FawnLocke it's a very sensible & nice & useful option, it just has the drawback that there's no x F (G x) on monadic ∘ to behave equally to

Fawn Locke

Yeah

Adám

12:56 PM

@FawnLocke What do you suggest for array operands of ⍛? I have default value. E.g. 2(1⍛+)10 gives 12 while 1⍛+10 gives 11.

dzaima

@BrianBED in APL, iterating twice is much less of a concern than in Python

Brian BED

oh why?

Adám

@dzaima But that's just one ⍨ away: F∘G⍨

PyGamer0

@BrianBED its APL /s

Fawn Locke

@Adám I hadn't thought too hard about that, but that's really nice !

dzaima

12:58 PM

@BrianBED there's no horribly slow python interpreter to take 95% of the time, leaving only 5% for the actual operation you're doing

@Adám but so is F⍛G⍨

Brian BED

@dzaima ahhhhh i see... that sounds very fair

@PyGamer0 i can't keep having "apl does magic" as an excuse lmao

PyGamer0

@dzaima i have heard that python is slower than JS

Brian BED

way slower

Adám

@dzaima True, but what could F⍛G y be? G y?

PyGamer0

@BrianBED why?

does JS do magic?

i should try learning it...

Brian BED

1:00 PM

i mean... just iterating through a loop in js is like... 50 times faster

dzaima

@dzaima even 1+2+⍳10 is iterating over ⍳10 twice (three times if you count the initial creation of ⍳10). Nearly every sequence of operations (except idioms) just has a separate loop for each operation

Brian BED

@PyGamer0 sure. i dont like the language per se, but its very useful and in demand

Razetime

js has a lot more money behind its improvement and optimization. some hardcore jitting

Brian BED

true

dzaima

@PyGamer0 JS at least tries to be fast. (pypy or whatnot also does, but i don't know to what level)

Fawn Locke

1:02 PM

I don't think there's much F⍛G y could be that isn't just a ⍨ away. Maybe it should be G F y to match Dyalog's ∘

dzaima

@Adám I'm not saying F⍛G y shouldn't be (F y) G y. It's definitely the best option

G F y would be useful for saving parentheses i guess, but besides that it'd just be confusing

PyGamer0

@dzaima there are plans to speed up cpython ...

dzaima

@PyGamer0 huh.

Fawn Locke

I suppose monadic over could've been G F y, nicer than another atop at least

Richard

1:19 PM

@Adám "let's make it worse!" Nice promise/quote in your last video of the APL Quest :) Had fun watching it.

Brian BED

1:33 PM

is it worth using array operators in python? like so far i haven't but i'm tempted to try using some APL inspired code, but i wanna ask first because if it isn't worthit then i won't bother

Marshall

1:45 PM

If the monadic ⍛ puts its argument on both sides, you could finally do sensible tacit filtering with 10∘<⍛/.

Fawn Locke

Good point

PyGamer0

@BrianBED example?

Adám

@FawnLocke Nah, that'd break the pattern that Over pre-processes all argument using G

Fawn Locke

mmm

Fair enough, it only tackles the "issue" of complex right operands needing brackets anyway.

Marshall

I use ambivalent Over all the time. I think it's better to design a combinator as a single thing on a variable number of arguments when possible.

Fawn Locke

1:58 PM

Why not (G y) F (G y) then

Brian BED

@PyGamer0 using sum(), all(), functools.reduce(), array calculation stuff involving numpy, that kind of stuff

PyGamer0

@BrianBED i use them, but people consider them "unreadable"

(i dont use numpy though)

Brian BED

yea, I can't understand lamda expresions whatsoever in python

and they are super neat

well... look super neat... idk them yet

PyGamer0

@BrianBED lambdas are nameless functions

i also made a super slow library for python: pyhof

Adám

@FawnLocke Again prevents ambivalent functions from working.

Fawn Locke

2:08 PM

Ohhhh, I see now

Brian BED

@PyGamer0 what does it do?

dzaima

@BrianBED lambda x,y: x+y*y is like {⍺+⍵×⍵}, just the names of arguments are explicit (and you can have arbitrarily many of them)

Brian BED

ahh thats a great example

Fawn Locke

@Adám Maybe in Dyalog's case G F y as monadic before makes sense then. Keeps it symmetrical and consistent

Hmm, or not. It's kinda an outliner, Best to stick to the obviously useful form

Brian BED

@dzaima wait how do i define x and y?

Fawn Locke

2:22 PM

x,y: is the definition

PyGamer0

@BrianBED wdym

Brian BED

wait oh... wait so you can't use them in the same line? like do you have to have a name to the lamda function?

PyGamer0

lambda arg1, arg2, arg_with_default=None:...

@BrianBED you can do (lambda x:x+1)(2)

Brian BED

ahhhh ok thats what i was looking for

dzaima

@BrianBED you can invoke it like (lambda x,y: x+y*y)(4,10)

it's just a regular function

just defined in a single line, instead of multiple

Brian BED

2:25 PM

right makes sense. i did that but i forgot the first parens around the lamda

PyGamer0

@BrianBED dzaima.github.io/…

Brian BED

yaya

OOOo i'm gonna use lamdas a lot

i also did this and amazingly i get no syntax error:
print((lambda x=1: x+x)(2))
4

Fawn Locke

lambda x, y: x + y - 1 is 1-⍨+ in APL :)

Brian BED

like because i did x=1 i would expect an error but yea

@FawnLocke nothing beats apl :D

dzaima

that sets a default argument, so if you invoked it with (lambda x=1: x+x)() you'd get 1+1

Brian BED

2:28 PM

ahhhhhh!

awesome

in my head now it makes a lot of sense because thats the usual way of setting defaul value for a function

Adám

The APL Orchard has become the The Python Terrarium…

Fawn Locke

Lol

Brian BED

well i appreciate the help :)

PyGamer0

@Adám lmao

PyGamer0

2:50 PM

apl quest in 10 mins

Brian BED

OOoo

@dzaima {⍺,(3*⍨⍵)}⍣5⍨2 this almost works. the problem with starting out with 2 is that well... it starts off with 2... so i did this version but it doesn't work:

{⍺,(3*⍨{⍵≡1:1+⍵ ⋄ ⍵}⍵)}⍣5⍨1

i tried making it incriment by one if its 1 just to get it looping... didn't work

{⍺,(3*⍨1+⍵)}⍣5⍨1

this explodes

there has to be some way of doing this... ill keep working on it

dzaima

@BrianBED F⍣5⍨ 1 will do 1 F 1 F 1 F 1 F 1 F 1

Brian BED

yes exactly. i can make it work with enough if statements

:D

i think

dzaima

the problem is that you're still iterating over only ⍵; ⍺ is always 1 (or 2 in the case of the first expression)

Brian BED

but the output changes across... oh wait only in the second expression... right right i see

dzaima

2:58 PM

but you want to iterate two variables - the counter, and the result array

so {⍺,(3*⍨⍵)}⍣5⍨2 is f←{2,⍵*3} ⋄ f f f f f 2

RikedyP

@Adám but the expression of the question is to do that: for integers up to 5, if its cube is less than 20, keep, else throw away. I'm sorry idiomatic APL is to do it this way

Adám

Welcome to the APL Quest! This weeks quest is Home On The Range:

> Write a dfn which returns the magnitude of the range (i.e. the difference between the lowest and highest values) of a numeric array.

Brian BED

@dzaima this is true... can i use ⍺ to iterate?

Adám

This should be fairly simple, except maybe for the empty array case. Any contenders?

Brian BED

yes gimme a min

dzaima

3:01 PM

@BrianBED no. ⍺ never changes during ⍣

Richard

{(⌈/,⍵)-⌊/,⍵}

Kamila Szewczyk

the obvious: {(⌈/-⌊/),⍵}

works for everything except ⍳0 as expected

Adám

;-)

Brian BED

@dzaima awww

Adám

@KamilaSzewczyk Wonder why you wrapped that in {…⍵} — because it asks for a dfn?

Kamila Szewczyk

3:02 PM

yeah

Richard

but why is ⌊/⍬ not ⍬

Kamila Szewczyk

because reduction identity element

Adám

@KamilaSzewczyk We're not strict about it for Quests. APL trains weren't a thing in 2013.

Richard

@KamilaSzewczyk ?

Adám

@Richard Shouldn't the sum of an empty list be 0?

Richard

3:03 PM

I should think also ⍬

Kamila Szewczyk

@Richard from a functional programming perspective, when you have a fold over array A, it returns the same value as the fold over array id(f) : A if f is a monoid

Brian BED

⌊/⍬
1.797693135E308

im sorry... what...

Kamila Szewczyk

in simple words: if you append the identity value to the array, you ideally get the same result as if you didn't

Fawn Locke

@BrianBED It's just an arbitrary way to get infinity. /shrug

dzaima

@Richard that'd be the only case when the minimum of a numeric array isn't a number, which'd be very weird

Brian BED

3:04 PM

ahhh

Adám

@BrianBED Maximum representable value. The only value which would preserve the other argument when used with ⌊

Kamila Szewczyk

it's not really arbitrary

Richard

ok thanks

PyGamer0

@Adám my answer: (⌈/⌈⌿)-(⌊/⌊⌿)

Adám

Another way to say it is that an identity value I is such that X ≡ I f X and/or X ≡ X f I for any array X.

Kamila Szewczyk

3:05 PM

seems needlessly complicated, and fails for ⍳0.

Adám

@PyGamer0 Fails on rank-3 arrays.

PyGamer0

i know "_"

but passed the cases on the problems.tryapl

Adám

@PyGamer0 You could do ⌈/⍣≡-⌊/⍣≡ to handle all ranks.

@PyGamer0 Huh, then the reference solution might be wrong.

PyGamer0

hm does that apply ⌈/ repeatedly until the depth is 0?

Kamila Szewczyk

@Adám i considered it but , seemed simpler

Adám

3:07 PM

@PyGamer0 Well, until no more changes.

@KamilaSzewczyk Sure. ⍣≡ might be faster though, for large high-rank arrays.

Kamila Szewczyk

it's tempting to check it

Adám

Go for it.

RikedyP

so the failure on ⍬ comes from going out of range of ⎕FR 645?

Kamila Szewczyk

shouldn't monadic , be very fast since it just queries the underlying ravel?

Adám

@KamilaSzewczyk It has to copy the array.

So it is only fast when done in-place, i.e. when ref-count is 1.

Kamila Szewczyk

3:10 PM

doesn't the ⍣≡ solution require copying the array too

Adám

OK, so the reference solution is… suboptimal.

@KamilaSzewczyk No, how so?

dzaima

@KamilaSzewczyk it creates a new array, but that new array may (or may not) be smaller than the argument

whereas for , the argument and result are always the same size

Adám

      a←?(6⍴10)⍴0
      ]runtime -c +/,a +/⍣≡a

  +/,a  → 2.6E¯3 |   0% ⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕
  +/⍣≡a → 5.7E¯4 | -78% ⎕⎕⎕⎕⎕⎕⎕⎕⎕

Brian BED

@Adám what should empty return?

RikedyP

⎕←{0::{rng←(⌊/,⌈/)⍵ ⋄ ⎕FR←1287 ⋄ -/rng}⍵ ⋄ (⌈/-⌊/)⍵}⍬

Adám

3:11 PM

@BrianBED 0

RikedyP

curious

TryAPL

@RikedyP 3.59538627E308

Brian BED

@Adám alr cool

Kamila Szewczyk

      v←,8 23 3 10 7 2⍴70000⍴1000
      cmpx 'f1 v' 'f2 v'
  f1 v → 2.8E¯6 |  0% ⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕
  f2 v → 2.6E¯6 | -7% ⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕
      f1
  ⌈/ ⍣≡ -  ⌊/ ⍣≡
      f2
  ⌈/ - ⌊/  ,

as expected

dzaima

@Adám counter-comparison

Adám

3:12 PM

Uh, v is a vector.

Kamila Szewczyk

oh wait oops stray comma

Adám

@dzaima Right, because you force a full copy.

Kamila Szewczyk

      v←8 23 3 10 7 2⍴?70000⍴1000
      cmpx 'f1 v' 'f2 v'
  f1 v → 1.9E¯4 |   0% ⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕
  f2 v → 7.8E¯6 | -96% ⎕⎕

okay, now that's more like it

Adám

@KamilaSzewczyk (Why 70000⍴?)

Kamila Szewczyk

because it's approximately ×/8 23 3 10 7 2

i wanted to fill the array with random data

rak1507

3:14 PM

⌈/⍣≡,∘.-,

Brian BED

{⍵≡⍬:0⋄(⌈/-⌊/),⍵}

now maybe wierd... but works?

dzaima

@KamilaSzewczyk well you forgot the ?

Adám

Seems that +/, is faster for integers, and +/⍣≡ is faster for floats, unless the shape is adversarial.

rak1507

wait, my solution gives the wrong thing for empties, but the site doesn't check that?

Kamila Szewczyk

i'm being sloppy today

RikedyP

3:15 PM

@BrianBED honestly not sure there's a better encoding

Kamila Szewczyk

but i'm right

Adám

@BrianBED That's sensible enough.

Kamila Szewczyk

      v←8 23 3 10 7 2⍴.5×?70000⍴1000
      cmpx 'f1 v' 'f2 v'
  f1 v → 1.8E¯4 |   0% ⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕
  f2 v → 4.3E¯5 | -76% ⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕

if we create some floats here and there they get a bit closer

i tried .33333×, etc... and the results are similar

Adám

@KamilaSzewczyk They are all floats there.

Kamila Szewczyk

are they?

maybe according to internal representation.

Adám

3:17 PM

If any element of a flat array is a float, all are.

Kamila Szewczyk

anyway the ravel is faster as expected

rak1507

⌈/⍣≡0,0⍪,∘.-, :/ not great

Brian BED

my python friend's participating:
f = lambda x: (max(x)-min(x)) if x else 0

Adám

@rak1507 Yay, O(n²)

rak1507

yep lol

Adám

3:19 PM

The reference solution isn't actually bad, but someone forgot to use ⍬ (or any other empty array) as test case. Oops. Will fix.

PyGamer0

@BrianBED ato.pxeger.com/…

Adám

My take on it: (⊢/-⊣/){⍵[⍋⍵]}⍤,

PyGamer0

did you just sort the array o_o

Adám

Wait, I have an idea!

Brian BED

@PyGamer0 true true, i forgot it also applies to python

Adám

3:21 PM

((⌈/-⌊/)⊢↑⍨1⌈≢),

PyGamer0

@Adám would this work? (⊃⍤⌽-⊃){⍵[⍋⍵]}⍤,

Adám

@PyGamer0 D'uh, that works. Mine doesn't.

Alternative: (⌈/-⌊/)⊢⍴⍨1⌈×/⍤⍴

BrianBED's {⍵≡⍬:0⋄(⌈/-⌊/),⍵} is clearer, though.

dzaima

{⎕div←1 ⋄ (+/÷≢)((⌈/=⊢)⊢⍤/⊢),∘.-⍨⍵}

Adám

Another O(n²).

Brian BED

{⍵≡⍬:0 ⋄ (⌈/-⌊/)∊⍵}2 2⍴1 2 (3 4)
i use ∊ instead of ",". that makes sense right or na?

Adám

3:24 PM

That would make it work on nested arrays, so yes.

Brian BED

great yea thought it was good

Adám

(⌈/-⌊/),,0/⍨0∊⍴

ovs

A slightly worse sorting based one:

+/2-⍨/{⍵[⍋⍵]}⍤,

Adám

(⌈/-⌊/),,0∩⍴

Richard

:)

Adám

3:27 PM

@ovs Ugh.

dzaima

@Adám hm, it's possible to utilize ⎕div←1 without being O(n^2): {⎕DIV←1 ⋄ o←{(⍵=⍺⍺/⍵)/⍵} ⋄ (+/÷≢) (⌈o - ⌊o) ,⍵}

ovs

It fails for empty arrays though

Adám

@ovs Can be shortened to +/2-/{⍵[⍒⍵]}⍤,

@dzaima Oh, good point; the avg is always within the range.

((⌈/-⌊/)⊢,+/÷≢),

PyGamer0

k: {(|/x)-(&/x)} ... i think this is semi valid (as in passes some cases)

Adám

Fails on high-rank (i.e. for K, nested) arguments.

PyGamer0

3:30 PM

wait {(|/,x)-(&/,x)}

does that work

Adám

@PyGamer0 Monadic , is like ,⊂ in APL. You want ,// I think.

PyGamer0

yeah

array languages are neat

Adám

@PyGamer0 What does it give on the empty list? 2?

Any other solutions?

Brian BED

i wanna do a funny one but i can't think of one

ovs

Does 0 = f ⍬ really makes sense? The empty set has no minimum/maximum, and if we consider infimum/supremum the difference should be -∞.

Richard

3:36 PM

I also used outer product ∘.> - ∘.<
But is just cumbersome

Adám

@ovs No it doesn't, but that's what the customer wants, so ¯\_(⍨)_/¯

Brian BED

very random question. is monadic ∊ a recursive operator?

Adám

It is a function.

Brian BED

the reason i ask is because my python friend can't replicate it on lists without recursion

Adám

@BrianBED And while it could be implemented recursively, I think it just traverses the array.

Brian BED

3:38 PM

like.... best he has is like 5 lines to flaten a nested list

@Adám ah alright

Fawn Locke

Depth-first search in APL

►

Richard

Out of suggestions...

Adám

Monadic ∊ is almost equivalent to {r←⍬ ⋄ r⊣{0=≡⍵:r,←⍵ ⋄ ∇¨⍵}⍵}

OK, I think that's enough for this week then. See you next week for Float Your Boat!

Richard

I'm probably not able to join next week. If I constructed something genius I'll let you know before ;)

PyGamer0

4:03 PM

f 0N     / @Adám
0

wait 0N is integer null

returns: (,{(|/,//x)-(&/,//x)})!,0 ...

Brian BED

5:21 PM

@Adám can you explain to me why there are 2 commas there?

((⌈/-⌊/)∊,0∩⍴)
solves nesting

Brian BED

5:34 PM

i don't understand why ∊ is infront of the comma not behind though

or well... behind wouldn't make sense either

Fawn Locke

6:10 PM

{⍺⊃⍛⊃∘(-/@⍺)⍵}⍨∘((⊢/,⊣/)⍋)⍨,

another sorting solution

(⊢/,⊣/)⍤⍋⍛{⍺⊃⍛⊃∘(-/@⍺)⍵},

even

Transcript for