The APL Orchard

Adám

00:00

Again, use only what we've learned (there are better ways using additional things we've not learned yet).

diogotito

⋄ IsDivisibleBy←{⍺÷⍵=⌊⍺÷⍵}

Dyalog APL

@diogotito (no output)

diogotito

⋄ IsDivisibleBy←{⍺÷⍵=⌊⍺÷⍵} ⋄15 IsDivisibleBy 5

Dyalog APL

@diogotito DOMAIN ERROR

diogotito

Whoops, almost forgot

⋄ IsDivisibleBy←{(⍺÷⍵)=(⌊⍺÷⍵)} ⋄15 IsDivisibleBy 5

Dyalog APL

00:01

@diogotito 1

diogotito

⋄ IsDivisibleBy←{(⍺÷⍵)=(⌊⍺÷⍵)} ⋄15 IsDivisibleBy 6

Dyalog APL

@diogotito 0

diogotito

⋄ IsDivisibleBy←{(⍺÷⍵)=(⌊⍺÷⍵)} ⋄15 IsDivisibleBy ⍳20

Adám

That's good. You don't actually need the right hand parenthesis, but it may be helpful for clarity.

Dyalog APL

@diogotito
┌→──────────────────────────────────────┐
│1 0 1 0 1 0 0 0 0 0 0 0 0 0 1 0 0 0 0 0│
└~──────────────────────────────────────┘

Adám

00:02

@diogotito I love it. That's what I was about to ask you to do next. If you define a function in terms of such mathematical functions (we call them scalar functions) then your function will work that way too.

diogotito

@Adám Is it good practise to always leave parenthesis when possible?

Adám

@diogotito No, then it'd become unreadable, but it is perfectly alright to have parentheses for clarity or to demonstrate symmetry.

diogotito

⋄ IsDivisibleBy←{(⍺÷⍵)=(⌊⍺÷⍵)} ⋄15 ⍨IsDivisibleBy ⍳20

Dyalog APL

@diogotito VALUE ERROR

Adám

Oops, wrong location of that operator ⍨

diogotito

00:03

oh!

⋄ IsDivisibleBy←{(⍺÷⍵)=(⌊⍺÷⍵)} ⋄15 IsDivisibleBy⍨ ⍳20

Dyalog APL

@diogotito
┌→──────────────────────────────────────┐
│0 0 0 0 0 0 0 0 0 0 0 0 0 0 1 0 0 0 0 0│
└~──────────────────────────────────────┘

diogotito

I still have to unlearn "high order functions" from functional programming

rak1507

one of the great things about APL is you can write code and it 'just works' so often with any shape of left and right argument

Adám

@rak1507 … as long as they conform.

@diogotito You can call them that too.

rak1507

I was more thinking scalar + any shape and any shape + scalar

but yeah

Adám

00:06

@diogotito Can you write IsPrime?

diogotito

Let me try

Adám

(Note that this will only work for a single number at a time.)

diogotito

⋄ IsDivisibleBy←{(⍺÷⍵)=(⌊⍺÷⍵)} ⋄ IsPrime←{FromTwo ← 1 + ⍳(⍵-2) ⋄ NumDivisors ← +/ ⍺ IsDivisibleBy FromTwo ⋄ NumDivisors > 0} ⋄ IsPrime 13

Dyalog APL

@diogotito VALUE ERROR

RGS

@diogotito You tried using ⍺ in your IsPrime function, but you called IsPrime 13, only with the ⍵ argument, the one on the right.

diogotito

00:12

Thank you

Adám

Probably meant ⍵

diogotito

⋄ IsDivisibleBy←{(⍺÷⍵)=(⌊⍺÷⍵)} ⋄ IsPrime←{FromTwo ← 1 + ⍳(⍵-2) ⋄ NumDivisors ← +/ ⍵ IsDivisibleBy FromTwo ⋄ NumDivisors > 0} ⋄ IsPrime 13

Dyalog APL

@diogotito 0

Adám

There's another problem too.

diogotito

⋄ IsDivisibleBy←{(⍺÷⍵)=(⌊⍺÷⍵)} ⋄ IsPrime←{FromTwo ← 1 + ⍳(⍵-2) ⋄ NumDivisors ← +/ ⍵ IsDivisibleBy FromTwo ⋄ NumDivisors = 1} ⋄ IsPrime 13

Dyalog APL

00:13

@diogotito 0

diogotito

⋄ IsDivisibleBy←{(⍺÷⍵)=(⌊⍺÷⍵)} ⋄ IsPrime←{FromTwo ← 1 + ⍳(⍵-2) ⋄ NumDivisors ← +/ ⍵ IsDivisibleBy FromTwo ⋄ NumDivisors = 0} ⋄ IsPrime 13

Dyalog APL

@diogotito 1

Adám

Nice.

diogotito

Sorry If I rushed a bit there XD

Adám

No worries.

Instead of adjusting the range to 2…N-1 you could also just test if there are exactly 2 divisors.

RGS

00:15

@diogotito @diogotito Cool! I was expecting you to go with ~~⋄ IsDivisibleBy←{(⍺÷⍵)=(⌊⍺÷⍵)} ⋄ IsPrime←{2=+/ ⍵ IsDivisibleBy ⍳⍵} ⋄ IsPrime¨ 10 13 73 101~~

diogotito

Yes, that would have been simpler

Dyalog APL

@RGS
┌→──────┐
│0 1 1 1│
└~──────┘

RGS

Wasn't ~~ for strikethrough..?

Adám

No, ---

Bubbler

~~abc~~

diogotito

00:16

~~strikethrough~~

@RGS Ok that makes sense!

RGS

@diogotito You can still give it a go, I think. Unless you read my code before Adám's suggestion.

diogotito

I'll try to replicate it without looking

Adám

Btw, notice how we didn't need commas or parens to form a list? You can actually put any two things next to each other to form a list: ⋄ (1+2)(3+4)

Dyalog APL

@Adám
┌→──┐
│3 7│
└~──┘

rak1507

@Adám what do you think about telling him about some other potentially useful primitives? (⎕UCS 124)

RGS

00:18

@rak1507 I like the encoding xD

Adám

@rak1507 Meh, easy to define in terms of what we've got.

rak1507

True, but still makes things nicer

diogotito

⋄ IsDivisibleBy←{(⍺÷⍵)=(⌊⍺÷⍵)} ⋄ IsPrime←{2 = +/ ⍵ IsDivisibleBy ⍳⍵} ⋄ IsPrime 13

Adám

@diogotito Can you define Split 7.62 to give 7 0.62? I.e. it splits a number into its integer and fractional parts?

Dyalog APL

@diogotito 1

diogotito

00:20

@Adám Yes!

⋄ Split←{⍵-⌊⍵} ⋄ Split 7.62

Dyalog APL

@diogotito 0.62

diogotito

Oh, I forgot

⋄ Split←{⌊⍵ ⍵-⌊⍵} ⋄ Split 7.62

Dyalog APL

@diogotito
┌→──┐
│0 0│
└~──┘

Adám

Note that ⍵ ⍵ immediately forms a list.

diogotito

⋄ Split←{(⌊⍵) ⍵-⌊⍵} ⋄ Split 7.62

Dyalog APL

00:21

@diogotito
┌→─────┐
│0 0.62│
└~─────┘

Adám

And so does (⌊⍵) ⍵

diogotito

Yes

⋄ Split←{(⌊⍵) (⍵-⌊⍵)} ⋄ Split 7.62

Dyalog APL

@diogotito
┌→─────┐
│7 0.62│
└~─────┘

Adám

Nice.

rak1507

Is there anything shorter than 4 characters?

diogotito

00:23

@rak1507 To implement Split?

rak1507

Yeah

Just wondering really

Adám

Can you write a function that takes two lists of equal length and computes the fraction of elements in the left argument that are greater than the corresponding element from the right argument?

RGS

@diogotito Most (all?) people here like to do code golf, and more often than not, the number of characters of a solution is the only thing that cares to them when solving a problem.

diogotito

Let'me try

rak1507

@RGS Harsh!

RGS

00:25

@rak1507 Was it? D: I thought it was pretty accurate XD

rak1507

if you want I can ask him to write a sparse diagonal matrix solver and then I'll care about speed more than code size @RGS

RGS

@rak1507 Right :P But that is only for the first implementation. I bet the next iterations of the code will be getting shorter and shorter, and not necessarily faster :P

rak1507

Haha maybe

diogotito

looooool

(I've just realised that pressing backtick with the US layout trigger the JS bookmark and allows me to type the APL characters directly!)

Adám

@diogotito You should be able to use º on your Portuguese layout too.

diogotito

00:29

You're right! It works!

Adám

You'll find that the keys are rather mnemonic, e.g. i for ⍳ and d (round Down) for ⌊.

rak1507

and s for round... skyward?

diogotito

XD

Adám

seiling (c is for cap which cannot be spelled with an s)

diogotito

oops I erased the answer

I'll try to speedrun it now

rak1507

00:31

v for vnion, because APL has to be backwards compatible with mainframe systems written in ancient rome

RGS

@rak1507 Can you show me yours? Can only come up with 5 chars.

rak1507

@RGS 0 1∘⊤

Adám

@rak1507 Looks like 5 to me.

rak1507

(oops)

it's because I didn't actually count it (I can count I promise) but rather misremembered it from the 2018 problem solving competition solutions

in that case ⌊,⊢-⌊ is simpler

RGS

@rak1507 I was at ⌊,1∘⊤

diogotito

00:32

If it doesn't bother you too much I'll iterate with the bot

⋄ GtFrac ←{ ⍺÷⍵ } ⋄ 5 5 5 5 GtFrac 1 1 9 9

Adám

@rak1507 Are you sure you didn't just count from 0?

Dyalog APL

@diogotito
┌→────────────────────────────┐
│5 5 0.5555555556 0.5555555556│
└~────────────────────────────┘

rak1507

@Adám haha maybe

Adám

@diogotito Sure, or use tryapl.org

diogotito

Thanks!

rak1507

00:34

Avg←{(+⌿⍵)÷≢⍵} the fact this is the given definition of average makes me sad

RGS

@rak1507 What would you want to be given?

rak1507

+⌿÷≢

RGS

@rak1507 Ah ok :P

Adám

@rak1507 On TryAPL, you mean?

rak1507

it's so much nicer!

yeah

it's the perfect example of a train, and how nice tacit programming can be

diogotito

00:36

Ok, I came up with

⋄GtFrac ←{ (⍺>⍵)÷(+/⍵÷⍵) } ⋄ 5 5 5 5 GtFrac 1 1 9 9

Adám

OK, let's find the messages around the time when rak1507 was first introduced to tacit programming…

Dyalog APL

@diogotito
┌→────────────┐
│0.25 0.25 0 0│
└~────────────┘

diogotito

⋄GtFrac ←{ +/ (⍺>⍵)÷(+/⍵÷⍵) } ⋄ 5 5 5 5 GtFrac 1 1 9 9

Dyalog APL

@diogotito 0.5

rak1507

@Adám oh noooo

I think my first introduction to it was bubblers solution to one of the phase 1 problems

which was more complicated than +⌿÷≢

Adám

00:37

@diogotito Perfect. In fact, you can find the length of a list with monadic ≢ (which may render funny if you're using Chrome on Windows).

rak1507

maybe if I'd been introduced to that first (through something like tryapl) I wouldn't have found it so confusing

diogotito

≢ 1 2 3 4 5

⋄ ≢1 2 3 4 5

Dyalog APL

@diogotito 5

diogotito

⋄ ≢⍳420

Dyalog APL

@diogotito 420

Adám

00:38

@DyalogAPL It'd better be.

diogotito

⋄ {≢⍳⍵} ⍳10

Dyalog APL

@diogotito 1

diogotito

⋄ id ← {≢⍳⍵} ⋄ id ⍳10

Dyalog APL

@diogotito 1

diogotito

⋄ id ← {≢⍳⍵} ⋄ id 1 2 3 4 5

Dyalog APL

00:40

@diogotito 1

diogotito

⍳(1 2 3 4 5)

rak1507

that's certainly an interesting way of doing an identity function

Adám

OK, I think this is enough teaching for now. Should you want more, then I'd be delighted to continue tomorrow. If you can't sleep, then you can look at apl.wiki/Learning_resources

rak1507

⋄ ⍳⍳5

Dyalog APL

@rak1507 0x0.st/-iu3.txt

Adám

00:41

@rak1507 Not an identity function.

diogotito

@Adám Thank you for your time!!

rak1507

@Adám *for some set of inputs

Adám

My pleasure.

@rak1507 Any array with a leading axis of length 1…

rak1507

@Adám right yeah I couldn't be bothered trying to think about when it works

RGS

Alright @diogotito, how cool is APL? :P

diogotito

00:43

Quite!

rak1507

you mentioned functional programming earlier, do you happen to know any haskell?

RGS

Precisely. Are you leaving now/coming back tomorrow for more?

diogotito

Yes, I read some chapters from Learn You a Haskell

rak1507

Do you know what f<*>g is when f and g are functions?

diogotito

ap, If I recall correctly

oh

rak1507

00:44

right

diogotito

It was funny

rak1507

?

diogotito

f <*> g reuses the operand I guess

rak1507

In APL, you can do something similar

you can have (f g h) where f g and h are functions, and if you apply it with one argument you get (f ⍵) g (h ⍵), and with two arguments you get (⍺ f ⍵) g (⍺ h ⍵)

which is why the average can be written as +/÷≢

(+/÷≢) x = (+/ x) ÷ (≢x)

diogotito

Let that sink into my head xD

In your example, f and h are unary functions and g is binary, right?

oh, they can be either unary or binary

RGS

00:51

@diogotito But g must be dyadic.

rak1507

yeah, 'monadic' or 'dyadic'

Adám

@rak1507 Sure, but in my experience, true fgh trains are actually quite rare. Usually either f or h is a constant or identity function.

rak1507

true

well, they're not that rare, but ⊢ f g is probably more common

⋄ ⊢ 1 ⋄ ⊣ 1 ⋄ 1 ⊣ 2 ⋄ 1 ⊢ 2

Dyalog APL

@rak1507
1
1
1
2

rak1507

⊣ and ⊢ are both identity functions monadically, and return what they 'point to' dyadically

Adám

00:53

@rak1507 Maybe why J's (f g) is (⊣ f g)…

rak1507

yeah

Adám

Oh and because of that combinator stuff code_report always complains about.

rak1507

⋄ palindromic ← ⊢≡⌽ ⋄ palindromic 'racecar'

Dyalog APL

@rak1507 1

rak1507

@Adám I don't think he complains about it, just talks about it

Adám

00:54

@rak1507 He complains about the APL world having forgotten the connection.

rak1507

Ah right

well fair enough

it's an interesting connection

Dyalog APL

<moon-child> @Adám j also gets away with that because it has caps, so purely monadic applications are easier

diogotito

@rak1507 Oooh! I get it now! +/÷≢is Sum divided by Length!

rak1507

yep!

Adám

moon-child: I think it is the other way around: J had to add the anomalous cap because (f g) was defined as it was.

diogotito

00:56

Pretty cool!

Adám

@diogotito It literally reads as +/ sum ÷ divided by ≢ length.

rak1507

yeah

⌽≡⊢ 'reverse equals same'

diogotito

@Adám Exactly! I'm still getting overwhelmed by the notation

⋄ ⌽≡⊢ (1 2 3 2 1)

Dyalog APL

@diogotito 1

diogotito

⋄ ⌽≡⊢ 1 2 3 2 1

Dyalog APL

00:58

@diogotito 1

diogotito

Ok, got it!

rak1507

that returns 1 for the wrong reasons

that is doing ⌽(≡(⊢1 2 3 2 1))

Dyalog APL

<moon-child> @Adám fair enough. Causality is sometimes hard to divine :P

rak1507

⋄ ⌽≡⊢ 1 2 3

Dyalog APL

<moon-child> maybe roger knows

@rak1507 1

rak1507

00:59

⋄ (⌽≡⊢) 1 2 3

Dyalog APL

@rak1507 0

Adám

@rak1507 Erm…

rak1507

yeah, the point was to show that it's wrong like that

diogotito

Oh I see. Thanks!

Adám

@rak1507 Orthogonal←⍉≡⌹ ⋄ Hermitian←⍉≡+ ⋄ SetDiff←∪~∩ ⋄ Promote←∩,~ Any other using only three primitive functions?

rak1507

01:02

Can't think of many

Adám

Maybe DirMag←×,|

rak1507

⍉∧⊢ to convert a diagonal matrix to a ... not diagonal matrix? idk if it has a special name

Adám

> three

rak1507

ah

RGS

@Adám IsInt ← ⌈=⌊

Adám

01:05

@RGS ⊢=⌊

rak1507

there's ⍋⌷¨⊂ for sorting, sort of uses 3

RGS

@Adám It computes the same thing, but ⌈=⌊ reads elegantly, that's why I added it.

Adám

@RGS Double the work, though. -1

RGS

Alright, fine, I concede.

Adám

@rak1507 Nah, ⊂ here is an identity function.

rak1507

01:07

I suppose

+,-

Adám

It is just making up for the missing ⊇ primitive. Also, unless golfing, that definition isn't good, as it is neither general, nor fast.

rak1507

true

Adám

@rak1507 Yeah, although I kind of feel that , and ⍪ and {⍺⍵} shouldn't really count, as they don't truly compute anything.

rak1507

fair enough

RGS

@Adám How about IsConstant ← ⌊/=⌈/ to see if a list is only composed of a single number?

Adám

01:11

@RGS ⊢≡∪

RGS

Although that's probably not the best way to go about computing that...

@Adám That's not what I mean, I mean it has (possibly) multiple elements, but they are all the same number.

Adám

Oh, no sorry.

rak1507

1≡∘≢∪ I guess

Adám

Or ⊃∧.=⊢

rak1507

yeah

∧/∘,∘.=⍨

∘,∘ looks like a face

RGS

01:14

Can someone please help me understand when is {f/⍺ g ⍵} different from {⍺ f.g ⍵}?

Adám

@RGS When any argument isn't a scalar/vector.

Bubbler

and g isn't a scalar function, I guess?

RGS

@Adám For ranks 2 and above would it be fixed if I had ⌿ instead?

@Bubbler Yeah that makes sense :P

Adám

@RGS No. I suggest you try it with f←{⍺'f'⍵} ⋄ g←'{⍺'g'⍵}.

RGS

@Adám Good suggestion.

Adám

01:17

Ooh, Range←⌈/-⌊/

rak1507

that's a nice one

diogotito

Oh, so ⌊ and ⌈ live a double life as floor/ min and ceiling/max

RGS

@diogotito Yes, they do.

Adám

Yes. While not directly connected, they both have something to do with going up and going down.

RGS

Most of the primitives have different meanings when used monadically or diadically.

For some, their meanings are very very related. E.g. -Y and X-Y, or ÷Y and X÷Y. For others, not so much :P

Adám

01:23

And for a few, not at all. But they are quite rare, and in those cases, the symbol is quite mnemonic for both.

rak1507

what are some where they're not related at all?

RGS

@rak1507 ∊?

rak1507

I guess ≢ and ≡

Adám

∊ for Enlist and ElementOf

rak1507

yeah

well monadic ∊ could be seen as getting all the elements of the argument

Adám

01:24

Besides for their traditional dyadic meanings, ≢ is very much a tally mark, and ≡ is a stack, indicating depth.

rak1507

so they are maybe a little bit related

Adám

@rak1507 |

rak1507

absolute value is sometimes called the 'modulus', so there must be a connection there

monadic is 0|

that's interesting that 0|¯1 is ¯1

RGS

0∘| is a no-op for nums

rak1507

maybe it's more like infinity|⊢

RGS

01:28

0∘| doesn't really make much sense mathematically, does it? x∘| is supposed to be the remainder of the argument when divided by x, but you can't really divide by 0.

rak1507

yeah true

RGS

Another way to look at it is by looking at the list of possible values, e.g. 3∘| could give 0 1 2, 2∘| could give 0 1 and 1∘| always gives 0, so 0∘| gives... ⍬? :P

rak1507

yeah definitely more like infinity∘|

n|x restricts x to 0 to n-1, |x restricts x to 0-infinity

they seem related to me

Adám

@rak1507 ↑ and ↓

@rak1507 I claimed , but code_report disagreed.

rak1507

typical :P I'll admit I'm not seeing it as obviously as ⌽

oh, I misread what you were saying

yeah, monadic and dyadic ,

Adám

01:32

@rak1507 Oh right, he found a connection for ⌽ too.

rak1507

the connection for ⌽ is a little bit dubious but it is nice, the fact rotation can be implemented in terms of reverses

{⌽⌽@(⍺~⍨⍥⍳≢⍵)⌽@(⍳⍺)⊢⍵}

Adám

The symbol is just so fitting for both.

rak1507

dyadic ⍉ doesn't seem that related to monadic ⍉

Adám

What are you talking about‽

rak1507

but I never use it for anything other than 0 0⍉x so I wouldn't know

Adám

01:35

The default left argument of ⍉ is ⌽⍳≢⍴⍵

rak1507

ah

Adám

In other words, dyadic ⍉ reorders the axes to a specified order, while monadic ⍉ reverses them.

Bubbler

@Adám (which should have been 1⌽⍳≢⍴⍵ ... or is it ¯1?)

Adám

One could argue that 1⌽⍳≢⍴⍵ would have been a better choice of extension from 2D though.

Ninja'd.

But this doesn't detract from their close relationship.

rak1507

I would say monadic and dyadic ⍸ aren't that related

Adám

01:38

True, that's another odd one.

rak1507

and then there are \/⌿⍀ which are all over the place

Bubbler

But monadic ⍸ is related to monadic ⍳ and dyadic ⍸ is related to dyadic ⍳, I think

Adám

True.

RGS

@rak1507 BUT those aren't monadic and dyadic per se, just dyadic.

Adám

@rak1507 Monadic and dyadic f/ are very related.

rak1507

01:40

@RGS as a function, yes, but in general they can either represent reduction or replication, which don't seem all that similar

@Adám agreed

RGS

@rak1507 Agreed, I was just being too literal when interpreting the statement that started this discussion.

James Heslip

08:45

@Adám were you involved with the dyalog.com/2016-year-game.htm?

Razetime

Wrote an answer for https://codegolf.stackexchange.com/questions/127765/interlaced-rotations : [Try it online!](https://tio.run/##SyzI0U2pTMzJT///v7r0UVeztn71o5690YbaRjWPerfGPuqY8ai3s/zwdEMHjUr9R70rHnWs0D@0QgMop1OhCZLt6Dq0ovJR2wQdIEdPB6gCJKdrqPmobfKj3s0VQBlDbZBRuo86F5VrPupaZHB4enntoRVAyUc9HQZ6poeng2SA6oCKaktBdN/UUOfg/2lgoT6gmx71rnnUu@XQeuNHbROBksFBzkAyxMMz@H86UE01kAOk1NUfdbdo6IAM3qoJotNAjFqudAVjBWOgdnVDI2MTUzNzC0t1oJiZghlCzNHJ2cXVzd3D08vbx9fPPyAwKDgkNCw8IjJK0UFZBaTcUsESpDwkI1WhsDQzOVshqSi/PE8hLb9CIas0t6BYIb8stUihBCidk1hVqZCSn64OAA "APL (Dyalog Unicode) – Try It Online")

Adám

@JamesHeslip A bit, why?

James Heslip

09:05

@Adám were discussing it in Optima, and decided to recreate the problem for this year. (optima-systems.co.uk/programming-challenge-the-year-game) I had a solution for 29 using 2 0 2 1, but I wasn't sure the rules permitted: |20J21

Original rules state 'In addition to the four digits 2 0 1 6, only primitive functions/operators, parentheses/braces, spaces, high minus signs and decimal points can be used. The resultant expressions must be deterministic (that is, give the same result on repeated evaluations).' Does this mean that solution is illegal?

Adám

Sounds like it.

James Heslip

@Adám Dah, will have to find another clever one now... Was pretty proud of myself for spotting that, lol.

Adám

It is good.

> The original challenge was intended for users of APL, so the official Dyalog rules are specifically tailored to APL solutions, but do not let this put you off trying it in different languages.

I created a spec that works for non-APL solutions:

26

Q: Official Dyalog APL 2016 Year Game

If you think this could be fun, but too much work, consider participating in this much smaller challenge. A bit of fun (and possibly frustration!) for 2016... Dyalog's "puzzle of the year". Enjoy! The Objective Find Dyalog APL (download) expressions (other languages are allowed, see Eligibility ...

Dyalog APL

<moon-child> @JamesHeslip 20+×⍨2+1

Adám

Nice!

@JamesHeslip Oh, it even says so in the FAQ:

> Is J (e.g. 37=⌈⍟!20J16) allowed?
> No: In addition to the four digits 2 0 1 6, only only built-in symbols and names, parentheses/braces, spaces, high minus signs and decimal points can be used.

James Heslip

09:19

@Adám Ah I missed that, no worries.

Adám

@JamesHeslip How could you miss it in a text you didn't know about yet?

James Heslip

@Adám I thought you were referring to the official FAQ.

Adám

@Razetime I htink I've got 52.

Golf in progress…

Razetime

09:39

@Adám I knew my algorithmwas too big

it's at 81 right now

Adám

@Razetime 46.

Razetime

well great

Idk what you've done but you should post it

Adám

42.

Razetime

⍎⊖⍕⊃⊂|⌊-*+○⌈×÷!⌽⍉⌹~⍴⍋⍒,⍟?⍳0

Adám

35

Razetime

09:49

what are you doing?~?~??~

Adám

Removing fluff.

Razetime

huh.

Adám

@Razetime Meh, feel free to improve your post with this: ⍉⌽m⊣{(b↓e↓m)←⌽⊖b↓m↓⍨e←-b←2⍴⍵}¨⍳≢m←⎕

Razetime

so um

how

Adám

Just add "-46 thanks to Adám" or something…

rak1507

09:58

lol

Transcript for