The APL Orchard

« first day (1660 days earlier) ← previous day next day → last day (1294 days later) »

PyGamer0

06:13

dfn ← {(2×⍳⍵)-1}
⍝ Equivalent to ..
dfn ← {1-⍨2×⍳⍵}

^ in that case does ⍨ switch the arguments of the function -?

Bubbler

Yes

PyGamer0

is there a way to split a vector by a delimiter (say x)

or just count them

Bubbler

Is the delimiter a scalar or a vector?

For scalar x, the canonical way to count x's in a vector v is +/x=v

and split v by x with (x≠v)⊆v

Razetime

06:28

@PyGamer0 one of my favourite idioms is <char>(≠⊆⊢)<string>

Razetime

06:44

splits string on char

RikedyP

07:30

@Razetime Also one of my faves. And for multiple delimiters: ((~∊⍨)⊆⊢)

Adám

@RikedyP ~⍤∊⍨⊆⊢?

RikedyP

@Adám Yeah but I just can't get into using atop for these things, don't like how it looks

Also I think what's happened for me mentally is trains just "feel right" in parens, since I don't often (unless copying from aplcart) assign trains to names, since in my mind the ideal train is just larger than a single composition but smaller than a dfn

Razetime

08:01

I vibe with rikedyp

3 hours later…

xpqz

11:18

For 2015 p4 (progressive dyadic iota), whatever I enter I get the following message: Internal error – No result was provided when the context expected one -- temporary issue, or test bug?

Adám

@xpqz Probably not temporary, as the site is static GitHub Pages+TIO. Sounds like a test bug. I'll have a look.

Mysterious. Everything looks normal.

xpqz

As in you can't reproduce?

Adám

I can, using the site. I'll try running it locally.

Vegard Stikbakke

12:09

Hi all!
Dipping my toes into APL.
I have written a solution to [Project Euler problem 1](https://projecteuler.net/problem=1), which asks for the sum of all multiples of 3 or 5, below 1000:

`euler1 ← {+/ ⍸ 0 = (3 | ⍳ (⍵ - 1)) ^ (5 | ⍳ (⍵ - 1))}`

`euler1 10` gives 23, the sum of 3, 5, 6 and 9, as described in the problem there.

It seems like it should be possible to simplify my solution a bit.
I have watched a couple of Conor Hoekstra's videos, among others, so I have seen this concept of forks, for example.

Adám

@VegardStikbakke (You might want to read apl.wiki/APL_Orchard#Basic_formatting for help with the markdown.)

Vegard Stikbakke

@Adám Indeed, thanks!

Adám

Oh, and welcome to the Orchard. You've found the right place!

Do you know about the outer product ∘.f?

Vegard Stikbakke

No!

But I know of it from math

Adám

⎕←3 5∘.|⍳10

TryAPL

12:17

@Adám
1 2 0 1 2 0 1 2 0 1
1 2 3 4 0 1 2 3 4 0

Vegard Stikbakke

and thanks! that's great!

let's see. Trying that

Adám

Feel free to use the bot.

)about

TryAPL

@Adám To run APL code, write code blocks starting with ⎕← or ⋄ or write a multi-line code block and prepend ⎕← or ⋄ to lines you wish to run. All matching groups / lines will be joined by ⋄ and run via TryAPL, and the output will be posted here. To format a codeblock, write `code`, or for a multi-line code block, use Shift+Enter to type multiple lines and press Ctrl-K, press the 'fixed font' button, or prepend four spaces to each line.

Vegard Stikbakke

Oh, excellent!

Right, so for each number in the array on the left, it'll perform the operation on the right?

Sorry, the other way around

Adám

It pairs up each element from the left with each element from the right. The arguments are treated equally in that way.

Vegard Stikbakke

12:20

For each number on the right, it'll perform the operation on the left?

Okay!

⎕←1 1∘.+ 1 1

TryAPL

@VegardStikbakke
2 2
2 2

Vegard Stikbakke

cool

Adám

Try changing the numbers to 1 2 and 10 20.

Vegard Stikbakke

so in the example above, the | is the f

Adám

Yes.

Vegard Stikbakke

12:22

⎕←1 2∘.+ 10 20

TryAPL

@VegardStikbakke
11 21
12 22

Vegard Stikbakke

So now I want to do some kind of reduction along the y axis?

Adám

Yes, that's ⌿ instead of /

Vegard Stikbakke

ah!

⎕←∧⌿3 5∘.|⍳10

TryAPL

@VegardStikbakke 1 2 0 4 0 0 2 6 0 0

Adám

12:25

Two things:

Vegard Stikbakke

Hm, there might be a better one? I still need to find those equal to 0 and sum them

Adám

∘ You want to know when the division remainder is zero, so you need 0=

∘ You probably mean OR, not AND, so ∨ (not ∧)

Vegard Stikbakke

yeah, true!

⎕←^⌿0=3 5∘.|⍳10

TryAPL

@VegardStikbakke 0 0 0 0 0 0 0 0 0 0

Vegard Stikbakke

oops

ah sorry

you did say v

⎕←∨⌿0=3 5∘.|⍳10

TryAPL

12:28

@VegardStikbakke 0 0 1 0 1 1 0 0 1 1

Vegard Stikbakke

⎕←+/∨⌿0=3 5∘.|⍳10

TryAPL

@VegardStikbakke 5

Adám

This counts how many there are, but you want their sum, so what you did before with ⍸ was good.

Vegard Stikbakke

Right!

⎕←⍸∨⌿0=3 5∘.|⍳10

TryAPL

@VegardStikbakke 3 5 6 9 10

Vegard Stikbakke

12:30

⎕←+/⍸∨⌿0=3 5∘.|⍳(10-1)

TryAPL

@VegardStikbakke 23

Adám

Alternatively, you could multiply all the numbers by their corresponding Boolean, and sum that, since it would null out the non-multiples.

Vegard Stikbakke

Can you show me that?

Adám

⎕←{+/all×∨⌿0=3 5∘.|all←⍳⍵-1}1000

TryAPL

@Adám 233168

Vegard Stikbakke

12:32

Ohh, I get it. Nice

and name←value both sets name to value and evaluates to the value?

Adám

Yes, in general, the result of any assignment is always whatever is on the right of the ←

Vegard Stikbakke

I see. Useful!

Adám

This even applies if you do what we call "modified assignment" (I think other languages call it "augmented assignment").

Vegard Stikbakke

What's that?

Adám

E.g. ⋄ a←10 ⋄ 2+a+←1 ⋄ a

TryAPL

12:34

@Adám
3
11

Razetime

similar to += in other languages

Adám

So a+←1 added 1 to a's current value, but it also returned 1, and then 2+1 gave 3.

Vegard Stikbakke

I see.

Razetime

modified assignment has different scoping

Adám

@Razetime What?

Razetime

12:35

doesn't it assign globally?

Adám

No.

Razetime

is that only ⊢←?

Adám

No.

⋄ a←10 ⋄ {a←20 ⋄ a+←1 ⋄ a}⍬ ⋄ a

TryAPL

@Adám
21
10

Vegard Stikbakke

Thanks a lot Adam!

Adám

12:37

No problem. You're always welcome to ask questions here and hang out in general. There are usually people ready to help at a moment's notice.

Otherwise, questions on Stack Overflow are usually answered within a few hours.

Vegard Stikbakke

With the apl tag here? stackoverflow.com/questions/tagged/apl

Adám

Exactly, and also [dyalog] if that's what you're using.

Vegard Stikbakke

Nice! Thanks!

2 hours later…

RGS

14:59

@Adám I wonder why does it feel like I always write the slower function 😂

@xpqz ○/ Thank you for the book

Adám

Announcement: BAA webinar NOW. Zoom 858 532 665, passcode: ×/1920 12 17

rak1507

15:14

I normally get an email about it, I didn't today, wonder if something's broken.

Joshua

May I get a little J help. Trying to get the same result as (3 5) ∘×¨ ⍳3 in APL. I can get there with <"1 |: (3 5) */ i. 3, but am I missing something obvious?

rak1507

nothing obviously better to me but <"1]3 5*/~i.3 avoids the |:

I suppose it's not actually any shorter than <"1|:3 5*/i.3 :/

Adám

@rak1507 Maybe because it isn't interesting…

rak1507

maybe, don't think I got one last time either

Joshua

yeah, well it was the |: that seemed unneccessary. I figured there must be another way

rak1507

15:26

would it be rude to leave? as fascinating as the agm is...

Joshua

that's @rak1507

erm... i meant... thanks @rak1507

RGS

@rak1507 just drop a "sorry, have to go; thanks for the webinar" in the chat and leave.

That's how I usually do it, at least.

rak1507

@Joshua np

what's the equivalent to ∘ in j?

for dyadic, x f∘g y being x f g y

Joshua

@rak1507 I don't know. I've just started to play with J a little, but sometimes I try to learn by looking at APL stuff.

rak1507

yea, doesn't look like j has an exact equivalent from a quick look at the docs

Adám

15:49

@rak1507 (f g)

@Joshua Obvious? 3 5&*each i.3

Joshua

thanks @Adám, I didn't find each in NuVoc, but I will play with this and look up more info

Adám

@Joshua You could also write it as 3 5&*&.>i.3

Joshua

ahh thanks. I was looking at Compose thinking it could do it somehow

Adám

In this aspect, J is exactly like APL.

1 hour later…

pmikkelsen

17:19

What is the user command to show the amount of memory taken by some variable in dyalog? I never used it, but I am pretty sure I have seen it being used at some point

Adám

@pmikkelsen Do you mean memory used by a specific name right now, or how much memory is needed to evaluate an expression?

Either way, do you know about APLcart?

pmikkelsen

Memory used by a name right now

@Adám Ah I should use APLcart some more instead of asking easy questions :) thanks

Adám

Then it isn't a user command you're looking for, but rather the ⎕SIZE system command.

pmikkelsen

Yes that looks like the one i need

Adám

Just be aware of what the number it reports actually represents.

pmikkelsen

17:32

Yes

2 hours later…

Adám

19:57

Can I unify these?

susp∨←1≡⊃event
susp∧←0≡⊃event

Adám

20:07

Never mind, that makes no sense.

« first day (1660 days earlier) ← previous day next day → last day (1294 days later) »

all rooms

Transcript for

Aug11

Aug '2112

Aug13

apl.chat ― Learn, teach, ask, code, golf, & discuss usage. See ...

apl array-manipulation j tips

join this room
about this room

00:00

06:00

12:00

18:00

all times are UTC