The APL Orchard

PyGamer0

10:00

how do i write {⍵ ⍵⍴⍳×⍨⍵} tacitly?

ok i got the rightmost part

⍳⍤×⍨

,⍨ is the ⍵ ⍵ part

and now i'm stuck

@Adám ^ help

Adám

@PyGamer0 ,⍨⍴⍳⍤×⍨ :-)

@JayantChoudhary Welcome to the APL Orchard!

PyGamer0

@Adám and here i was using atop, and beside :/

Adám

This is exactly the type of job where which forks shine.

PyGamer0

10:32

@Adám so is ,⍨⍴⍳⍤×⍨ a 3 train?, and it consists of ,⍨; ⍴ and ⍳⍤×⍨?

Adám

That's correct: ⎕←,⍨⍴⍳⍤×⍨

TryAPL

@Adám
  ┌─┼─┐
  ⍨ ⍴ ⍨
┌─┘ ┌─┘
,   ⍤
   ┌┴┐
   ⍳ ×

Adám

Note the ┌─┼─┐ on the first line, indicating a 3-train.

Adám

11:07

@FawnLocke I'm adding links to your vocabulary on APL Wiki. How do you want to be named there? Fawn "awagga" Locke?

Jayant Choudhary

Hey there @Adám here from discord

Adám

Nice.

PyGamer0

does ravel mean flatten?

whats the difference between ravel and enlist?

Adám

11:26

@PyGamer0 Ravel (,Y) is equivalent to ×/⍤⍴⍴⊢ while Enlist (∊Y) discloses all enclosures and returns a depth-1 vector.

Fawn Locke

@Adám Yeah, that sounds good.

Master Quiz

12:36

Tacifying this {(⍴⍵),⊂⍸<⍀' '≠⍵}↑' *'[?5 5⍴2]
Can I do better than (⍴,⊂∘⍸∘(<⍀' '∘≠))↑' *'[?5 5⍴2]?

Adám

@MasterQuiz What is ↑ supposed to do here?

@MasterQuiz ⍴,⊂∘⍸∘(<⍀' '∘≠) → ⍴,∘⊂∘⍸<⍀⍤≠∘' '

Master Quiz

@Adám Nothing, I was doing ↑ followed by random strings

@Adám Can you explain this? I'm lost from ⍸, and the tree version confused me much more

Also on TryAPL it isn't rendered correctly ⋄⍴,∘⊂∘⍸<⍀⍤≠∘' '

TryAPL

@MasterQuiz
┌─┼────┐
⍴ ∘    ∘
 ┌┴┐ ┌─┴─
 ∘ ⍸   ⍤
┌┴┐   ┌┴┐
, ⊂   ⍀ ≠
    ┌─┘
    <

Adám

Ugh, that's pretty bad.

@user9691923 Hi Syd ElCid. If you want to participate here, please email [email protected]

Master Quiz

@Adám It eliminates quotes. Also here ⋄⍴,∘⊂∘⍸<⍀⍤≠∘'1' ⋄'-----' ⋄⍴,∘⊂∘⍸<⍀⍤≠∘1

TryAPL

12:46

@MasterQuiz
┌─┼───┐
⍴ ∘   ∘
 ┌┴┐ ┌┴┐
 ∘ ⍸ ⍤ 1
┌┴┐ ┌┴┐
, ⊂ ⍀ ≠
  ┌─┘
  <
-----
┌─┼───┐
⍴ ∘   ∘
 ┌┴┐ ┌┴┐
 ∘ ⍸ ⍤ 1
┌┴┐ ┌┴┐
, ⊂ ⍀ ≠
  ┌─┘
  <

Adám

@MasterQuiz You want to apply a bunch of monadic functions to the result of ≠ but ⊂∘⍸∘<⍀∘≠ doesn't work because < is bound to the left. Instead, we make ⊂∘⍸ a pre-processor for the right argument of , as ,∘⊂∘⍸ and move the space to the other side of ≠ (it is commutative) and make <⍀ a post-processor for ≠ as <⍀⍤≠

Fawn Locke

Adám are there any ways in which you think the train trees could be improved? (Just curious)

Adám

Yeah, I think it'd be helpful if 2- and 3-trains had the "root" function in the junction.

Fawn Locke

Gotcha

Adám

E.g.

  ┌─┼─┐
  ⌿ ÷ ≢
┌─┘
+

could be

  ┌─÷─┐
  ⌿   ≢
┌─┘
+

Fawn Locke

12:52

Mhm, I think that's nice. Almost makes trains self-explanatory

Adám

or possibly

    │
  ┌─÷─┐
  ⌿   ≢
┌─┘
+

or

    ÷
  ┌─┴─┐
  ⌿   ≢
┌─┘
+

Similary

  ┌┴┐
  / ,
┌─┘
+

could be

  ┌,
  /
┌─┘
+

or

   │
  ┌,
  /
┌─┘
+

or

   ,
  ┌┘
  /
┌─┘
+

or even

  ,
  │
  /
┌─┘
+

Master Quiz

@Adám Still can't got ,∘... I'd imagine it as monadic

Fawn Locke

Interesting, thanks! I think the last revision of +⌿÷≢ is my favourite. Not sure about the 2-trains

Adám

@MasterQuiz f∘g is equivalent to f except that g is used to preprocess the right argument of f just before f is applied..

@FawnLocke Agreed.

Master Quiz

@FawnLocke +←1

PyGamer0

12:59

@Adám i like this

@Adám imo this is best

Master Quiz

@Adám I've never thought of trains like this

Adám

That's not trains, that's apl.wiki/Function_composition

But yes, it all became much clearer to me when I realised that

f⍤g uses f to post-process the result of g

f∘g uses g to pre-process the right argument of f

f⍥g uses g to pre-process both arguments of f

And then we realise that there's a missing composition:

f⍛g uses f to pre-process the left argument of g

PyGamer0

@Adám knew it you would mention that

what about under?

Adám

That's not a pure composition, as it doesn't just apply functions.

Fawn Locke

That's a nice way to remember them. I always just thought of them in terms of derived functions

Adám

13:05

f⍢g is g⍣¯1⍤f⍥g

PyGamer0

@FawnLocke imo diagrams of these compositions are easier to understand

Fawn Locke

I agree

Adám

Too bad I've lost the source for the APL Wiki diagram.

Kamila Szewczyk

@Adám i was always wondering what's the difference between this and the structural under

structural under seems much more powerful if i understand it all right

PyGamer0

now whats structural under?

Adám

13:07

@KamilaSzewczyk Yeah, I personally regard computational under as a cute trick, but structural under is genuinely useful.

@PyGamer0 Same thing, but g is a selection/structural function.

E.g. -⍢(¯2∘↑) would negate the last two.

Fawn Locke

@Adám ⍙ ← {⍵⍵⍣¯1⍤⍺⍺⍥⍵⍵} heh

PyGamer0

Adám

@FawnLocke Unfortunately, dfns can't return functions, so you have to write {⍺←⊢ ⋄ ⍺ ⍵⍵⍣¯1⍤⍺⍺⍥⍵⍵ ⍵}

PyGamer0

@PyGamer0 lol

Fawn Locke

Ah, true

PyGamer0

13:11

@Adám why not make a new one?

Adám

Yeah, I'll have to.

Kamila Szewczyk

"cute APL" brought me an interesting chain of thought/silly logo idea for APL

Adám

Hurry up then; only a couple of days left!

Kamila Szewczyk

oh no, please don't pick this one

Adám

Hey, I've uploaded logos I definitely don't want.

Fawn Locke

13:14

Will the next BAA webinar discuss the logo? Haven't kept up to date about voting, etc. I'll check out the logo wiki page

Adám

I think the next BAA webinar will announce that the polls are open.

Fawn Locke

Good to know :)

PyGamer0

is this right?

Adám

Looks right to me.

PyGamer0

ok what happens if f⍛g is called monadically?

Adám

13:24

⍛ doesn't really exist.

Kamila Szewczyk

i think the eyes should be maybe a bit bigger and lower

but otherwise, cute APL concept has been finished

PyGamer0

o_o

Kamila Szewczyk

that's the most cursed thing i made this week

Fawn Locke

Oh dear

PyGamer0

post it in TNB

lol

Adám

13:28

@KamilaSzewczyk How do you expect me to sleep now‽

Kamila Szewczyk

HAHAH

PyGamer0

is that an evil laugh?

Kamila Szewczyk

no, it's just a "this is hillarious" laugh

Adám

@PyGamer0 There are a couple of options. E.g. back-hook {⍺←⍵ ⋄ (⍺⍺ ⍺)⍵⍵ ⍵} and the questionably useful {⍺←{⍵ ⋄ ⍺⍺} ⋄ (⍺⍺ ⍺) ⍵⍵ ⍵}

Fawn Locke

What did you go with in Dyalog extended?

Adám

13:32

The latter.

PyGamer0

@Adám well if this is different from the other 3, i think the other 3 should be unique

Adám

@PyGamer0 I don't understand.

Kamila Szewczyk

@Adám so, will my logo be featured on the suggestions page? /s

Adám

@KamilaSzewczyk It clearly blows they others out of the water. Why don't we just use that and forget this whole election process‽

Kamila Szewczyk

I wholeheartedly agree

Adám

13:34

Fun fact: /// is a valid function.

Kamila Szewczyk

now that's surprising

reduce of reduce of scan?

Adám

No, N-wise reduction reduction.

Kamila Szewczyk

oh!

fun

i don't know why i said scan tbh

clearly there's no \

Adám

And if used dyadically, it is N-wise N-wise reduction reduction.

Fawn Locke

function/operator overloading is terribly cursed sometimes :)

Kamila Szewczyk

13:36

almost as cursed as the unspeakable logo

Adám

⋄ /// ,42 ⋄ 1/// ,42

TryAPL

@Adám
42
42

Fawn Locke

Being able to pass a derived function to an operator which is later treated as an operator is amazingly bad

Adám

Oh you mean like ⋄ /{+⍺⍺⍵}1 2 3

TryAPL

@Adám 6

Master Quiz

13:42

@Adám This is kinda funny, the new symmetric generation ⋄1, \\∘/⍤\∘// ,1⋄

TryAPL

@MasterQuiz 1

Fawn Locke

Yes

Adám

I wouldn't call that amazingly bad. I've never experienced it giving any trouble.

It is / (when intended as function) catching the function on its left that is problematic.

@MasterQuiz You've seen the grand palindromic phi video, right?

Master Quiz

@Adám Sure

Adám

@PyGamer0 @FawnLocke Any other ideas for what f⍛g Y should do?

Fawn Locke

13:44

Yeah. I think it's one of the uglier aspects of APL tbh, I can get over ⎕IO and such historical baggage. If only John Scholes had advocated for first class functions

Adám

The good thing is that it is easy to fix through addition of glyphs. ⫽←{⍺⌿⍵} and ⑊←{⍺⍀⍵}

Fawn Locke

I'm not sure. Give me a moment to think on it

Kamila Szewczyk

@Adám i don't think there are any useful functional combinators besides the ones APL already has

dzaima

@KamilaSzewczyk well, the {⍺←⍵ ⋄ (⍺⍺ ⍺) ⍵⍵ ⍵} one is certainly very useful, from my experience with ⊸ in BQN

Kamila Szewczyk

all the fancy stuff e.g. in Haskell, like Kleisli composition depends on monads and a sane side effect model which isn't a thing in APL for good

@dzaima hmm, so it's like beside, but reversed?

and forced to a "dyadic" case

Adám

13:56

Yeah, it'd be a hook out of the box, so you don't need ⍨

milia

@KamilaSzewczyk kill it with fire xd

Kamila Szewczyk

@Adám i don't think i ever needed this sort of construct

dzaima

@KamilaSzewczyk (f⊢⍤/⊢), i.e. a filter, could be f⍛/

Kamila Szewczyk

I always wrote filter as a dfn

Adám

I was about to write ^ and also ⌽⍛≡ for palindrome checking. Similar pattern for lots of other such "property checks"

Kamila Szewczyk

13:59

well, fair enough i guess

dzaima

@KamilaSzewczyk well, you would indeed always write anything that sucks to write in one way, in a different way

Kamila Szewczyk

lol

I swear, APL occupies a different part of my brain than esolangs :)

dzaima

random translated examples from my BQN AoC solutions: ⊃⍛=; (-2|≢)⍛↑; ≢⍛-; «⍛f (where « is 0,⍨1↓); f⍛⊆ (where ⊆ is Sane Indexing), and like 29 filters

Adám

14:16

Further examples from APLcart: ×⍛| +⍛= ⌊⍛= +⍤≠ ∪⍛≡ ∪⍛⍳ ⍉⍛≡ ⍕⍛≡ ⌈⌿⍛= ∪⍳⍛∨ ≠⍀⍛∨ ⍳∘≢⍛, ⊃∘⍋⍛⌷ ⊂∘⍋⍛⌷ ⍋∘⍋⍛≡ etc.

PyGamer0

@Adám so in short: reverse composition is useful for code golfing

Adám

Every composition can be written as a dfn/dop, so yes, I guess.

Still, ⍛ "fixes" ⌷ as ⊂⍛⌷ much like ⍤ fixes / as ⊢⍤/

Kamila Szewczyk

what is ⌷ anyway

the RIDE description of it is incredibly bad

i know that you can use it for indexing, and that's it

mostly describes "materialize" which looks super irrelevant

dzaima

that's the monadic case

Kamila Szewczyk

hmm, i think i know why squad index requires ""fixing""

but I like the brace indexing syntax much more

dzaima

14:30

⊂⍛⌷ is for the dyadic case

Kamila Szewczyk

shame we can't use it in tacit expressions - never wondered why

dzaima

the brace syntax does not at all work in trains

Kamila Szewczyk

i guess so

but we could make it work with trains, couldn't we?

dzaima

⍺(⊂⍛⌷)⍵ does ⍵[⍺]

@KamilaSzewczyk nope

Kamila Szewczyk

(by special casing a few things, i meant)

@dzaima yeah, but bracket indexing also has ;

dzaima

14:31

funcion axis conflicts

Kamila Szewczyk

oh, that.

i forgot anyone uses this.

dzaima

@KamilaSzewczyk right, and that's where things get slightly more complicated

Adám

⌷ is essentially a functional form of bracket indexing, such that x[a;b;c] is a b c⌷x

dzaima

but the vector[index list] case is plenty useful on its own

Adám

The problem is that more often than not, you want x[a;;] which then has to be (⊂a)⌷x

dzaima

14:33

@Adám oh yeah right it does that. But doesn't allow empty sections, which is like the by far most useful case

Adám

Ahem, that's my message ^^

Kamila Szewczyk

i think i still like bracket indexing more

Adám

It does allow trailing empty sections; just omit them.

dzaima

@Adám i'm working with like a 10s delay here, through my client & bridge :/

Adám

Ah, didn't know. Sorry.

It also (kind of, but sit down and guard your eyes…) allows skipping sections, because that x[a;;b] is a b⌷[1 3]x (!!!ugh!!!)

dzaima

14:36

@dzaima (i assume that's because i went the lazy route and used the built-in SQLite for synapse (matrix homeserver server), and not the fancy, but optional, postgres)

Adám

@dzaima J uses an additional level of enclosure to indicate inversion (all-but-these, like ^ in regex) so you can write a(⊂⍬)b⌷x for x[a;;b] and then adds a symbol for ⊂⍬ like Iverson retconned ∘ ("nil") to be in ∘.g — altogether a∘b⌷x which is pretty neat.

PyGamer0

14:52

ok how i do print the result of something in J

Try it online!

dzaima

@PyGamer0 tio.run/##y/r/PzU5I18hU0/B0OD/fwA

you can often use the "Hello World" button to get an example of how to print stuff

PyGamer0

oh

is there an apl version for this

dzaima

@PyGamer0 there's this massive thing

Adám

@PyGamer0 And also this nice thing

dzaima

oh yeaaah that exists now lol

PyGamer0

14:59

@Adám i saw the nice thing already :)

Adám

@PyGamer0 There's this but that's for GNU APL.

Kamila Szewczyk

@dzaima oh, you're talking through matrix?

would you mind sharing how did you accomplish this / do you have a room that i could join?

dzaima

@KamilaSzewczyk through a local homeserver & half-finished bridge

Kamila Szewczyk

oh, i see

dzaima

if someone could offer a public homeserver on which the bridge user could make accounts on, i could publish it

Kamila Szewczyk

15:03

i considered making my own homeserver, but i presume most of my friends wouldn't switch to matrix just to talk to me or something, so i never made it happen

PyGamer0

i cant find apl vs j in the j wiki

Richard

do you mean these?
https://help.dyalog.com/18.0/#Language/Primitive%20Operators/Operator%20Syntax.htm#Function_Composition

PyGamer0

Adám

@PyGamer0 That's rendered to png. I had a vector source once.

PyGamer0

@Adám ah you mean svg?

Adám

15:12

@PyGamer0 J4APL and APL2JPhraseBook.

PyGamer0

thanks

Adám

@PyGamer0 It wasn't SVG, but yes, something like that.

PyGamer0

can j be run from the command line?

Adám

I'm pretty sure it can

Kamila Szewczyk

use ijconsole

might depend on your version, for me it's /bin/ijconsole-9.02

PyGamer0

15:40

@Adám is the expected time for release of 18.2 around April?

Adám

I'd expect it even before that. It is basically ready to go.

PyGamer0

February?

Adám

Before, even.

PyGamer0

new year?

so in a couple of weeks?!

Adám

I expect release at some point during January.

Kamila Szewczyk

15:45

hype

PyGamer0

^

so someone forked vim-apl and added neo-layout keybinds

whats that?

oh its a german layout

Fmbalbuena

16:13

⎕←(-@⍳50)⍳100 errors

TryAPL

@Fmbalbuena
DOMAIN ERROR
      ⎕←(-@⍳50)⍳100
        ∧

Fmbalbuena

@Adám ^

Adám

@Fmbalbuena Operators bind their operands before any functions are applied, so this becomes ((-@⍳)50)⍳100. You need (-@(⍳50))⍳100. You don't actually need the outer parenthesis, because ⍳ separates: ⋄ -@(⍳50)⍳100

TryAPL

@Adám

¯1 ¯2 ¯3 ¯4 ¯5 ¯6 ¯7 ¯8 ¯9 ¯10 ¯11 ¯12 ¯13 ¯14 ¯15 ¯16 ¯17 ¯18 ¯19 ¯20 ¯21 ¯22 ¯23 ¯24 ¯25 ¯26 ¯27 ¯28 ¯29 ¯30 ¯31 ¯32 ¯33 ¯34 ¯35 ¯36 ¯37 ¯38 ¯39 ¯40 ¯41 ¯42 ¯43 ¯44 ¯45 ¯46 ¯47 ¯48 ¯49 ¯50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100

Fmbalbuena

thanks

Fawn Locke

16:39

⋄ -@(≢↑(,∘~⍨0⍴⍨∘⌈.5×≢))⍳25

TryAPL

@FawnLocke 1 2 3 4 5 6 7 8 9 10 11 12 13 ¯14 ¯15 ¯16 ¯17 ¯18 ¯19 ¯20 ¯21 ¯22 ¯23 ¯24 ¯25

Adám

@FawnLocke Hairy, but -@(≢↑0,∘~⍨⍤⍴⍨∘⌈0.5×≢)⍳25

Fawn Locke

Couldn't figure out that last step, cool!

Adám

@FawnLocke -@(0 1/⍨∘(⌈,⌊)2÷⍨≢)

Fawn Locke

Ah, should've seen that.

Adám

16:47

@FawnLocke -@(≢↑1⍴⍨∘⌈2÷⍨≢)-

Kamila Szewczyk

@Adám as a followup, I think APL would benefit a lot if we allowed i.e. greek characters as glyph names

mainly because e.g. some quantities in mathematics are represented using these

Adám

@FawnLocke -@(⍳∘≢≥1+2÷⍨≢)

Fawn Locke

That's a fun one

Adám

@KamilaSzewczyk Yeah, I think so too, but there's of course the issue of ⍺∊⍳⍴⍵ vs αϵιρω

And also AΒΔΕΙΗΚΜΝΟοΡΤΖ vs AB∆EIHKMNOoPTZ

Of course, it is the programmers' responsibility to write sane code, but I bet my customer support colleagues will be very worried about this.

Adám

17:13

@KamilaSzewczyk How about only allowing non-confusables?

Kamila Szewczyk

@Adám that's a good idea

PyGamer0

^

Adám

Of course, it'll prevent/make it very awkward for Greek programmers to use "fake" Greek identifiers.

Per Wikipedia:

> Those Greek letters which have the same form as Latin letters are rarely used: capital A, B, E, Z, H, I, K, M, N, O, P, T, Y, X. Small ι, ο and υ are also rarely used, since they closely resemble the Latin letters i, o and u.

So we're only really talking about ΠΣΨΩγδεζηλμξπςσφχψϖ

Due to ⌽, both phi forms would probably need banning as some fonts reverse their looks! φϕ vs φϕ (they'll look switched if you're on Windows with default monospace rendering of Consolas)

Kamila Szewczyk

18:28

@Adám ϖ seems out of place on this list too

for the record, i also can't tell the difference between ⍣ and ⍤ when using shitty fonts.

Adám

@KamilaSzewczyk Why?

Kamila Szewczyk

confusable with omega?

Adám

ϖ you mean?

Kamila Szewczyk

except it renders like crap

Adám

It isn't in APL385.

Kamila Szewczyk

18:30

well, yeah

Adám

^ is APL386

But yeah, you're probably right, and it is pretty rare too.

Richard

21:10

What does ⎕R do?
And sometimes I see a ':' in a line of code.
Both I can't find in the manuals.

Master Quiz

@Richard It's replace. ⋄'_'⎕R' '⊢'Hi_there'

TryAPL

@MasterQuiz Hi there

Richard

Thanks!

Adám

@Richard Did you try pressing F1 on them?

(Just be aware that by default, ⎕R is regex replace. You can switch to plain-text replace using 'from'⎕R'to'⍠'Regex'0)

Richard

No, didn't now that :)

Adám

21:15

You can also type ]help thing like ]help ⎕r and ]help : and it kind of works with the bot too: ⋄]help :

TryAPL

@Adám help.dyalog.com/18.2/Content/Language/Symbols/Special Symbols.htm

Adám

and ⋄]help ⎕R

TryAPL

@Adám help.dyalog.com/18.2/Content/Language/System Functions/r.htm

Richard

ok thanks, I'll do my homework better next time with these lookup possibilities

Adám

How would you have known? Maybe there are even more tips you could use?

Richard

21:29

Thought I read most of the information, but probably forgot the most obvious.

For a new user (at least for me) it also is a little bit skattered. Some information is a bit outdated but a lot of good YouTube video's and manuals are indeed available.
Same can be said about the exercises.

But at the same time, maybe the APL info is much more organised compared to other languages because Dyalog is the major player, and most of the info is arranged around them.

By the way, the APL tips is the first link at the 'getting started' menu, so not very bright of me...

Slowly getting there :)

Transcript for