Yes that did the trick :) How could ⍳ have missed that. Looking for that already for months...

@Richard We're beginning to plan APL Seeds '23. Is presenting there something you might be interested in doing?

@Adám sure!

OK, then I'll have RikedyP contact you to discuss subjects etc.

Welcome to APL Quest 2017-3! Today's quest is Miss Quoted:

> Write a function that will remove text found between pairs of double quotes (").

I realy hope someone found a better one than I did:

{⍵/⍨(⍵='"')∨(~≠\'"'=⍵)}

That's great, though, just factor out the comparison to happen only once.

(Doable using a variable or a train or a dfn.)

yes.!

{⍵/⍨~(≠\>⊢)'"'=⍵}

I tried to look for a method where the second '"' was selected directly

@awagga thank you!

@awagga Uh ~ plus > equals ≤

I'm not caught up on my boolean algebra :)

ah, I also wanted to do somethuing witg Regex

but did not manage

Is new for me but looks very powerfull

That's not very involved: '"[^"]+"'⎕R'""'

...

/⍨∘((≠\≤⊢)'"'=⊢)⍨

≠\⍛≤⍤=∘'"'⍛/ should work in 20.0

Anyone dares having a go at basing the solution on -\?

And how about =\?

working on it

still that second '"'

State machine version: {⍵∩⍨r⊣{r,←⍵/⍨l∨l≠←'"'=⍵}¨⍵⊣l←≡r←''}

{=\'"'≠⍵}, {~≠\'"'=⍵}, and {~2|-\'"'=⍵} seem to do the same thing?

@Richard Just save the mask to variable.

@rabbitgrowth Indeed.

@Adám yes, and then exlude the remaining '"' like the first solution

Exactly. Or use a train or dfn. Same idea.

Due to the equivalence that @rabbitgrowth stated, using =\ can be just as short as {⍵/⍨(≠\≤⊢)'"'=⍵}

@rabbitgrowth Also, 0≠-\ is the same as ≠\

So again, there are two equivalent solutions using -\ one using = and one using ≠ to generate the initial mask.

Wait, maybe I'm mistaken. I can only get it to work as {⍵/⍨(⊢∨0=-\)'"'=⍵}

where does it go wrong?

If I try to use '"'≠⍵

Anyway, I think we've beaten this one.

@Adám It's nice how APL lets you do ≠←

@Richard OK, so homework for you for this one is to remove both "content" and 'content'!

thanks!

smells like an outer product :)

@rabbitgrowth Yes, being able to use any function for modified assignment is nice, although my boss frowns on me writing things like var{giant function here}←0

See you next week for 2017-4: Slice(s) of Pie(s)!

The longer I stare at the state machine solution, the nicer it is. Thanks a lot Adám and see you all next week!

@Richard For last week's problem, try rounding to the next higher multiple of the left argument.

I will!

@Richard Remember test cases like this "isn't" so 'easy'!

In l∨l, why exactly is the l on the left unaffected by the assignment?

Separated by ∨

@rabbitgrowth Oh, maybe I misunderstood. The l on the left is affected, but the right argument to ∨ is the pass-through value of the assignment, i.e. what's on the right of ← — NOT the new value of l

Ah I see, I read it wrong sorry

Also, the ⍵∩⍨ part is only for handling the empty string case, right?

yes

I see, thanks

hugely wasteful ofc

@Adám no I haven't I'll try