The APL Orchard

Elias Mårtenson

10:00

What is the difference between (FN0 FN1) and (FN0∘FN1) ?

They seem to be identical to me.

dzaima

@EliasMårtenson the dyadic case ⍺(f g)⍵ is f ⍺g⍵ whereas ⍺(f∘g)⍵ is ⍺ f g⍵

but there also is ⍤, for which f⍤g and (f g) are exactly identical (except required parentheses, usability in trains, grouping, etc)

Elias Mårtenson

So it seems to be identical to FN0⍤FN1 ?

Ao assuming all uppercase letters are functions, how is (A B C D E) parsed?

dzaima

@EliasMårtenson yep, that's what i said

Elias Mårtenson

@dzaima Yeah, I saw. I was testing while you typed it.

dzaima

@EliasMårtenson (A B (C D E))

Elias Mårtenson

10:04

I see.

dzaima

a 2-train is only ever parsed as the leftmost thing in a train

Elias Mårtenson

Got it.

J does things differently right? I seem to recall it having 5-forks and stuff?

dzaima

so 2-trains must almost always be parhenthesized to add anything more to them, and that's where ⍤ comes in to be a bit more helpful

Bubbler

Related: Clearly parenthesize APL trains

@EliasMårtenson There's no special 5-forks in J. 3-forks are the same, and 2-forks happen to be different

J: x(f g)y → x f (g y), (f g)y → y f (g y)

And a special case for a 3-fork in J is a "capped fork" [: g h, which is the same as a 2-train in APL.

Normally the cap [: is a function that always errors.

(In all the examples, f g h are functions and x y are arrays.)

Adám

10:25

And the J 2-train is simply ⊣ f g in APL.

Elias Mårtenson

10:49

@Adám I see. I always found J trains incomphrehensible.

Elias Mårtenson

11:00

Can someone help me write a very simple test of a 2-train where the code is X (A B) Y and the result is either a scalar number or an array of numbers. The question is what A, B, X and Y should I choose such that any change in order of X and Y or A and B would result in a different result?

The input should be integers (or arrays of integers) and the output should be scalars or arrays of integers as well. The reason for that is that the same test is run multiple times with different array specialisation to ensure that optimisations are correct.

dzaima

@EliasMårtenson 2(-*)6 should work

RGS

3 (⍴-) 5

Elias Mårtenson

@dzaima Thanks. I'm going with this one.

@RGS Thanks. This one suffers from a different limitation that I never made clear: If I replace the input with 3.0 and 5.0, the output is still integers.

RGS

@EliasMårtenson np, I did my best :P

dzaima

@EliasMårtenson does your * output integers on integer args?

Elias Mårtenson

11:07

@dzaima No, not at the moment. But it should.

As long as the output fits in a 64-bit integer.

It seems I've managed to implement 2-trains and 3-trains in Kap that matches Dyalog behaviour.

Wezl

13:29

@Adám no, spiderwire has a few APL characters but not enough

ngn

13:45

@Wezl does it have static html hosting?

Wezl

@ngn yes

docs.codeberg.org/codeberg-pages

ngn

@Wezl i'm in :)

xpqz

@Wezl well spotted :) I only took it up as I saw you used them. Nice and simple, and you can have private accounts. I like it so far.

Wezl

Now would be the time where I make a contract with them, if they weren't non-profit :)

nathan rogers

15:43

is there a way to retrieve a list of cells using squad without each?

dzaima

@nathanrogers do you want a vector of all cells, or specific ones by indexes?

nathan rogers

I want to retrieve indies in a particular order without using arr[idns]

dzaima

@nathanrogers (⊂inds)⌷arr?

nathan rogers

thanks @dzaima

This was a fun silly problem. adventofcode.com/2015/day/3

s03←{≢∪+\(⊂0 0),(⊂'v<>^'⍳⍵)⌷,∘.,⍨¯1 1} how would you go about golfing this?

example inputs with expected results:
s03_tests ← ('' 1)('<>' 2)((400⍴'<>') 2)('^v' 2)((400⍴'^v') 2)('<^v>' 3)('<^v<' 4)('^>v<' 4)
s03_tests,← ((4⍴'^') 5)(('<^'[?500⍴2]) 501)

I don't see anything obvious that stands out, but my golfing technique bag is small

Marshall

16:04

@dzaima Added a few new system functions to the spec. •Eval and •Fmt are new names for ⍎ and ⍕, and •BQN and •Using are new functions (I don't think •BQN can be written easily in terms of •Eval because it needs to block out parent scopes). I think these are all reasonable names but maybe there are better ones.

I couldn't figure out what the left arguments to dzaima/BQN's ⍎ are; could you explain them?

dzaima

@Marshall a vector •args‿•name‿•path because Reasons™

(i didn't remember either, i just followed through the chain of calls on github ¯\_(ツ)_/¯)

Razetime

@nathanrogers maybe (⊂0 0), to ↓0⍪↑?

Marshall

@dzaima I guess •path‿•name‿•args is easier to remember because it follows the ordering you'd have in a shell call. I've only ever used •path so that works out well for saving typing too.

nathan rogers

@Razetime then I can get rid of the↓ and just use +⍀

great

Adám

@nathanrogers Can (⊂0 0), not be 0, ?

dzaima

16:10

@Marshall i've used none, the left arg is just directly the internal format of file-specific data ¯\_(ツ)_/¯

Elias Mårtenson

I have just updated kapdemo.dhsdevelopments.com with a version that implements the Dyalog-style trains. I'd be very happy if someone could write a few expressions to see if it does the right thing.

nathan rogers

@Adám no because each cell is a 2vec

Elias Mårtenson

Since I don't normally use these features myself.

nathan rogers

of permutations of 1 and ¯1

Adám

@nathanrogers Ah, but if you do ↑ as per Razetime, then 0⍪ should work.

nathan rogers

16:11

s03←{≢∪+⍀0⍪↑(⊂'v<>^'⍳⍵)⌷,∘.,⍨¯1 1}

yeah that had the nice effect of eliminating the ↓ by using ⍀

Adám

@nathanrogers You might get away with going tacit there.

Probably not shorter, though.

Nah, too many monadic calls.

dzaima

@EliasMårtenson there's also the (A f g) train, with which (¯1+≢)"abc" would be 2

Adám

Or in 18 words, A f g is A⍨f g

dzaima

@Adám well, Kap doesn't have A⍨ either ¯\_(ツ)_/¯

Razetime

@Adám I can only count 7 words there ⍨

dzaima

16:15

@Razetime 18≡18.0 in APL :)

Razetime

:P I know

dzaima

@EliasMårtenson unrelated: ,(∘.×⍨⍳4) works, but ,∘.×⍨⍳4 doesn't

Adám

@EliasMårtenson Didn't you kill ∘.?

nathan rogers

16:28

@Adám do you have a link to 2015 APL solutions? I see something in APL cart, but not specifically for 2015

watched JF's video becaues of aplcart. Such a neat tool you've built up

Adám

@nathanrogers 2015 what? Competition?

xpqz

@nathanrogers You can have mine

nathan rogers

sorry, Advent of code

Adám

@nathanrogers apl.wiki/aoc

xpqz

github.com/xpqz/AoCDyalog <-- 2015-20

Razetime

16:30

bubbler has most of them I think

github.com/Bubbler-4/advent-of-apl

Adám

Guys, they are all on the wiki.

Razetime

ah yeah

Adám

@nathanrogers you mean aplcart.info/pub? That's just placeholder data. I wish I had the time to actually populate that table to the same level of completion as main APLcart.

Razetime

hmm I can help with that

Adám

@Razetime Knock yourself out

Razetime

16:35

hoo boy

xpqz

The wikilink to @ngn's solutions is dead -- what should it be, or have you binned them, @ngn?

nathan rogers

@Adám is there some way to set an entry point to a namespace? as in just call the namespace as a function?

Adám

@nathanrogers No. That'd always return a reference to the namespace. However, you can have a class with a default property (which when queried is simply a function call) that you can invoke with ⌷

nathan rogers

I thought ⎕IO is inherited from the root NS?

something up with link, setting ⎕IO in root directory doens't solve things

nathan rogers

17:54

@Adám potentially linking namespaces before ⎕.a files means that they get the default ⎕ settings when imported, and not effected by linking ⎕.a files?

how do I tell dyalog where to look for text files when using things like ⎕NGET?

aside from specifying the fully qualified path

dzaima

18:16

@nathanrogers ]cd

nathan rogers

]link my stuff
]cd to mystuff
read mystuff

this is a lot to do every time I load in a project

what do you recommend?

dzaima

@nathanrogers no clue how Dyalog is supposed to use relative file paths properly. There's ⎕SE.Dyalog.Utils.CD, equivalent to ]cd which you could insert in your code, but that's also ugly (and the source has a comment of "use at your own risk!"..)

@nathanrogers if you want to just run something on it being loaded, you can write arbitrary code within :namespace

nathan rogers

just name is like, zzz.apln or something?

folders are first then files, so I think that's the right way to do it

dzaima

@nathanrogers no clue about extension conventions. Anything works probably

Elias Mårtenson

18:33

@Adám I didn't. I realised it was easy to keep it. I might yet do so :-)

@dzaima I'm going to have to investigate that one tomorrow. I'm going to sleep now :-)

Thanks for finding issues.

@dzaima I currently have no support for having a left argument in a train. It should be implementable, but I haven't bothered with it yet.

dzaima

@EliasMårtenson right. I just wanted to let you know that it's a thing and that it's useful

Elias Mårtenson

@dzaima It doesn't have it, because GNU APL doesn' thave it as far as I know so I never used it :-)

dzaima

@EliasMårtenson A⍨ is a pretty recent thing (always returns A). It's useful in trains - e.g. (⊢*3⍨) for a cube function as a simple example, and also 2⍨¨A for replacing each item of an array with 2

Elias Mårtenson

@dzaima OK, now I know why it doesn't work. I don't think it'll be possible to make it work. The reason is that it parses from left to right, so it first sees , which is a function. It then checks for applicable operators and finds ∘ which is a dyadic operator. It then recurses down to find the right argument to the operator, but finds . and it fails.

There is no backtracking to try to parse it in a different way.

@dzaima But {A} is just one character more, and more readable in my opinion?

dzaima

@EliasMårtenson but it must re-evaluate A every time it's executed

Elias Mårtenson

18:44

@dzaima Also, you can write that code like this instead, which is more concise and clear: ,×⌺⍨⍳4

@dzaima That's not really a problem in Kap :-)

dzaima

@EliasMårtenson right

@Marshall my ⍕ (well, the monadic version) currently isn't something i'd call "format". It only accepts as an argument numbers, and character atoms/vectors/matrices, and nothing else

Elias Mårtenson

OK, sleep time.

dzaima

@Marshall "The effect of •Eval should be the same as if its argument were written as source code" you don't expect a←1 ⋄ {•Eval"a←2"⋄a} to return 2, do you?

Elias Mårtenson

@dzaima "written as source code in a toplevel scope" perhaps?

Similar to how Common Lisp performs eval in a "null environment".

dzaima

@EliasMårtenson that'd be the behavior of •BQN, but that's explicitly about •Eval

Elias Mårtenson

18:53

@dzaima That's how I expect it to work in APL, but to be fair, I never tried.

I don't think I've ever used eval for real

(I mean, other than to parse numbers and such things)

dzaima

@EliasMårtenson In interpreted APLs (which include Dyalog and dzaima/APL), ⍎"abc" is pretty much literally equivalent to if abc was executed there directly instead

Elias Mårtenson

@dzaima dzaima/APL has lexical closures, doesn't it?

dzaima

@EliasMårtenson it does, but that doesn't stop ⍎ from working

Elias Mårtenson

@dzaima Yes, you're right of course.

But does that mean that when you close over a function, you preserve all variables, not just the ones referenced in scope?

Since you cannot determine which variables to capture in the closure.

dzaima

@EliasMårtenson "when you close over a function" the way variables are stored doesn't change between a function being executed and it being stored somewhere

@EliasMårtenson I can't determine that anyways

Elias Mårtenson

19:02

I mean like this (in Kap): { a←1 ◊ b←2 ◊ λ{a+⍵} }⍬

In this case, I can return a closure that closes over a only. Since b isn't referenced in the scope of the lambda, there is no reason to capture it in the closure.

dzaima

@EliasMårtenson right. In that case, the outer function would create a Scope with a hashmap of a→1 and b→2, and that is used both while evaluating it, and as a reference to give to the inner function. There's zero concept of "closing" in dzaima/APL

Elias Mårtenson

@dzaima OK, I see. So when you use ⍎ that code will simply reference that same hashmap when looking up variables.

dzaima

since dzaima/APL is dynamically interpreted & typed, even with no ⍎ it couldn't understand whether, in { a←1 ⋄ b←2 ⋄ {a f←3 ⋄ a} }⍬, should the a be kept in the closure or not - that depends on whether f is a function or not, which can change afterwards

Elias Mårtenson

@dzaima Yes of course. I do spare myself a lot of trouble by not supporting that.

dzaima

@EliasMårtenson right. You have the luxury of an AST :)

Elias Mårtenson

19:07

It's really the thing that makes function invocation so much faster.

I wonder i fthere is some neat way to handle that in an interpreted APL. Perhaps one can cache the tokenised syntax tree, and only reparse if any of the referenced variables changed from value to function or vice versa. That should be a really rare occurence.

dzaima

@EliasMårtenson iirc something somewhere does that

Elias Mårtenson

@dzaima Dyalog doesn't seem to.

And GNU APL don't either.

dzaima

@EliasMårtenson Not dyalog of course. But its function evaluation is fast enough

Elias Mårtenson

@dzaima I'm not sure. Compare the performance of +/V to {⍺+⍵}/V. The latter is horribly slow.

dzaima

@EliasMårtenson well, the former is vectorized and special-cased to no end too

Elias Mårtenson

19:11

Fair enough, but the latter is much slower than even Kap before specialised arrays were implemented (and with specialised arrays, it got 4 times faster)

dzaima

Dyalog does have function compilation and its own bytecode, but it's not much of an improvement

Elias Mårtenson

@dzaima My point is that Kap has no right to win that particular testcase. Since Dyalog is faster on pretty much everything else, there is something wrong with that specific case.

Marshall

@dzaima I hadn't thought about the case where static code depends on dynamic code. I (currently) think a←1 ⋄ {•Eval"a←2"⋄•Eval"a"} should return 2 but the case where you'd have to redo lexical resolution isn't as clear to me. Is there a model you'd suggest?

dzaima

@EliasMårtenson there's also this. You'd expect trains to be plenty faster than a function, but no

Marshall

@dzaima Oh, I didn't know ⍕ was so limited. The idea with •Fmt is just to give the programmer access to whatever the REPL uses to print.

dzaima

19:15

@Marshall right. Dyadic ⍕ does that

@Marshall i think the current ⍎ is fine, where it creates a new scope for itself. Supporting mutating the variable name list is gonna be messy in any impl

Marshall

@dzaima Okay, so it creates a scope for each instance of •Eval and reuses it if it's called multiple times. I didn't actually know it did that but evidently it works pretty well.

ngn

@xpqz i binned them. see conversation here.

dzaima

@dzaima actually, it doesn't do that, but it should. ¯\_(ツ)_/¯

Elias Mårtenson

@dzaima OK, that's strange.

Marshall

I guess I'll leave left arguments to •Fmt implementation-defined, just like the actual result.

Elias Mårtenson

19:21

I'd love to hear what someone who knows Dyalog internals can explain.

But now I really have to sleep :-)

dzaima

@dzaima ⍎ even uses LOC_ to access & set outer variables :o

•Eval¨•la∾¨<"←1" would be an O(n^2) operation, but that's expectable i guess

@Marshall I actually think it should always create a new scope, so •Eval doesn't need any special support

gtg now, i'll leave by noting a fun )sci in dzaima/BQN that displays all the allocated variable slots (and when the hashmap for VAR_ exists)

Marshall

@dzaima That would break most use cases for •Eval instead of •BQN though.

dzaima

@Marshall how so? you can still read variables and ↩ them, just not create previously non-existing ones

Marshall

An example from JtoLaTeX: process a file with some escapes for BQN code in it, where it's possible to add new escapes from BQN.

•Eval is basically for build-your-own-REPL type things.

It would be reasonable for an implementation not to support it though. But even the file functions are like that so probably all system functions should be optional.

@dzaima Would be pretty easy to make •Eval scopes overallocate variable slots to get O(n log(n)) for that.

@EliasMårtenson I'm somewhat surprised by this result as well, but the basic issue is that the user has to be able to stop and save even if a train is on the stack. So all the information needed to continue the train has to be stored in a pocket in the workspace.

dzaima

19:45

@Marshall oh, that's awful

@Marshall oh, hmm

(also, with the mutating •Eval, you can't allocate the variable slots inline with the scope/closure object, but that's less of a problem)

Marshall

Oh, even for inline processing where you could statically extract all the strings (like md.bqn), a •BQN that doesn't save scopes would be pretty inconvenient. You want a result out for each input string, and I don't see an easy way to do that.

dzaima

@Marshall Right. mutating scopes is plenty useful

Marshall

I'd rather use •BQN for evaluating code in markdown because it doesn't use any variables from md.bqn (unlike the svg/html generation, which does), but that's not that important. There won't always be a function with the exact features you want.

dzaima

@Marshall •BQN saving scopes would be less of a problem - you can guarantee there isn't any code currently running inside the scopes you're about to modify

Marshall

@dzaima Is it? Isn't F←{b+𝕩} followed by b←6 the same issue? Or would you just reject the first part?

dzaima

19:59

@Marshall F←{b+𝕩} without a preceding b definition currently falls back to VAR_, which I'd assume would be an error otherwise

Marshall

Oh, you can also pass the •BQN instance into a function that it was used to define, so there's definitely no difference in level of weird problems.

dzaima

@Marshall oh right, its return value could be a mutable namespace..

Marshall

@dzaima Or just a closure.

dzaima

I was imagining that •BQN would be a completely closed-off interface, but that breaks that fantasy

so i guess there's no way around having arbitrary mutation if you want some mutation

Marshall

@dzaima I think I'm now convinced that only •Eval should save scopes.

dzaima

20:06

@Marshall and •BQN makes a new one on every input?

Marshall

@dzaima Yes, it would just be an embedded instance in the same manner of bqn.bqn. Or •Import I guess.

dzaima

ok, so that's that. next: •Using, what?

Marshall

And it seems like it's not any harder to implement •Eval in the current scope than in its own saved scope, so I guess we're back to what I wrote initially.

@dzaima I guess my argument for •Using is that sometimes there's a framework so central to what you're doing that you really want to write •Using •Import "JQuery" (okay probably not) instead of importing every single name in it.

dzaima

@Marshall I understand wanting it, but does that not just force VAR_ usage?

nathan rogers

I have a matrix I want both the identity and the negation of that matrix as a 3d matrix

(+⍪-) was my guess, but that's not it

dzaima

20:12

@nathanrogers (+,[.5]-) or something

ngn

don't use + as "identity"

Marshall

@dzaima I guess you could resolve names once it's evaluated or something like that. VAR_ is probably the easiest way to support it.

If the file just starts with some •Using •Import "..." statements you could special-case those before even compiling.

And it should give an error if there are name conflicts, so you can assume names declared in the scope in question won't change.

nathan rogers

@ngn why?

Marshall

@nathanrogers Because it isn't, it conjugates complex numbers.

nathan rogers

my domain is ¯1,1

also, none of these things are giving me what I want

ngn

20:18

@nathanrogers ⊢ is the same number of characters

@nathanrogers maybe (⊢{⍺⍵}-) ?

nathan rogers

that's it

dzaima

@nathanrogers so you didn't want a 3D array

nathan rogers

I definitely thought I did, is that NOT a 3d array?

dzaima

@nathanrogers it's a vector of matrices. That's a different thing to a 3D array, or a vector of vectors of vectors

nathan rogers

↑(⊢{⍺⍵}-)0⍪↑(1 1)(1 0)

etc

ngn

20:21

@ngn also: (⊢,⍥⊂-) ⍝ in a recent enough version of dyalog

Marshall

In case it's relevant, note that dzaima's ,[.5] is really ,[⎕IO-.5] so you have to use ,[-.5] if ⎕IO is 0.

nathan rogers

@ngn I got this nasty mess on that same structure ⊃,/↓¨+⍀¨

I want a vector of items for the row-wise sumscan of each 2d matrix

Marshall

@nathanrogers That's ,↓↑+⍀¨, I think.

Or ,↓+⍀⍤2 on the ,[.5] version.

ngn

20:37

      ⊃,/↓¨+⍀¨(⊢,⍥⊂-)0⍪↑(1 1)(1 0)
 0 0  1 1  2 1  0 0  ¯1 ¯1  ¯2 ¯1

@nathanrogers what should the result be?

nathan rogers

that looks about right

I was doing the wrong thing anyway

i needed a different fucntion than ~

er, -

{(⊂⍵)⌿¨⍨(⊢{⍺ ⍵}~)2|⍳≢⍵}

that's what I was after

I want a list of odd and even rows separated

I guess key could do that?

ngn

@nathanrogers what's the larger problem you're solving?

Marshall

@nathanrogers Key is bad because the ordering depends on the data. You want group.

nathan rogers

{((≢⍵)⍴0 1){⍵}⌸⍵}

that works

Marshall

Oh, you're safe here because you know 0 comes before 1 in the left argument.

dzaima

20:41

@nathanrogers you could also reshape, transpose, and split

nathan rogers

I have a 2d matrix, I need to split even and odd rows

dzaima

@nathanrogers not particularly if you have 0 items

nathan rogers

that's the primary problem I'm trying to solve now

in my case ther eis a base case so 0 items isn't possible

I just need a 2d matrix split into even and odd rows

dzaima

@dzaima {↓⍉(2,⍨2÷⍨≢⍵)⍴⍵}

Marshall

(BQN is superior)

nathan rogers

20:43

from a matrix?

dzaima

@Marshall (but fails for 0 items)

nathan rogers

@dzaima depends on the input

for my case the base case is 1 item

so can't have 0

dzaima

@nathanrogers but it's not a nice solution in general

ngn

@nathanrogers note that ⌸ mixes the result, so you might get an extra row of zeroes or spaces

nathan rogers

,↓+⍀⍤1{(0 1⍴⍨≢⍵)⊢⌸⍵}

Marshall

20:48

@ngn Yeah, you probably want {⊂⍵}⌸.

@nathanrogers If you know you have an even number of rows, you could reshape it from (2×n)m to n 2 m and then use plain +⍀.

nathan rogers

are you saying because it will pad 0s?

I don't carea bout that, 0 is the identity element in this case so its not important if it pads 0

so... no that doesn't work what?

oh yes it does nvm

Marshall

Assuming even lengths, ,⍉↓+⍀(((2÷⍨⊃),2,1∘↓)∘⍴⍴⊢)mat works. Have to do an overtake first for odd lengths though.

nathan rogers

21:05

{≢∪,↓+⍀⍤2{(1 0⍴⍨≢⍵)⊢⌸⍵}0⍪↑(⊂'v<>^'⍳⍵)⌷,∘.,⍨¯1 1} 100⍴'v^'
101

this is a working solution to day 3 AOC 2015

adventofcode.com/2015/day/3

part 2

crits plz

how I defined it generally to avoid repetition with part 1

my favorite insight of this solution is the insight of a diagonal coordinate system

ngn

@nathanrogers complex numbers could be of use there

nathan rogers

yes I see bubblers answer

that's pretty keen

ngn

21:22

you must be talking about github.com/Bubbler-4/advent-of-apl/blob/master/AoC2015/…

nathan rogers

yep

rak1507

21:51

my solution ≢∪,+⍀0⍪(⊢⍴⍨2,⍨2÷⍨≢)⌊*0J1×○2÷⍨'^<v>'⍳input

oh, bubblers is very similar, cool

and I overcomplicated the complex number bit oops

nathan rogers

I think the complex numbers is the more obvious version for people who math harder than me

Like, I see it now, but I wouldn't have found that way

instead, I intuited a progressive list of cells in a 2d coordinate system, but the regular 0 1 combinations I've used before wouldn't cut it

I thought maybe evens and odds could do it, but finally intuited that 1 and ¯1 each coordinate in x and y is updated each movement

nathan rogers

22:20

here's a question

+⌿⍣≡∘↑ this works, +⌿⍣≡⊢↑ this doesn't, and I don't understand way

ngn

@nathanrogers in isolation, those would be trains - the second one a fork. what's the larger expression you used them in?

nathan rogers

+⌿⍣≡∘↑{(×/⍵) ,2× ⍵[2↑⍋⍵]}¨

ngn

@nathanrogers no argument at the end?

nathan rogers

s02_2 ← +⌿⍣≡∘↑{(×/⍵) ,2× ⍵[2↑⍋⍵]}¨ ⍝ 2_2 Sum total of double the 2 shortest
⍝ ... plus the volume of the input

ngn

@nathanrogers ah, i see. so s02_2 itself is a train

nathan rogers

22:26

just trying to find some way to add clarity

some spacing

some... something, but I don't see it

I'd really be keen to get rid of [] if I can

but its longer no matter how I slice it

and also hides the clarity of the existing expression

ngn

if you use 2 functions in a row without an argument, it's an "atop": f g ←→ {f g ⍵}. but if you use 4, they go like this: f g h i ←→ f (g h i) ←→ {f (g⍵)h i⍵}

nathan rogers

s02_2 ← +⌿⍣≡∘↑{(×/⍵) ,2× 2↑ ⍵[⍋⍵]}¨ ⍝ 2_2 Sum total of double the 2 shortest

or I could move it

but there doesn't seem to be much to wring out of this one

ngn

+⌿⍣≡∘↑ is a single function. +⌿⍣≡⊢↑ is a sequence of 3.

you add another one to the right - the first case becomes an atop (works fine), the second case becomes like i described above and it obviously isn't what you intended

@nathanrogers if you're gonna code in apl long-term, it would be good to memorize this: codegolf.stackexchange.com/a/43084/24908

nathan rogers

ahah +⌿⍣≡∘↑(×/,2 ×2↑ ⊂∘⍋ ⌷ ⊢)¨

@ngn I'm getting there. rewatched a bunch of the trainspotting in apl yesterday

I ask myself, I need ⍵ to go to ⌷ on the right and I need ⊂⍋⍵ on the left, so it needs to be in the middle, and I need to compose the other 2

no something is wrong :c

ngn

22:42

btw, i was just describing the way it is with trains in dyalog. i'm not saying it should be that way.

nathan rogers

no harm in practicing

unless there is

then you shouldn't

rak1507

@ngn when would you say something in dyalog is as it should be!

ngn

@rak1507 the core apl notation is great of course (not: oop, not: trains, not: namespaces..) except for unfixable bugs

nathan rogers

no I had it right

why is it right

rak1507

really? I thought you didn't like unicode

ngn

22:47

@rak1507 i like squiggles, actually. it's just the inconvenience of setting up fonts and keyboards, i would complain about that. but that's minor compared to other defects.

rak1507

fair enough

ngn

and yeah, i'd rather have overloads and be able to type them anywhere

nathan rogers

(×/, 2× 2↑ ⊂∘⍋ ⌷ ⊢ ) I read this as a fork of ×/ , (...) with 2 atops 2x and 2↑ and a train of (⊂⍋) ⌷ ⊢

is that right?

ngn

try pasting it in the repl with ]box on

nathan rogers

┌─────┬─┬─────────────────────────┐
│┌─┬─┐│,│┌─┬─┬───────────────────┐│
││×│/││ ││2│×│┌─┬─┬─────────────┐││
│└─┴─┘│ ││ │ ││2│↑│┌───────┬─┬─┐│││
│ │ ││ │ ││ │ ││┌─┬─┬─┐│⌷│⊢││││
│ │ ││ │ ││ │ │││⊂│∘│⍋││ │ ││││
│ │ ││ │ ││ │ ││└─┴─┴─┘│ │ ││││
│ │ ││ │ ││ │ │└───────┴─┴─┘│││
│ │ ││ │ │└─┴─┴─────────────┘││
│ │ │└─┴─┴───────────────────┘│
└─────┴─┴─────────────────────────┘

I did that

I don't really understand how to read this either

ngn

22:50

it's more like 4 nested forks: ×/ , (2 × (2 ↑ (⊂∘⍋ ⌷ ⊢)))

nathan rogers

my question is, what does ×/ get? does it get the result of (2× (2↑...)) or does it get ⍵ ?

{(×/⍵) ,2× 2↑ ⍵[⍋⍵]} this is the dfn

ngn

@nathanrogers ⍵

nathan rogers

so it parses down , not from the right

question mark

ngn

@nathanrogers parenthesization is from the right

(parenthesization - a made up word)

nathan rogers

that doesn't help answer my question

and I don't see how they're 4 forks

ngn

22:53

if you have more than 3 functions in a row, the last 3 become a fork

nathan rogers

does the existence of the constants 2 make them atops?

or they're just forks with constant arguments

ngn

@nathanrogers no, the constants act as if they are functions returning those constants: A g h ←→ {A} g h

nathan rogers

oh

yeah that makes sense

so if I were to express the application
(×/⍵) , (...)⍵
...(2 ⍵) × (...) ⍵
......(2⍵) ↑ (...) ⍵
.........(⊂∘⍋ ⍵) ⌷ ⍵

is that right?

ngn

@nathanrogers does "..." mean you're replacing it with the content of the following line?

nathan rogers

yeah

bceause there's no indentation in SE chat :C

ngn

22:57

@nathanrogers then, it's mostly right, except 2⍵ should be just 2

nathan rogers

I just meant that {2}⍵ sort of thing

discards ⍵ and returns 2

ngn

well, {2}⍵ is 2 but 2⍵ is a pair (2-vector) of 2 and ⍵

nathan rogers

what I'm saying right now is I meant {2}⍵

but I can't edit it anymore

ngn

okay

nathan rogers

(×/⍵) , (...)⍵
...........({2} ⍵) × (...) ⍵
..........................({2}⍵) ↑ (...) ⍵
.......................................(⊂∘⍋ ⍵) ⌷ ⍵

that actually makes a ton of sense to me

Transcript for