I don't understand what dyadic interval index does with a left arg rank > 1. This is the example from the language bar: ⎕←(3 2⍴⍳6)⍸3 5 -- can someone explain what is compared with what?

@xpqz 2

I think that's equivalent to ⎕←(↓3 2⍴⍳6)⍸⊂3 5

@dzaima 2

@dzaima Right :/ -- not sure that's any clearer in my mind. How do the comparisons go?

it finds the place of 3 5 lexicographically in (1 2),(3 4),(5 6), which is after the 2nd element

⎕←{⍵[⍋⍵]} (1 2) (3 4) (5 6) (3 5) - inserting that 3 5 lexicographically

@dzaima
┌───┬───┬───┬───┐
│1 2│3 4│3 5│5 6│
└───┴───┴───┴───┘

Wow. I had internalised this completely and utterly the wrong way.

CMC: Put a space in between every letter. 'APL' -> 'A P L'

@pVCaecidiosporeadduced ⎕←' '(1↓∘,,⍤0)'APL'

@xpqz A P L

@xpqz thats a train?

It is indeed a train. I'd love to take credit, but it's straight out of APL Cart.

aplcart.info/?q=join%20elements%20of%20vector#

⎕←1↓∘,,⍤0

@xpqz
┌─┼───┐
1 ∘   ⍤
 ┌┴┐ ┌┴┐
 ↓ , , 0

⎕←0(1↓∘,,⍤0)1 2 3 4

@pVCaecidiosporeadduced 1 0 2 0 3 0 4

,¨ is shorter than ,⍤0

Here's another way: ⎕←' ' {¯1↓∊(⍪⍵),⍺} 'APL'

@xpqz A P L

(1↓⊢⊢⍤\⍨2|∘⍳2×≢) is fun too using \

what is that...:)

expand

{⍵\⍨2|⍳(2×≢⍵)-1} similar

yep

⎕←{(' ',⍵)[(1-⍨2×(⍴⍵))⍴↑,∘1¨1+⍳⍴⍵]}'APL'

@WongJiaHau A P L

Is there a reverse code golf discipline? Make simple code obfuscated and long. Like ⎕←⍎⌽⍕⌈*○≡⍬

@xpqz 42

⎕←{1↓,↑' ',¨⍵}'APL'

@WongJiaHau A P L

Nice

@WongJiaHau ,↑is just ∊

@PaulMansour @rak1507 @EliasMårtenson If enough people ask for it, I'm sure will do it. We already added a variant to import null to ⎕NULL rather than the default ⊂'null'

Ah, cool

@pVCaecidiosporeadduced Full program: 1↓∊¯2↑¨⍞

¯2↑¨ is a nice trick