The APL Orchard

Absolutely, but it certainly isn't abuse. APL is terrible if you ignore its array handling capabilities. In fact, some say APL should mean "Array Processing Language".

EdgyNerd

does it have an 'official' thing that it stands for?

Adám

A Programming Language ⍨

Quintec

9:04 PM

A Programming Language

frank

probably the best acronym there is tbh

EdgyNerd

oh wow

Adám

Remember that I told you APL was intended as a better alternative to TMN?

EdgyNerd

yeah

Quintec

⎕←{2=⍴⍸⍵⍷∘.×⍨⍳⍵} 97 ⊣ 'I think weirdly.'

Dyalog APL

9:05 PM

@Quintec
1

EdgyNerd

⎕←⍸{⍵∊∘.×⍨1↓⍳⌈/⍵}⍳100

Dyalog APL

@EdgyNerd
4 6 8 9 10 12 14 15 16 18 20 21 22 24 25 26 27 28 30 32 33 34 35 36 38 39 40 42 44 45 46 48 49 50 51 52 54 55 56 57 58 60 62 63 64 65 66 68 69 70 72 74 75 76 77 78 80 81 82 84 85 86 87 88 90 91 92 93 94 95 96 98 99 100

EdgyNerd

oh wait

why does that get non-primes?

Adám

APL was created by a mathematician — to replace TMN. Only later came the idea to make a programming language out of it. He presented the idea in a book called A Programming Language and when they went to implement it, they used the acronym…

EdgyNerd

oh wow

Adám

9:07 PM

⍞←{⍵∊∘.×⍨1↓⍳⌈/⍵}⍳10

Dyalog APL

@Adám 0 0 0 1 0 1 0 1 1 1

EdgyNerd

oh right

is there a NOT builtin in APL?

Adám

@EdgyNerd ~

EdgyNerd

⎕←⍸~/{⍵∊∘.×⍨1↓⍳⌈/⍵}⍳100

Dyalog APL

@EdgyNerd
DOMAIN ERROR

EdgyNerd

9:08 PM

⎕←⍸~{⍵∊∘.×⍨1↓⍳⌈/⍵}⍳100

Dyalog APL

@EdgyNerd
1 2 3 5 7 11 13 17 19 23 29 31 37 41 43 47 53 59 61 67 71 73 79 83 89 97

Adám

Hold on, NOT is a monadic function.

EdgyNerd

oh yeah

Adám

But wait, we can do better.

Remember that primes are all the numbers NOT in the multiplication table?

EdgyNerd

oh yeah

Adám

9:09 PM

So if we have all the numbers and just remove those that are in the multiplication table, that leaves the primes.

EdgyNerd

⎕←⍸{⍵~∊∘.×⍨1↓⍳⌈/⍵}⍳100

Adám

Look at this:

Dyalog APL

@EdgyNerd
DOMAIN ERROR

Adám

⍞←'mississippi'~'ps'

Dyalog APL

@Adám miiii

Adám

9:10 PM

Dyadic ~ is "set subtraction" a.k.a. "without"

EdgyNerd

so use ~ instead of ∊?

Adám

@EdgyNerd Yes.

EdgyNerd

⎕←⍸{⍵~∘.×⍨1↓⍳⌈/⍵}⍳100

Dyalog APL

@EdgyNerd
DOMAIN ERROR

Adám

And remove the ⍸

EdgyNerd

9:11 PM

⎕←{⍵~∘.×⍨1↓⍳⌈/⍵}⍳100

Dyalog APL

@EdgyNerd
1 2 3 5 7 11 13 17 19 23 29 31 37 41 43 47 53 59 61 67 71 73 79 83 89 97

EdgyNerd

I'm kinda confused how that works

Adám

You're kind of doing double work here. Let's take it step by step. We start with all the integers above 1:

⍞←1↓⍳10

Dyalog APL

@Adám 2 3 4 5 6 7 8 9 10

Adám

Then we make a times table for them:

⎕←{∘.×⍨1↓⍳⍵}10

Dyalog APL

9:12 PM

@Adám
 4  6  8 10 12 14 16 18  20
 6  9 12 15 18 21 24 27  30
 8 12 16 20 24 28 32 36  40
10 15 20 25 30 35 40 45  50
12 18 24 30 36 42 48 54  60
14 21 28 35 42 49 56 63  70
16 24 32 40 48 56 64 72  80
18 27 36 45 54 63 72 81  90
20 30 40 50 60 70 80 90 100

Adám

And remove the times table from the numbers:

⍞←{(1↓⍳⍵)~∘.×⍨1↓⍳⍵}10

Dyalog APL

@Adám 2 3 5 7

Adám

Now we can "break out the 1↓⍳⍵ phrase:

⍞←{{⍵~∘.×⍨⍵}1↓⍳⍵}10

Dyalog APL

@Adám 2 3 5 7

Adám

we could also use an inline variable assignment:

⍞←{c~∘.×⍨c←1↓⍳⍵}100

Dyalog APL

9:14 PM

@Adám 2 3 5 7 11 13 17 19 23 29 31 37 41 43 47 53 59 61 67 71 73 79 83 89 97

Adám

@EdgyNerd Understand?

EdgyNerd

kind of

~ confuses me a little still

Adám

@EdgyNerd It takes a list on the lift and removes all the elements that appear anywhere in the array on the right.

EdgyNerd

ohhh right

I thought it was the other way round

that's why I was confused

Adám

Think of it like - it takes something on the left and removes what's on the right.

EdgyNerd

9:16 PM

yeah

voidhawk

Okay, after watching the video on thunks: Is Marshall a literal wizard? Like, with wands and ravens and such?

@voidhawk Yes.

Yeah, I thought so

⍞←{c~∘.×⍨c←1↓⍳⍵}1000

@EdgyNerd 2 3 5 7 11 13 17 19 23 29 31 37 41 43 47 53 59 61 67 71 73 79 83 89 97 101 103 107 109 113 127 131 137 139 149 151 157 163 167 173 179 181 191 193 197 199 211 223 227 229 233 239 241 251 257 263 269 271 277 281 283 293 307 311 313 317 331 337 347 349 353 359 367 373 379 383 389 397 401 409 419 421 431 433 439 443 449 457 461 463 467 479 487 491 499 503 509 521 523 541 547 557 563 569 571 577 587 593 599 601 607 613 617 619 631 641 643 647 653 659 661 673 677 683 691 701 709 719 727

733 739 743 751 757 761 769 773 787 797 809 811 821 823 827 829 839 853 857 859 863 877 881 883 887 907 911 919 929 937 941 947 953 967 971 977 983 991 997

EdgyNerd

9:17 PM

oh wow it can do that

Adám

@EdgyNerd Why not? (other than it being a bit odd that it posted two messages)

EdgyNerd

because a 1000x1000 table is big

and it makes a table for the numbers from 1-1000

frank

array processing language, remember?

EdgyNerd

yeah

Adám

Each number needs two bytes, and there are a million of them, so that's about 2MB.

EdgyNerd

9:19 PM

oh wow

Adám

The bot handles arrays up to 128MB, if I recall correctly.

EdgyNerd

what's next?

Adám

But on an actual installed APL system, there's no limit. We regularly test arrays up to about 100GB. Though you can go bigger if you have the money for that kind of RAM.

@EdgyNerd You can build your vocabulary by yourself, so let's instead advance your knowledge of those functions.

EdgyNerd

@Adám how fast can it do arrays that large?

Quintec

@Adám 1.5TB RAM, anyone?

Adám

9:22 PM

@EdgyNerd Depends on the operation. For a lot of arithmetic and comparison, the bottleneck is actually the speed at which the RAM can deliver data to the CPU, while the CPU is just sitting semi-idle, waiting for more work.

EdgyNerd

oh wow

also I just noticed you can hover over stuff in the symbol shortcut thing to see what they do

that's quite useful

⍞←○100

Dyalog APL

@EdgyNerd 314.1592654

Adám

We haven't even gotten to those functions yet, but there are things where Dyalog APL beats carefully hand-crafted C, which is of course a paradox since Dyalog APL is written in C…

@EdgyNerd So, in a dfn (those functions written in braces) you can actually have multiple statements:

⍞←{c←1↓⍳⍵ ⋄ c~∘.×⍨c}10

Dyalog APL

@Adám 2 3 5 7

EdgyNerd

how does that work?

Adám

9:26 PM

You've already met ⋄ as a statement separator. Works the same here.

frank

does it return the result of the last statement?

Adám

No, it returns the first non-assignment.

EdgyNerd

oh right, I was trying to read it from far right to left

instead of the right of the first statement

Adám

@EdgyNerd Yeah, you can write like that as well, but not using ⋄:

⍞←{c~∘.×⍨c ⊣ c←1↓⍳⍵}10

Dyalog APL

@Adám 2 3 5 7

Adám

9:27 PM

⊣ is actually just a very very simple function (so simple that people have a hard time with it). It takes two arguments and returns the left:

⍞←3⊣4

Dyalog APL

@Adám 3

EdgyNerd

oh wow

does ⊢ return the right by any chance

Adám

It does :-)

So what's actually happening in …c ⊣ c←… is that we assign to c then discard that in favour of c

frank

unfortunately apl is not a 2d language so ⊤ and ⊥ do not return below and above

Adám

Nope. Sorry. But there's actually a way you can almost do that.

EdgyNerd

9:29 PM

what is modulo in APL?

Adám

| but with swapped arguments compared to ÷

EdgyNerd

so 5|2 is 1?

or is it 2|5

Adám

Of course, you can just use ⍨ whenever the order of arguments doesn't suit you.

frank

⎕←5|2

Dyalog APL

@frank
2

frank

9:30 PM

⎕←2|5

Dyalog APL

@frank
1

voidhawk

@Adám Do you know if the Dyalog interpreter is written in "Whitney C" or is it more standard?

EdgyNerd

⍞←{⍵|⍨×⍨!⍵-1}13

Dyalog APL

@EdgyNerd 0

Adám

@voidhawk Very much a standard looking, actually quite old-fashioned, C.

EdgyNerd

9:31 PM

⍞←{⍵|⍨×⍨!⍵-1}14

⍞←{⍵|⍨×⍨!⍵-1}13 14

Dyalog APL

@EdgyNerd 0 0

EdgyNerd

oh that didn't work

Adám

What are you trying to do?

EdgyNerd

I was trying to do wilson's theorum (which I saw in this answer) in APL

frank

w-1 factorial squared modulo w?

Adám

9:32 PM

The x mod square of the beta function beta function of x?

EdgyNerd

⍞←{⍵|×⍨!⍵-1}13 14

Dyalog APL

@EdgyNerd 0 0

Adám

That's "correct", but I'm not sure what it means.

EdgyNerd

it should give 1 if it's prime I'm pretty sure

Adám

@EdgyNerd Really? Never heard of that. But then again, I am not a mathematician.

EdgyNerd

9:34 PM

actually I don't think that works nvm

Adám

Anyway, continuing with dfns: You can set up guards, which are conditional expressions followed by : followed by an expression which will give the result if the conditional was true. If it isn't, the dfn continues with the next statement:

⍞←{⍵>10:'big' ⋄ 'small'}15

Dyalog APL

@Adám big

Adám

⍞←{⍵>10:'big' ⋄ 'small'}7

Dyalog APL

@Adám small

EdgyNerd

does that require the ⋄?

Adám

9:36 PM

Yes, otherwise there's no way to see where the guard result ends.

And you can't use ⊣ either, for obvious reasons if you think about it.

EdgyNerd

yeah

what other (basic) conditionals are there?

Adám

You can catch errors with an error number followed by :: followed by the result-if-error. Each error type (DOMAIN, LENGTH, etc.) has its own code. DOMAIN ERROR is number 11.

⍞←{11:'nope' ⋄ ÷0}0

Dyalog APL

@Adám DOMAIN ERROR

Adám

Oops.

⍞←{11::'nope' ⋄ ÷0}0

Dyalog APL

@Adám nope

Adám

9:39 PM

⍞←{11::'nope' ⋄ ÷0}10

@DyalogAPL Pretty please?

⍞←{11::'nope' ⋄ ÷0}10

Dyalog APL

@Adám nope

Adám

@DyalogAPL Thank you, that's very kind.

EdgyNerd

so it runs the right statement and if it errors with the error code it returns the left argument

Adám

@EdgyNerd Not exactly. All ⋄-separated statements are evaluated in order from left to right. Error guards are "set up" and execution jumps back to the nearest error guard of the appropriate type whenever such an error happens after the guard has been set up.

frank

⎕←{c>10: }

oops

Dyalog APL

9:41 PM

@frank
{c>10:}

Adám

:} Cute.

frank

⎕←{c←⍵ ⋄ c>10: 'test' ⋄ c←11 ⋄ 'testing'} 9

Dyalog APL

@frank
testing

Adám

Ah, the scientist in action. Right, normal guards don't jump into action if the condition becomes true later.

@EdgyNerd That's actually it for dfns. There's another functional form (call tradfns) which allows all the traditional control structures, but it is also less elegant.

However, dfns have one more trick up their sleeve. Anonymous recursion. Are you up for it?

EdgyNerd

sure (although I will have to go in around 15 mins so that might be a problem)

Adám

9:46 PM

We can always start and continue another time.

EdgyNerd

ok

Adám

Inside a dfn, ∇ means the dfn itself. So e.g. we can define the factorial (in TMN) as:

f(x)={1         if x=1
      x×f(x-1)  otherwise

As a dfn: {⍵=1:1 ⋄ ⍵×∇⍵-1}

⍞←{⍵=1:1 ⋄ ⍵×∇⍵-1}4

Dyalog APL

@Adám 24

EdgyNerd

⍞←{⍵=0: ⍵×∇⍵-1 ⋄ 1}5

Dyalog APL

@EdgyNerd 1

EdgyNerd

9:49 PM

oh wait

why doesn't my one work?

Adám

@EdgyNerd It says: if the argument is 0, recurse with that formula, else return 1. 5≠0, so it gives 1.

EdgyNerd

oh right

⍞←{⍵≠0: ⍵×∇⍵-1 ⋄ 1}

Dyalog APL

@EdgyNerd      ∇{⍵≠0:⍵×∇ ⍵-1 ⋄ 1}

EdgyNerd

⍞←{⍵≠0: ⍵×∇⍵-1 ⋄ 1}5

Dyalog APL

@EdgyNerd 120

EdgyNerd

9:51 PM

:D

Adám

Yup

Are you familiar with Fibonacci numbers?

EdgyNerd

yep

Adám

Can you write the Fib function?

EdgyNerd

{⍵ ∇ ⍵ + ⍺}

⍞←0{⍵ ∇ ⍵ + ⍺}1

Dyalog APL

@EdgyNerd DOMAIN ERROR

EdgyNerd

9:54 PM

@Adám what will the Fib function do?

Adám

@EdgyNerd If the argument is less than or equal to 1 it gives 1, else it gives (Fib ⍵-1)+(Fib ⍵-2)

frank

so the nth Fibonacci number

Adám

Yeah.

EdgyNerd

⍞←{⍵>1: ∇⍵-1+∇w-2⋄1}5

Dyalog APL

@EdgyNerd VALUE ERROR

EdgyNerd

9:57 PM

⍞←{⍵>1: (∇⍵-1)+∇w-2⋄1}5

Dyalog APL

@EdgyNerd VALUE ERROR

Adám

@EdgyNerd You have a double-yoo instead of an omega.

EdgyNerd

⍞←{⍵>1: (∇⍵-1)+∇⍵-2⋄1}5

Dyalog APL

@EdgyNerd 8

EdgyNerd

oh ok

Adám

9:58 PM

Btw, a real full APL system would tell you much more:

      {⍵>1:(∇ ⍵-1)+∇ w-2 ⋄ 1}5
VALUE ERROR: Undefined name: w
      {⍵>1:(∇ ⍵-1)+∇ w-2 ⋄ 1}5
                     ∧

EdgyNerd

oh ok

Adám

@EdgyNerd That's very good. You're a quick learner.

You have to go, no?

EdgyNerd

yeah basically

Adám

OK, it was fun. Have a look at these lessons to build your APL vocabulary. And never hesitate to pop in and ask.

EdgyNerd

ok

I'll continue tomorrow I guess

Adám

10:01 PM

Sure. I should be around from 9 AM UTC or so.

frank

⎕←{⌽{⍵>1: 1 ⋄ (∇⍵-1)+∇⍵-1}⍳⍵}5

Dyalog APL

@frank
LENGTH ERROR

frank

⎕←{⌽{⍵>1: (∇⍵-1)+∇⍵-1 ⋄ 1}⍳⍵}5

Dyalog APL

@frank
LENGTH ERROR

Adám

@frank The condition is (⍳5)>1 which is neither 0 nor 1 so it is invalid.

What you probably want is to apply the function to each element of ⍳5, no?

frank

10:07 PM

⎕←{⌽{⍵>1: (∇⍵-1)+∇⍵-1 ⋄ 1}¨⍳⍵}5

Dyalog APL

@frank
16 8 4 2 1

frank

oh I see my mistake

Adám

Should one of your -1 be -2?

frank

⎕←{{⍵>1: (∇⍵-1)+∇⍵-2 ⋄ 1}¨⍳⍵}5

Dyalog APL

@frank
1 2 3 5 8

frank

10:08 PM

alright

so I assume ∇ looks at the function its currently in?

Adám

This is of course a horribly inefficient way to create Fibonacci numbers.

@frank That's correct. If you want to call another function, you can use its name or pass it in as an operand.

frank

yes I imagine creating fibonacci numbers backwards isnt the best way to do it haha

Adám

What you can do instead is iterate over a beginning pair, adding one more element, and then continuing with the last two elements.

frank

how would you keep track of where you are in the sequence?

Adám

⍞←{⍵,+/¯2↑⍵}1 1 2 3

Dyalog APL

10:11 PM

@Adám 1 1 2 3 5

Adám

@frank I don't understand. You don't need to, do you?

frank

if you wanted to get the first 10 fibonacci numbers, for example

Adám

You could have a condition on the length, and quit if long enough.

You could recurse and keep passing in the target length as the other argument.

Alternatively, you could apply the function N times. Do you know about ⍣?

frank

ah yes, I saw that when I looked at the bookmarked lesson

Adám

So you know how TMN writes f³(x) meaning f(f(f(x)))?

So that's a very different ³ than in x³.

We write x³ as x*3 and f³ as f⍣3:

⍞←{⍵,+/¯2↑⍵}⍣10,1

Dyalog APL

10:16 PM

@Adám 1 1 2 3 5 8 13 21 34 55 89

frank

⍞←10⍣⍨{⍵,+/¯2↑⍵}1

Dyalog APL

@frank SYNTAX ERROR

frank

ah oh well

Adám

⍣ is not a function but rather an operator, so ⍨ can't swap its operands.

Recursive version:

frank

makes sense

Adám

10:18 PM

⍞←10{⍺=≢⍵:⍵ ⋄ ⍺∇⍵,+/¯2↑⍵}1

frank

I just thought the comma make it look a bit confusing

Dyalog APL

@Adám 1 1 2 3 5 8 13 21 34 55

frank

makes sense

Adám

@frank It isn't actually needed, but something has to separate the 10 from the 1. ⊢ would do the trick, but since we're really dealing with a vector, I thought I'd initialise the right argument as a vector.

You can also use a parenthesis:

⍞←({⍵,+/¯2↑⍵}⍣10)1

Dyalog APL

@Adám 1 1 2 3 5 8 13 21 34 55 89

Adám

10:19 PM

Or simply give it a name:

⋄ Fib10←{⍵,+/¯2↑⍵}⍣10 ⋄ ⎕←Fib10 1

Dyalog APL

@Adám
1 1 2 3 5 8 13 21 34 55 89

Adám

Or you could wrap it in another dfn:

⍞←{{⍵,+/¯2↑⍵}⍣⍵⊢1}10

Dyalog APL

@Adám 1 1 2 3 5 8 13 21 34 55 89

frank

is there a way to get the ⍵ of another function?

if that makes sense

Adám

@frank Of an outer function?

frank

10:21 PM

I guess you could pass it into the inner function as ⍺ or something

yeah

Adám

Indeed. That's the best way. Alternatively, you can give that ⍵ a name in the outer function and the inner function will be able to "see" that name.

frank

10:35 PM

is there a sort builtin? I know ⍋returns indices in ascending order

but do I have to do e.g. ⍵[⍋⍵] to sort?

Adám

@frank No. I'm trying to push for one, or at least a better way to sort, but for now you have to do that or {(⊂⍋⍵)⌷⍵} or (⊂∘⍋⌷⊢).

If you're golfing, you can use my experimental "Extended Dyalog APL" which does have sort functions; monadic ∧ and ∨.

Bubbler

11:32 PM

@Adám In that case, I'd guess a single dyadic "sort-by" would work in most use cases

Adám

@Bubbler Our CTO has suggested removing the current dyadic ⍋ functionality and making dyadic ⍋ sort-by like in J. I really don't like removing backwards compatibility, and I find dyadic ⍋ pretty cool when it is what I need.

Bubbler

Then plain sort is f⍨ and sort-by-key is key f ⊢

though yeah, replacing ⍋ feels like too much of a breaking change

Adám

Yes. But I instead propose "sane indexing" ⊇ (alternative names: select, reorder, permute) which is simply ⌷⍤0 99. This allows sort to be ⍋⊇⊢ and sort-by key is data⊇⍨∘⍋key.

I'd actually also really like to see "reverse compose" f⍛g (alt.: against, before) which is (f ⍺)g ⍵ and then allows key⍋⍛⊇data for ⍋⍛⊇⍨data.

Bubbler

I don't really think I had a chance to use current dyadic ⍋ by the way

voidhawk

Same, never used but I don't do a lot of string processing

Adám

11:48 PM

Occasionally, it comes up in a code golf where it secures a win. Other than that, it can be used to do various human language sorts. Here are some examples.