The APL Orchard

Adám

12:33 PM

@rak1507 Fixed in 19.0

pmikkelsen

Here is a fun (silly) way to divide by an integer {(⍎1↓⊃,⌿⍵⍴⊂'++')⍣¯1⊢⍺}

Adám

3:00 PM

Welcome to APL Quest 2016-3! Today's quest is Statistics - Mode:

> Write a function that takes a numeric vector or scalar as its right argument and returns the mode of the array.

Richard

 {c←{⍺ (≢⍵)}⌸ ,⍵ ⋄ c[;1]/⍨c[;2]⍷⍨⌈/c[;2]}

Adám

At least, this time, we don't have to special-case the empty argument.

@Richard Why ⍷?

Richard

To find where the highest value's are

Adám

Sure, but that's the same as =, no?

Richard

ah, yes ...

Adám

3:03 PM

X f g X can be written f∘g⍨X

Steve Allen

Good morning!

Adám

Hello!

You're just in time for the quest.

Steve Allen

Yep. Finally able to make one.

:)

Richard

Hey Steve

Steve Allen

Hey Richard

Adám

3:05 PM

@Richard Can you see how you can use my f g hint?

Richard

looking at it. f = '=' and g = ⌈/

Adám

Yes.

Richard

c[;2] = X

Adám

Just watch out for binding strengths.

Richard

Ans is ⌸ necessary? Or is there a better way to count them?

Adám

3:08 PM

I think that's best. Otherwise you need an outer product.

Richard

yes

Adám

There are other ways to use ⌸ though, and other ways to use its result.

Richard

Trying to replace with your suggestion but is not working yet. I'm not so fast, sorry

Adám

What did you try?

Richard

c[;1]/⍨=∘⌈/⍨c[;2]

Adám

3:12 PM

Ah, binding strength indeed: ⎕←=∘⌈/⍨

Richard

parenthesis I also tried

TryAPL

@Adám
     ⍨
   ┌─┘
   /
 ┌─┘
 ∘
┌┴┐
= ⌈

Adám

So ∘ is binding = to ⌈ and that becomes the operand for /.

Richard

{c←{⍺(≢⍵)}⌸,⍵ ⋄ c[;1]/⍨=∘(⌈/)⍨c[;2]}

Adám

Yes! You want ⌈/ to be the operand of ∘.

Now, what if you named the values and the tallies separately? (v t)←…{⍺(≢⍵)}⌸

Btw, since all values are simple scalars, you can use {⍺,≢⍵}

Richard

3:15 PM

then c[;1] becomes v and c[;2] becomes t

Adám

Right. What could you write where I put "…"?

Steve Allen

I'm thinking something like this: {(v t)←{⍺,≢⍵}⌸⍵ ⋄ (t=⌈/t)/v} But I'm getting a Rank error on the assignment.

Adám

Right, because you're trying to put a matrix into a vector (list of names).

So you need to convert the 2-column matrix to a 2-element vector.

Steve Allen

Ah, right. Gimme a sec

Richard

⍉

Adám

3:17 PM

That's half of one way to do it.

Richard

no

Steve Allen

{(v t)←↓⍉{⍺,≢⍵}⌸⍵ ⋄ (t=⌈/t)/v}

Adám

Very nice.

Richard

↓⍉

Adám

Another way to do it is ,⌿ — do you get why?

Steve Allen

3:19 PM

viz?

Oh .... is assignment actually a function?

Adám

Namely‽

I mean (v t)←,⌿{⍺,≢⍵}⌸⍵

Steve Allen

Oh, right. That makes sense.

Which is faster?

Adám

I'd guess ,⌿ because it can directly extract the data. ⍉ can be expensive as it has to shuffle all elements.

Steve Allen

hm.....that makes me wonder if that can't just be put into the key's left function.

Adám

Not really. It returns one major cell per unique element.

Steve Allen

3:22 PM

Oh ok

Adám

However, we can (ab)use that in a different way.

Steve Allen

LOL I love abusing functions for fun and profit. :P

Richard

@SteveAllen this is very readable, nice

Adám

Instead of finding the counts, lets just show the indices: ⎕←{⊢⌸⍵}¨(3 1 4 1 5)(2 7 1 8 1 8 1 8)

TryAPL

@Adám
┌───┬─────┐
│1 0│1 0 0│
│2 4│2 0 0│
│3 0│3 5 7│
│5 0│4 6 8│
└───┴─────┘

Adám

3:24 PM

Do you understand this result? In particular, what are the 0s?

rak1507

{∧/u←≠⍵: ⍵ ⋄ ∇⍵/⍨~u} doesn't seem to work on the site, but I don't get why

{∧/u←≠⍵: ⍵ ⋄ ∇⍵/⍨~u} should have returned 7 with (7) as right argument

Adám

Oh, clever.

@rak1507 The problem is that it should return a vector of the modes. Returns a scalar for a scalar.

Richard

@Adám no not yey, cause I am still stukc at the ⊢⌸⍵

Adám

Oh, that's just {⍵}⌸

rak1507

@Adám ah :/

Adám

3:27 PM

@rak1507 If you use ⌿ it'll even work for any rank.

rak1507

does it require sorted order too?

Adám

So, before, we were counting the occurrences: ⎕←{{≢⍵}⌸⍵}¨(3 1 4 1 5)(2 7 1 8 1 8 1 8)

TryAPL

@Adám
┌───────┬───────┐
│1 2 1 1│1 1 3 3│
└───────┴───────┘

Adám

@rak1507 Not sure. It doesn't say.

Here are the indices themselves: ⎕←{{⊂⍵}⌸⍵}¨(3 1 4 1 5)(2 7 1 8 1 8 1 8)

rak1507

sorting seems to work, but also just order of occurrence too

TryAPL

3:29 PM

@Adám
┌───────────┬─────────────────┐
│┌─┬───┬─┬─┐│┌─┬─┬─────┬─────┐│
││1│2 4│3│5│││1│2│3 5 7│4 6 8││
│└─┴───┴─┴─┘│└─┴─┴─────┴─────┘│
└───────────┴─────────────────┘

rak1507

{∧/≠⍵:,⍵ ⋄ ∇⍵/⍨~⌽≠⌽⍵}

Adám

The ⊂ is necessary because ⌸ returns a major cell per element, so we'd get a matrix. However, matrices cannot be ragged; it has to pad them, and will do so with 0s.

Steve Allen

@Adám Are the two vectors as input intended to indicate two different inputs, or something else?

Richard

@Adám one column for each occurence

Adám

@SteveAllen Yes, note the ¨ — they are just two test cases.

@Richard Exactly! So the rightmost column will have indices for the modes (together with a bunch of 0s).

All we need to do is isolate that rightmost column and remove the 0s.

Steve Allen

3:32 PM

Which is a compress

Adám

You don't even need that. Set different will do.

rak1507

{⍵/⍨~(⊢>∧/)⌽≠⌽⍵}⍣≡

Steve Allen

⍵[0~⍨⊢⌿]

Adám

⊢⌿ gives the bottom row, so you need ⊢/

Yes. ⎕←{0~⍨⊢/⊢⌸⍵}¨(3 1 4 1 5)(2 7 1 8 1 8 1 8)

TryAPL

@Adám
┌─┬───┐
│4│7 8│
└─┴───┘

Adám

3:35 PM

⎕←{⍵[0~⍨⊢/⊢⌸⍵]}¨(3 1 4 1 5)(2 7 1 8 1 8 1 8)

TryAPL

@Adám
┌─┬───┐
│1│1 8│
└─┴───┘

Richard

:)

Adám

@rak1507 Will be even nicer with ⍛

rak1507

and under

rabbitgrowth

I had (⊣/(/⍨)∘(⊢=⌈/)⊢/),∘≢⌸

Adám

3:37 PM

By why not ~ & > → ≤?

Steve Allen

@Adám Right. I'm slow. :)

Richard

@Adám only doesn't like a scalar or ⍬. but can be fixed

rak1507

oh, ~(⊢>∧/) can be (~∨∧/)

Steve Allen

{⍵⌷⍨⊂0~⍨⊢/⊢⌸⍵} appears to work, too.

Adám

@Richard Right, easy with only one ⍵?

@SteveAllen Yes, and that's better because it works for high-rank arrays.

@rabbitgrowth That's the tacit edition, yes.

@rak1507 Or (⊢≤∧/), no?

Steve Allen

3:40 PM

@Adám Suffers from the same problem @Richard pointed out though, re scalars & ⍬

rak1507

@Adám yeah

Adám

(Oh, wait, there are two ⍵.)

@SteveAllen You can fix that with 1/⍵ — a trick to convert a scalar into a 1-element vector, all other arrays staying as they are.

@rak1507 ∧/⍛≥⍤≠⍢⊖⍛⌿⍣≡?

rak1507

that's more like it!

Adám

Look ma, no trains!

OK, one more trick before we stop. {(v t)←↓⍉{⍺,≢⍵}⌸⍵ ⋄ (t=⌈/t)/v} can be done without assignment.

Since we only have two arrays, and ↓⍉ or ,⌿ gives them as a vector, we can use reduce to insert a function between them.

Steve Allen

@Adám {⍵/⍨{≢⍵}⌸⍵}, right?

Adám

3:47 PM

Uh, that's not a full solution.

Steve Allen

oops forgot the max

Adám

And you'll get a mask for the unique elements, not the original array.

Rather unfortunate to have to do ∪⍵ when ⌸ already did that internally.

So we can write {⊃{(⍵=⌈/⍵)/⍺}/↓⍉{⍺,≢⍵}⌸⍵}

OK, fine, one more thing: {⍺,≢⍵} is ,∘≢

???

Regarding what?

,∘⌸

3:50 PM

That's not what I wrote.

Richard

ah, tired eyes

Adám

Shall we call it a day, then?

Richard

Some attention to the weekgolf page? one vote short

Steve Allen

link?

Adám

week.golf/newLanguage.php

Steve Allen

3:52 PM

@Adám Has it been an hour already? Dang ... time flies. :)

@Adám Thanks

Adám

See you next week for 2016-4: Just Meshing Around. Don't forget that we'll start 2 hours earlier, beginning in 4 weeks, 14 October.

Richard

thanks, next week!

Adám

Statistics - Median (APL Quest 2016-2)

►

Jeremy gee

6:32 PM

Was a little confused by the cyclic reshape. But I think I understand now.

Transcript for