The APL Orchard

« first day (2101 days earlier) ← previous day next day → last day (850 days later) »

Electric Coffee

08:48

So suppose I'm solving a sudoku, I can index the rows like this: sudoku[n;] and the columns like this: sudoku[;n]. Is there an easy way to index the 9 3x3 squares?

sudoku[⍳ 3 3] gets me the top left corner, but I don't know how to modify this iota to offset it

Adám

rowoffset columnoffset∘+¨

Electric Coffee

so ro co ∘+¨⍳ 3 3?

Adám

Yes, or sudoku[3+⍳3;6+⍳3] for the last 3×3 in the middle row.

Electric Coffee

that's honestly more legant imo

thanks

Adám

Or you could drop: 3 3↑3 6↓sudoku

Electric Coffee

08:51

hmm

Adám

Or rotate: 3 3↑3⊖6⌽sudoku

Electric Coffee

now you're just flexing

Adám

Or mask: (3/0 1 0)⌿(3/0 0 1)/sudoku

Electric Coffee

09:35

I really like the mask, because it generates a pattern

it's easy to visualise

B. Wilson

10:34

No stencil love? :P 1 1⌷⊢⌺3 3⊢sudoku

Adám

Did you try that? It doesn't work.

B. Wilson

⎕←1 1⌷⊢⌺3 3⊢9 9⍴⍳81

TryAPL

@B.Wilson
0  0  0
0  1  2
0 10 11

B. Wilson

Ah, I always forget that I have ⎕IO←0 locally.

Adám

Uh, it still doesn't work, as it starts one step to far north-west.

⎕←2 2⌷⊢⌺(2 2⍴3)⊢0,0,0⍪0⍪9 9⍴⍳81

TryAPL

10:42

B. Wilson

⎕←2 2⌷⊢⌺3 3⊢9 9⍴⍳81

TryAPL

@B.Wilson
 1  2  3
10 11 12
19 20 21

Adám

OK, now try getting the middle square!

B. Wilson

⎕←5 5⌷⊢⌺3 3⊢9 9⍴⍳81

TryAPL

@B.Wilson
31 32 33
40 41 42
49 50 51

B. Wilson

10:46

Just SE by 3 3, no?

Adám

SE?

B. Wilson

Southeast.

Adám

Sure, but you had to go 3 steps SE instead of 1 step, because you generated way too many sub-arrays.

B. Wilson

Yeah, extraneous 8X overhead does seem subideal :P

Adám

And easy to fix with an additional row in the right operand.

B. Wilson

10:52

You're too fast! I just went and read the Stencil docs and then realized exactly what you were doing above. Why the zero padding though?

> Rectangles are centred on successive elements of Y

Hrm...

Adám

Yeah, we need a way to specify that. Without it, we have to discard the outer ones.

B. Wilson

11:18

Man, Roger Hui always seems to deliver: dyalog.com/blog/2020/06/towards-improvements-to-stencil

Really wish I could have met him.

B. Wilson

11:30

@Adám Thanks for sharing. Interesting that Git and SVN live together. Are they mirrors of each other or used on separate projects?

Adám

Separate things. new open source things use Git. Old stuff uses SVN.

2 hours later…

Sʨɠɠan

13:42

you have open source things?

xpqz

@Sʨɠɠan github.com/Dyalog

Sʨɠɠan

ooh

xpqz

Dyalog's open sourced a hefty chunk (maybe all?) of its code bar the interpreter itself. It's a very useful resource to learn from when it comes to "industry strength" APL.

Sʨɠɠan

14:01

i saw this code in the tutorial: ⍉2∘⊥⍣¯1⍳2*3. i dont get it, how can you repeat (power) something -1 times?

xpqz

That's an inverse.

Or "magic" if you like.

A lot of APLers find that a clever feature (I detest it).

That particular inverse is useful though.

      2⊥⍣¯1⊢976
┌→──────────────────┐
│1 1 1 1 0 1 0 0 0 0│
└~──────────────────┘

Converts to binary, using the smallest number of bits required.

Sʨɠɠan

i dont get why theres a ⍣ there tho

xpqz

It's consistent with mathematics.

Sʨɠɠan

what purpose does it serve?

xpqz

power-of-minus-one is one-over or inverse.

It magically lets you solve equations involving a function and the answer

What argument was a function applied to in order to give the answer?

Sʨɠɠan

14:15

ah i think i get it

how does it determine that tho (the inverse)?

brute force?

xpqz

That's the clever bit. In many (not all) cases, the interpreter can reverse its built-in formula for combinations of the primitives.

However, it can't do so for dfns you write. A proposed extension (obverse) would let you define forward and back versions of your own functions.

Sʨɠɠan

interesting

xpqz

Maybe :)

I find that beyond a few well-known ones (like the binary one above) it quickly becomes hard to follow.

Inverse ⍸ is very handy, too:

      ⍸⍣¯1⊢1 2 5
┌→──────────┐
│0 1 1 0 0 1│
└~──────────┘

Someone here said that Dyalog views inverses as 'Easter eggs' to be discovered, rather than documented. This contributes to my dislike of inverses, tbh.

awagga

I don't think that's true. They have been called party tricks, because it's generally not a good idea to use them in production.

It would be a lot of work to document the (useful) inverses

xpqz

@awagga Documentation is a lot of work.

awagga

14:23

I agree with the sentiment though, it's a shame

3 hours later…

Sʨɠɠan

17:26

k so ive been going through some examples. this one is for AoC 2016 day 6: {⊃⊃⍵[⍒⍵[;2];]}¨{⍺,≢⍵}⌸¨↓⍉↑data. could it be made any better/clearer?

the sorting by column was stolen from aplcart

Adám

You sort the entire range only to get the first element. You could simply compute the grade (as now) and get the first index.

You could also fuse the two loops into one, e.g. by using a 2-train ({⊃⊃⍵[⍒⍵[;2];]}{⍺,≢⍵}⌸)¨

If you want, you can make {⍺,≢⍵} tacit as ,∘≢ but I'm not sure if it will impact performance.

@Sʨɠɠan Btw, you could submit such questions to CR.SE

Sʨɠɠan

tbh to me {⍺,≢⍵} is clearer

@Adám i know, but i dont think its worth for such a small snippet

Adám

@Sʨɠɠan Yeah, it's a style thing.

@Sʨɠɠan It'd be kind of funny, because people usually submit walls of text, but APLers ask for review of single-line programs.

Sʨɠɠan

lol

thanks, time to do other aoc challenges now

Adám

Sure thing. Are you aware of apl.wiki/aoc?

Sʨɠɠan

17:34

does it have spoliers

ah fortunately not right in front of you

Adám

It is list of links to repos with published solutions. You can publish yours too and add to the list.

Sʨɠɠan

17:47

is there any way to apply a function on a vector rather than doing {⍵[1]<function>⍵[2]}?

Adám

⊃function/Y?

Sʨɠɠan

ah forgot folding

Adám

Did you search APLcart, btw?

Sʨɠɠan

yeah

aplcart.info?q=apply%20function%20on%20vector

why is aoc so easy with apl?

Adám

Right. The missing keyword is vector which I'm adding now.

Sʨɠɠan

17:54

i solved 2021 day 1 in a few mins compared to the half hour it took me with a python solution last year

Adám

How long have you been programming APL now?

Sʨɠɠan

2 days i think

or 3

Adám

How long had you been programming in Python back then?

Sʨɠɠan

first message in here was about an hour after i started:

Oct 24 at 15:22, by Sʨɠɠan

i love how you can reset the index origin in apl

@Adám erm... lets see

i started when i was 11, im 15 now...

learned python a year after starting to program...

3 years

Adám

I don't know how you do it. I think I've never experienced anyone picking up APL as fast as you.

Sʨɠɠan

18:00

how can i tell stencil to not overhang?

Adám

You can't :-( but you can pad with extra elements and discard the first sub-array(s).

Sʨɠɠan

aww

Adám

I know. That's why I have a proposal to fix it a bit.

Sʨɠɠan

okie. aoc 2021 day 1 part 2: +/(</⊢)⌺2⊢¯1↓1↓(+/⊢)⌺3⊢data

any comments?

Adám

(</⊢)⌺2 is 2</

¯1↓1↓(+/⊢)⌺3⊢ is 3+/

+/2</3+/data should work.

Sʨɠɠan

18:07

waiit whaat?

reduction has a window option?

Adám

Yes, left arg is window size, but step size is always 1, and it cannot overhang edges.

Sʨɠɠan

thats exactly what i need

learn something new every day™

@Adám indeed it does work

Adám

:-)

Adám

19:03

@Sʨɠɠan Next year, you could participate in the APL Problem Solving Competition. Maybe you'd eventually be interested in an APL internship? Many companies that use APL are desperate for more APLers…

Sʨɠɠan

19:14

what is the APL Problem Solving Competition?

as for an internship, i wont until at least im out of high school :P

Adám

In general, you can find out about things that relate to APL on the wiki, e.g. apl.wiki/APL_Problem_Solving_Competition.

Sʨɠɠan

mhm thanks

« first day (2101 days earlier) ← previous day next day → last day (850 days later) »

all rooms