The APL Orchard

gamma_delta

9:00 PM

wait ok

i think i am maybe figuring it out

how do i turn a char vector into a hexadecimal number

Adám

@gamma_delta You mean represent each byte as to hex digits?

gamma_delta

I think so?

#.Crypt.HASH_MD5 #.Crypt.Hash'test'

this gave me a string, looks like?

Adám

Convert chars to code points, then convert to hexadecimal, e.g. using the hex function from dfns.dws

gamma_delta

oh yeah what is dfns

i've heard about that

Adám

Or actually, you could just implement it yourself: ⎕←(⎕D,⎕A)[¯1+,⍉16 16⊤⎕UCS'hello']

TryAPL

9:03 PM

@Adám 46434A4A4D

gamma_delta

Huh

Adám

@gamma_delta It is a workspace (binary blob) that has a ton of useful things implemented as dfns.

awagga

⎕←↓⍉{(⎕D,⎕A)[1+16⊥⍣¯1⊢⍵]}⎕UCS'hello'

TryAPL

@awagga
┌──┬──┬──┬──┬──┐
│68│65│6C│6C│6F│
└──┴──┴──┴──┴──┘

awagga

Beat me to it

Adám

9:04 PM

@awagga That's dangerous.

gamma_delta

What does ⎕D and ⎕A and ⎕UCS and all mean

Adám

You know you can look them up with F1 and on APLcart?

gamma_delta

Huh

awagga

⎕D is '123456789', ⎕A is the same but letters and ⎕UCS converts letters to ascii codes

aplcart.info

Adám

… and vice versa.

gamma_delta

9:05 PM

Huh

awagga

@Adám It is?

Adám

Also, ⎕D has a 0 :-)

awagga

Darn, my memory has failed me

gamma_delta

Hexify← {(⎕D,⎕A)[¯1+,⍉16 16⊤⎕UCS⍵]} didn't seem to work

Adám

@awagga Yes: ⎕←↓⍉{(⎕D,⎕A)[1+16⊥⍣¯1⊢⍵]}⎕UCS ⎕JSON'"\u000a\u000c"'

TryAPL

9:07 PM

@Adám
┌─┬─┐
│A│C│
└─┴─┘

gamma_delta

Hexify 'AAAABBBB' gives me an index error

awagga

Ah, I see

Adám

@gamma_delta My bad: remove the ¯

gamma_delta

aha nice

and this yields a string?

or, char vector

Adám

"string"s are char vecs.

gamma_delta

9:11 PM

ok it seems to be working

hm. ok. this seems like a case where it's good to use an actual iterator and not a loop. or like a long-form dfn

Adám

@gamma_delta Yay, care to share?

gamma_delta

```
⍝ Thanks, Adam, i'm not going to pretend I know how any of this works
MD5 ← {(⎕D,⎕A)[1+,⍉16 16⊤⎕UCS(#.Crypt.HASH_MD5 #.Crypt.Hash ⍵)]}
```

awagga

⎕CY'dfns' to use hex btw
{hex ⎕UCS(#.Crypt.HASH_MD5 #.Crypt.Hash ⍵)}

I don't think you need those brackets either

Adám

@gamma_delta Remove the backticks and press Ctrl+k.

gamma_delta

⍝ Thanks, Adam, i'm not going to pretend I know how any of this works
MD5 ← {(⎕D,⎕A)[1+,⍉16 16⊤⎕UCS(#.Crypt.HASH_MD5 #.Crypt.Hash ⍵)]}

Adám

9:16 PM

@awagga Might want to 'hex'⎕CY'dfns' so as not to clutter.

gamma_delta

ok

awagga

Oh, I didn't know you could import a single function, cool.

Adám

You can import multiple with multiple names on the left too.

awagga

Good to know ^^

gamma_delta

MineThreshold ← {
    thresh ← ⍵
    recur ← {
        ⍝ ⍵ = the key we're trying in here
        hash ← MD5 input , ⍕⍵
        ∧/'0'=thresh↑hash : ⍵
        ∇ 1+⍵
    }
    recur 1
}

let's see

Adám

9:19 PM

@gamma_delta My colleague Brian says you just need echo -n to avoid the newline.

gamma_delta

Aha but that doesn't work on windows

it works on linux but not windows

Adám

@gamma_delta Please use Ctrl+k (you can still edit!)

gamma_delta

What does ctrl+K do and it said it was too late to edi tit

im very confused

Adám

It adds 4 spaces to each line, causing chat to show it as code.

@gamma_delta You get a VALUE ERROR?

gamma_delta

@Adám echo -n test dutifly prints out "-n test\n"

(dutyfly?)

(Obligatorily and stupidly)

Adám

9:21 PM

@gamma_delta Sure, but if you pipe it into md5sum?

gamma_delta

Yeah it still pipes it

oh well it's working with the library now

Adám

@gamma_delta Not by me. Wait, Windows?

@gamma_delta Good. That's probably also faster than shelling out a bunch of times.

gamma_delta

Yeah ... ⎕SH will use the windows command processor

bypassing cygwin and it's copy of echo that actually works

Adám

Ah, right, then -n doesn't work.

gamma_delta

Anyways more fun problems, i'm getting a syntax error at the newline on the MineThreshold ← { line

i already resaved the file as LF and not CRLF

Adám

9:25 PM

@gamma_delta Did you switch on multi-line mode?

gamma_delta

uh i don't know

i want all my final solutions to be runnable from .dyalog scripts

Adám

@gamma_delta Huh, apparently, under Windows, you need echo | set /p= to echo without a newline. Because Microsoft.

gamma_delta

for posterity or something

Adám

@gamma_delta Set the config param DYALOG_LINEEDITOR_MODE=1

gamma_delta

how does one do that

Adám

9:28 PM

You can do so in the registry, a config file, as a dyalog argument, an environment variable, or a command line parameter.

gamma_delta

will it auto-load the config file?

Adám

Depends a bit on how you are running stuff.

How do you run your .dyalog script?

gamma_delta

dyalog -script day04.dyalog

Adám

So just add DYALOG_LINEEDITOR_MODE=1 to that.

gamma_delta

so i have to retype it everytime? ugh. ok

Adám

9:31 PM

Then set it as an environment variable. Are you running this under cygwin or straight under Windows?

gamma_delta

wsl actually, cause the dyalog that goes on windows won't run -script files

(Didn't we talk about this)

Adám

Oh. then yeah, just set the variable permanently.

gamma_delta

YEAH it works

nice

Is there a nice clean way to run a couple functions on the same input, then check if they all returned 1?

like some kind of ∧/ that maps over function calls?

my brain tells me some kind of cool . usage but i dont know

Adám

You could express it as a train: ∧/(f,g,h)input

rak1507

or (f∧g∧h)input

Adám

9:42 PM

Ninja'd.

gamma_delta

Ohh i see(?)

you like stitch together (F calls) (G calls) (H calls) (I calls) ... and then check all of them?

Adám

Yeah.

gamma_delta

God someday I'll remember this. but uh for now how might i check how many vowels are in a string?

i forget the function for that

like i need to +/ over something

awagga

⎕←(×∧(⊢≡⌽)∧((⌊=⊢)*∘0.5))121

TryAPL

@awagga 1

awagga

9:47 PM

Checks if a number is a palindromic square, ×∧ is useless here, but you get the idea

rak1507

@gamma_delta you could use ≢ and ∩ (intersect)

but +/ and checking if it's in the string would work too

Adám

@gamma_delta +/string∊vowels

gamma_delta

thank you

gamma_delta

10:08 PM

hi, i am going to ask a very XY question, but i'm asking it because i'm asking for help on an algorithm i made up, i don't want a "good" algorithm cause then i'm not learning anything, right

So i need to see if a string has doubled letters in it. So far I have {⍺(2-/⍵)}⌸ 'aabcca'

the objective being, if there's any ¯1s in there, the letter is doubled

Problem is I have no clue how i might filter this

rak1507

oh, clever

that's actually a cool method!

Miguel

I have a question @gamma_delta why ddo you have the ⍺ in the function?

gamma_delta

@Miguel sure?

So I know what the letter is later

c-- oh

awagga

⎕←¯1∊¨↓{(2-/⍵)}⌸ 'aabcca'

TryAPL

@awagga 1 0 1

gamma_delta

10:11 PM

oh that's a good point

Adám

@gamma_delta ⎕←∊{⊂⍺/⍨1+¯1∊(2-/⍵)}⌸ 'aabcca'

TryAPL

@Adám aabcc

gamma_delta

¯1∊{2-/⍵}⌸

I don't need to know what the letters are just that they're there

i bet i can make this the coolest train you've ever seen hold on

Adám

Oh, you just need to know if any adjacent letters are identical?

That'd be ⎕←∨/{¯1∊2-/⍵}⌸ 'aabcca'

TryAPL

@Adám 1

gamma_delta

10:14 PM

(¯1∘∊{2-/⍵}⌸)

that's my solution

Adám

No need for ∘

gamma_delta

woah did i outgolf you

awagga

⎕←(¯1∊2-/⊢⌸) 'aabcca'

TryAPL

@awagga 1

awagga

Few people can outgolf Adám :P

Adám

10:15 PM

@gamma_delta Yeah, I didn't think of the fact that the mixed result's 0s don't matter.

Revenge: ⎕←∨/2=/'aabcca'

TryAPL

@Adám 1

gamma_delta

Well then

oh god that's way smarter than i

need to check for double letters? just check for double letters

Adám

Yup.

Miguel

Alright, so i have a question

Adám

Go for it!

Miguel

10:18 PM

I've been trying to make a fibonnacci function, you give it a list starting with 2 fibonnacci numbers (like ⍳10) and the starting position for it to continue the sequence

Adám

@gamma_delta Now, how would you check for triple letters? stresssyndrome → 1 stress syndromess → 0

Miguel

So the list is defined in the environment and the number is a parameter

Adám

@Miguel And then it has to replace elements after the starting position?

Miguel

i got up to here
FIB ← {
⍵>≢V:V
V[⍵]←V[⍵-1]+V[⍵-2] ⋄ ∇ ⍵+1
}

Adám

@Miguel Put your code in a separate message, and press Ctrl+K before posting it.

Miguel

10:20 PM

And it works but whenever i try to make V into ⍺ it break

@Adám yes, sorry

Adám

FIB ← {
    ⍵>≢⍺:⍺
    ⍺[⍵]←⍺[⍵-1]+⍺[⍵-2] ⋄ ⍺ ∇ ⍵+1
}

Like this?

My guess is that you missed the ⍺ before ∇

Miguel

@Adám Yes

No no, i did put it in there

Adám

Can you give us values for V and the argument that work as you want?

Miguel

V ← ⍳10

gamma_delta

I'm getting a domain error, somewhere

is there a way to pick apart where

Miguel

10:24 PM

so you would call it like
V FIB 3

Adám

@Miguel Oh, I see the problem. You're not allowed to change the value of ⍺

@gamma_delta Sure, but you'd want to run in the interactive session rather than with a script, then.

However, yes, you can set ⎕TRAP←0'E' '⎕←↑⎕DM at the top of your script.

Miguel

@Adám huh, alright. Then follow up, how could you make it work

Adám

@Miguel Just use x←⍺ and modify x

Alternatively, you can use @ to change the value and give the result to ∇:

FIB←{
    ⍵>≢⍺:⍺
    ((⍺[⍵-1]+⍺[⍵-2])@⍵⊢⍺) ∇ ⍵+1
}

@Miguel Btw, check out +/⍺[⍵-1 2]

gamma_delta

How do you filter for non-empty lines?

or like non-empty strings

Adám

Filter by 0≠≢¨

⎕←{⍵/⍨0≠≢¨⍵}'Hello' '' 'how' '' '' 'are' 'you?'

TryAPL

10:31 PM

@Adám
┌─────┬───┬───┬────┐
│Hello│how│are│you?│
└─────┴───┴───┴────┘

gamma_delta

god i'm so stupid i was like "why isn't this working"

it was because i was reading day05.dyalog and not day05.txt

Adám

:-)

gamma_delta

Given an array of strings, how can i tell how many times each of those strings appears in another string?

i would need ... ⍷ and +/ i think

Miguel

@Adám is ⍵⊢⍺ a special case? shouldn't it just be ⍺

Adám

@gamma_delta Yeah, strings+/⍤⍷¨⊂string

Many variations are possible.

gamma_delta

10:42 PM

Specifically i'm trying to figure out if the string contains any letter pairs twice (or more)

(2,/case)+/⍤⍷¨case is giving me a length error?

Adám

@Miguel It isn't ⍵⊢⍺ it is ⊢⍺. The ⍵ is bound by @ because @ is a dyadic operator.

@gamma_delta You're missing ⊂ before case

gamma_delta

{2,/⍵} 'alphabetic'

hey

⎕←2,/ 'alphabetic'

TryAPL

@gamma_delta
┌──┬──┬──┬──┬──┬──┬──┬──┬──┐
│al│lp│ph│ha│ab│be│et│ti│ic│
└──┴──┴──┴──┴──┴──┴──┴──┴──┘

Miguel

but isn't ⊢ dyadic aswell?

gamma_delta

aha

Adám

10:44 PM

@gamma_delta When you forget ⎕← you can just edit it in, and the bot picks up the change.

gamma_delta

Oh ok

Adám

@Miguel It is, but so are many functions. Here, it is used monadically.

Miguel

@Adám Alright, let me explain what i understand from the line

((⍺[⍵-1]+⍺[⍵-2])@⍵⊢⍺)
(⍺[⍵-1]+⍺[⍵-2])
                            ⍵⊢⍺
(⍺[⍵-1]+⍺[⍵-2])@⍵⊢⍺

Adám

No, that's wrong. @ is not a function, but a dyadic operator.

It needs at least a left operand (⍺[⍵-1]+⍺[⍵-2]) and a right operand ⍵ and an argument ⊢⍺

The ⊢ is necessary to prevent ⍵ ⍺ from being a 2-element vector.

gamma_delta

Hm. how might i do this problem making sure that 'aaa' doesn't count?

Adám

10:48 PM

You could also write it as …)@⍵)⍺

@gamma_delta Not sure what you mean.

gamma_delta

So we've been solving the problem "See if this string has any pairs of letters more than once"

the problem is our solution would match "aaa"

This is against the problem statement, they're not allowed to overlap

Adám

Ah, so you don't want it to be counted as aa twice?

gamma_delta

"aaaa" would work but not "aaa" yeah

Adám

That'll be bit more complicated. The easiest way is to use regex.

gamma_delta

Lovely

that would be like /(\w\w).*\1/?

Miguel

10:51 PM

@Adám Now it makes sense, thanks!

Adám

@gamma_delta I'd use '(.)\1' if I understand the problem right.

gamma_delta

I plugged my soln into regex101 and it seems to work

Adám

In APL, regexes are not a type, they are just normal character vectors.

gamma_delta

I dont think you understand the problem then... uh

> [The string passes if] It contains a pair of any two letters that appears at least twice in the string without overlapping, like xyxy (xy) or aabcdefgaa (aa), but not like aaa (aa, but it overlaps).

Adám

@gamma_delta Oh, OK, you're looking to see if the same double-letter occurs twice.

gamma_delta

10:52 PM

Yep

Regex my beloved

Adám

Then your regex is correct, yes.

⎕←(≢'(\w\w).*\1'⎕S 3)¨'xyxy' 'aabcdefgaa' 'aaa'

TryAPL

@Adám 1 1 0

Miguel

@Adám So, i've tried the sum reduction and got FIB looking like this:

FIB ← {
     ⍵>≢⍺:⍺
     ((+/⍺[⍵-1 2])@⍵⊢⍺)∇ ⍵+1
 }

Adám

That looks pretty nice.

Miguel

Thanks for the help! i'm really grateful of having a pro guiding me

Adám

10:58 PM

Happy I could help. That's what I'm here for.

Miguel

Idk why but there's something satisfying in APL code

rak1507

very true

Miguel

tomorrow i'll finish the ProjectEuler problem

Adám

@Miguel Yes, it is hard to put a finger on what exactly it is, but people keep coming back for more.

awagga

:)

rak1507

11:00 PM

stumbled across a syserror 999 - searched it here, and found I had the same issue a while ago haha

Miguel

Alright everyone, have a nice one, i'm off to sleep

Adám

@rak1507 But you still can't reliably repro? Did you at least get an aplcore?

rak1507

@Adám no, I can, it's the 8415⌶ one

awagga

Oh, I never realized there was a search bar in the top right

Adám

@rak1507 Hm, yeah I see my colleagues could repro it.

rak1507

11:03 PM

@Adám interesting

Miguel

oh btw @xpqz really liking the book, I found it a little overwhelming on the Indexing chapter

awagga

I bookmarked the Dyadic Transpose, Indexing + Rank page, they're worth referencing if you get stuck whilst learning :)

Adám

Speaking of @xpqz I've finally caught up a bit with my to-do list. Reviewing your blog post might just be the next thing…

gamma_delta

11:32 PM

Given the four corners of a box how might i select it in a way i could do ← on it?

or like .... this is a problem i'm not especially sure how to use apl with

I have a list of commands that are ways to update areas in a grid

Adám

Well, do you have the size of the box?

@hypumji Welcome. Interested in APL?

gamma_delta

uh, the commands are in the form 887,9 through 959,629

and the total grid is 1000x1000

⍳1000 ∘.0⍨ ⍳1000 yes?

⎕← ⍳10 ∘.0⍨ ⍳10

TryAPL

@gamma_delta
SYNTAX ERROR
      ⎕←⍳10∘0⍨⍳10
          ∧

Adám

That doesn't look right. Not sure what you;re trying to do.

Did you mean = instead of 0?

gamma_delta

∘. is cartesian product right?

Oh im so dumb

literally

⎕←10 10⍴0

TryAPL

11:35 PM

@gamma_delta
0 0 0 0 0 0 0 0 0 0
0 0 0 0 0 0 0 0 0 0
0 0 0 0 0 0 0 0 0 0
0 0 0 0 0 0 0 0 0 0
0 0 0 0 0 0 0 0 0 0
0 0 0 0 0 0 0 0 0 0
0 0 0 0 0 0 0 0 0 0
0 0 0 0 0 0 0 0 0 0
0 0 0 0 0 0 0 0 0 0
0 0 0 0 0 0 0 0 0 0

gamma_delta

except with 1000

Adám

OK. So now you need to parse the commands and update the "canvas"?

gamma_delta

Yeah

Once i have the region and can mutate it, that should be pretty easy fortunately

cause all i need to do is turn on, turn off, or toggle (~)

Adám

That should be easy, yes. What's the problem? Selecting the right regions?

gamma_delta

I could do it with some kind of like, multi-line dfun where i make a board and keep mutating it with ← as i ¨ over each line