The APL Orchard

Razetime

6:40 AM

How do I put multiple conditionals in a single dfn

do i just nest :s?

Bubbler

@Razetime {cond1: result1 ⋄ cond2: result2 ⋄ result3}

Adám

@Razetime What do you mean by multiple conditionals? {cond1∧cond2:'both'} maybe?

Razetime

like an if else hierarchy

@Bubbler I think it's this one

Adám

Then what Bubbler said.

Razetime

6:57 AM

f←{{⍺=0∧⍵=0:0⋄⍺=0∧⍵=1:1⋄⍺=1∧⍵=10:0⋄⍺=1∧⍵=11:1⋄⍺}/⍵}

This is my (very clunky) implementation for the talk interpreter

Adám

@Razetime Don't forget that ∧ is a normal function.

Razetime

oh yes, right to left

Adám

@Razetime ⍺=0∧⍵=0→⍺⍵≡0 0 etc.

@Razetime Hold on, it is simply a look-up table, no?

Razetime

yes pretty much

Adám

Why not pick the result from a list?

Razetime

7:02 AM

I didn't think of it

also I could just remove the outer function and use ⎕

Bubbler

@Razetime What is the input format of this function?

I think it could be simplified a lot

Razetime

a string or character list

I was planning on ⍎ with each chunk of 2 chars

then doing this

@Bubbler yeah, there's definitely a very short answer

Adám

@Razetime How can one become 10 or 11?

Bubbler

7:22 AM

If you map '00' '01' '10' '11' to 0 1 2 3 instead of 0 1 10 11, it's equivalent to {0 1∊⍨v←¯2⊥⍺⍵:v⋄⍺}/

Change ¯2 to ¯10 if you want 0 1 10 11

{⍺v⊃⍨0 1∊⍨v←¯2⊥⍺⍵}/ works too I guess

or (⊣(,⊃⍨0 1∊⊢)¯2⊥,)/

Adám

or {(0 1∊⍨V)⊃⊣,V←¯2⊥,)/

Bubbler

or {0::⍺⋄~~¯2⊥⍺⍵}/

Domain error FTW.

Adám

We need an adverse operator.

Razetime

@Bubbler so, convert from binary

Bubbler

Yeah, but ⍎ could be actually shorter

because if the original input is a string, you'll need ⍎ or ⎕D⍳ anyway

Razetime

7:35 AM

g←{((⍴⍵) ⍴ 1 0) ⊂ ⍵}

something like this

or is it fair to accept input as '01' '10' '00' '11'

that isn't a character vector is it

Bubbler

Right.

Razetime

codegolf.stackexchange.com/questions/190819/… Here's the question btw

Bubbler

Chunking: ⋄ ⎕IO←1 ⋄ {⍵⊂⍨2|⍳≢⍵}'0011010010'

Dyalog APL

@Bubbler 00 11 01 00 10

Razetime

How does this look: {{(0 1 ,(9/0), 0 1)[⍺+⍵]}/⍎¨((⍴⍵) ⍴ 1 0) ⊂ ('0',⍵)}

Bubbler

7:51 AM

Did you try running the code?

Razetime

not yet

I think ⎕IO←0 is required

Bubbler

There are two inputs (initial value and program), and you're taking only one.

Razetime

it takes the initial value and program together

Bubbler

separated by a space?

Razetime

that's why ('0',⍵) is used

no, no space

Bubbler

7:54 AM

Oh.

Razetime

input can be a single string, so it's allowed I guess

but something is still wrong

Bubbler

It's wrong because the reduction is done from the right.

So you need to reverse the entire array right before reduction

so it looks like <commands reversed> <initial>

Razetime

oh makes sense

Thanks for saving me a lot of time

Bubbler

Btw, looking through the submissions, an array of pairs of digits is a valid format for a program

Razetime

well, is it better to follow the question or the submissions?

Bubbler

8:00 AM

> You can ... split your input into valid commands (e.g. taking them as a list; e.g. [00, 01, 00]) if you like.

^ in the challenge description, so I guess it's OK.

But then there's something like this

Razetime

I guess that was more efficient there because it's a substitution

h←{{(0 1 ,(9/0), 0 1)[⍺+⍵]}/⌽⍵}

so this isn't working correctly

⋄{{(0 1 ,(9/0), 0 1)[⍺+⍵]}/⌽⍵} 0 00 01 11 11 01

Dyalog APL

@Razetime INDEX ERROR

Bubbler

⋄⎕IO←0⋄{{(0 1 ,(9/0), 0 1)[⍺+⍵]}/⌽⍵} 0 00 01 11 11 01

Dyalog APL

@Bubbler 0

Razetime

according to the test cases it's supposed to be 1

Bubbler

8:06 AM

⋄⎕IO←0⋄{{(0 0 1 ,(9/0), 0 1)[⍺+⍵]}/⌽⍵} 0 00 01 11 11 01

Dyalog APL

@Bubbler 0

Bubbler

No, that's totally wrong

Razetime

⋄{{(0 1 ,(9/0), 0 1)[⍺+⍵]}\⌽⍵} 0 00 01 11 11 01

Dyalog APL

@Razetime INDEX ERROR

Razetime

⋄⎕IO←0⋄{{(0 1 ,(9/0), 0 1)[⍺+⍵]}\⌽⍵} 0 00 01 11 11 01

Dyalog APL

8:07 AM

@Razetime INDEX ERROR

Bubbler

Razetime

hmm

maybe instead of adding 9 0's in the middle, change it to something else

and then return ⍺ by itself

l←{{⍺⍵≡0 0:0⋄⍺⍵≡0 1:1⋄⍺⍵≡1 10:0⋄⍺⍵≡1 11:1⋄⍺}/⍵} this one works

but adding doesn't seem to work, probably get indices in a matrix

which is probably bigger

Bubbler

Sum should work because 0 1 2 10 11 12 → 0 1 1 0 0 1

Razetime

I think I found the mistake

⋄⎕IO←0⋄{{(0 1 ,(9/⍺), 0 1)[⍺+⍵]}/⌽⍵} 0 00 01 11 11 01

Dyalog APL

@Razetime 1

Razetime

8:22 AM

silly me

we just need to replace the rest of the non conforming cases with ⍺ instead of 0

Adám

@Razetime 0 1 ,(9/⍺), 0 1 can be golfed (don't do this in production code) to ∊0 1(9/⍺)0 1

Razetime

⋄⎕IO←0⋄{{(0 1 ,(9/⍺), 0 1)[⍺+⍵]}/⌽⍵}0 00 01 00

Dyalog APL

@Razetime 1

Adám

Actually, 13⍴0 1,9/⍺ is shorter and better (fine for production code too).

Razetime

@Adám is it an extended thing?

Adám

8:24 AM

No, just bad form to go nested in the process of generating flat data. And it is a bit obscure too.

Razetime

@Adám nice, I'll add that in

Adám

@Razetime Btw, you can remove the outer {…⍵}

rak1507

lol my computer science teacher just said we won't cover multi dimensional arrays until next year... maybe APL is a bit out of reach for now :(

Razetime

Yes I was going to do that, just needed arguments

Now it can be replaced with ⎕

Bubbler

You don't even need ⎕, it's a valid 2-train

Adám

8:28 AM

@Razetime The inner function can be tacit: (+⌷13⍴0 1,9/⊣)

Razetime

How do tacit functions work with reduction?

Adám

@Razetime Reduction doesn't care what type its operand is.

Razetime

⊣ is ⍺ and ⌷ is ⍵?

Bubbler

Wrap the tacit function in parens and apply / like (+⌷13⍴0 1,9/⊣)/.

Adám

@Razetime No, + is ⍺+⍵ and ⌷ does indexing into the list.

Bubbler

8:31 AM

⍵ is ⊢.

But I think the arguments should be reversed, because ⍺ is the command and ⍵ is the accumulator there

Razetime

what does the / in the tacit fn do?

Bubbler

That's replicate.

But that works as replicate only when its left side is a constant

Razetime

coool

tio.run/##SyzI0U2pTMzJT///qKM97b@G9qOe7YbGj3q3GCgY6ljqP@parKn/…

what setup do i use for this?

Bubbler

8:47 AM

(If you take input as something like 0(0 0)(0 1)(1 1)(1 1)(0 1), then you can do (0<-/⍤,⍨)/⌽)

@Razetime This

And you need to change ⊣ to ⊢, as I said earlier

Razetime

oh, great

Bubbler

You'll need that footer line a lot if you golf in APL regularly

Razetime

@Bubbler well, it's already a bit ambiguous whether we should use the current solution , so, maybe not? I'm not sure.

Yep I'll bookmark it

Bubbler

Yeah, just an idea. I think yours is valid enough

Razetime

9:07 AM

so how dos that work?

compare first with o and subract if true

Bubbler

Attach ⍵ and ⍺ in that order, and add the two ends and subtract the middle.

Then you magically get positive when ans is 1, and non-positive when ans is 0.

Razetime

Very very elegant

0(0 0)(0 1)(1 1)(1 1)(0 1) type vector from a normalstring

maybe it'd be smaller

Adám

10:14 AM

Announcement: We're about to launch a site that verifies solutions to the APL Programming Competitions' phase I problems for the last few years. Let me know if you want to test the site (you'll probably have to solve the problems) and/or write some APL code to implement lenient checking of user solutions.

6

Bubbler

@Adám How does "lenient checking" work?

Adám

We have a reference implementation f and then we do (f(≡⍥p)your_function) where p is a post-processing function.

Bubbler

So the p can be defined per task?

rak1507

@Adám would love to test it!

Adám

@Bubbler Yes, of course.

@rak1507 Want to meet on Zoom?

rak1507

10:29 AM

Would it be possible at around 3-ish?

What time zone?

BST

I can do 14:45.

I won't be home in time unfortunately

Adám

What's your availability tomorrow?

rak1507

10:32 AM

Probably from 4 roughly

Adám

OK, lets say then then. Ping me when available. My Zoom ID is the result of -\758,435,8447 in APL.

rak1507

Alright great

Adám

10:57 AM

If anyone else wants to join too, they are welcome.

Razetime

11:11 AM

@Adám Sure, i'm in

Razetime

12:25 PM

⋄{⍺≠⍵}\1 1 1 2 2 2 2 3 3 3

Dyalog APL

@Razetime 1 0 1 1 1 0 0 0 0 0

Razetime

≠⍀1 1 1 2 2 2 2 3 3 3

⋄≠⍀1 1 1 2 2 2 2 3 3 3

Dyalog APL

@Razetime 1 0 1 1 1 0 0 0 0 0

Razetime

why doesn't it show the places where two numbers aren't equal?

aka 0 0 1 0 0 0 1 0 0 0

dzaima

@Razetime \ is a weird operation (≠\1 2 3 4 is (1)(1≠2)(1≠2≠3)(1≠2≠3≠4), plus regular APL RTL evaluation, aka it's O(n^2)). you probably want 2≠/x

Razetime

12:46 PM

⋄2≠/1 1 1 2 2 2 2 3 3 3 4 4 4

Dyalog APL

@Razetime 0 0 1 0 0 0 1 0 0 1 0 0

Razetime

yupppp

⋄2≠/1 1 1 2 2 2 2 3 3 3 2 2 2

Dyalog APL

@Razetime 0 0 1 0 0 0 1 0 0 1 0 0

Adám

@dzaima ≠\ is O(n) but {⍺≠⍵}` is O(n²):

      ]runtime -c ≠\v1 ≠\v2 ≠\v3 ≠\v4

  ≠\v1 → 4.5E¯7 |    0% ⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕
* ≠\v2 → 8.2E¯7 |  +83% ⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕
* ≠\v3 → 1.0E¯6 | +133% ⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕
* ≠\v4 → 1.5E¯6 | +230% ⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕

      v1←1=?1e2⍴2
      v2←1=?2e2⍴2
      ]runtime -c {⍺≠⍵}\v1 {⍺≠⍵}\v2

  {⍺≠⍵}\v1 → 1.2E¯3 |    0% ⎕⎕⎕⎕⎕⎕⎕⎕⎕
* {⍺≠⍵}\v2 → 5.1E¯3 | +321% ⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕⎕

Razetime

hmm

The drop function removes eveything before an index

how do i drop only one element

dzaima

12:54 PM

@Adám still O(n^2) for integers

(but you're right that most cases of \ would be O(n)ified by the implementation)

@Razetime by a specific index?

Razetime

yep

dzaima

@Razetime not very simple (concatenating before and after is probably your best bet)

(in dzaima/APL i have this (drop last item of the first 3 items) but that's a dzaima/APL-specific feature)

Razetime

I'll find something

Adám

@Razetime ⋄ 3(↑,1↓↓)'abcde'

Dyalog APL

@Adám abce

rak1507

1:00 PM

{∩/(↑∘⍵)¨(⍺,-⍺)}

oh you wanted to drop it

dzaima

another alternative - ≠∘⍳∘≢⊢⍤/⊢

rak1507

and that's dumb anyway

Adám

@dzaima That's nice in being sensitive to ⎕IO and being modifiable to remove multiple.

Razetime

how would it work if you wanted to remove multiple?

dzaima

@Razetime you'd need to use something like (~∊⍨) instead of ≠

Adám

1:04 PM

@Razetime Yeah, ↑ : ⋄ 1 3(~⍤∊⍨∘⍳∘≢⊢⍤/⊢)'abcdef'

Dyalog APL

@Adám bdef

dzaima

@dzaima (obligatory performance comparison)

Adám

Simpler: ⋄ 1 3{⍵[⍺~⍨⍳⍴⍵]}'abcdef'

Dyalog APL

@Adám bdef

Adám

I should add that one to APLcart.

dzaima

1:08 PM

@Adám it's 2x slower in the single item case

Adám

Multi-item case performance comparison coming up?

dzaima

@Adám i don't have anything to compare to

(oh right, i do)

Adám

⊂⍤~⍨∘⍳∘≢⌷⊢ works for any rank.

dzaima

@Adám there you go

Adám

@dzaima Wow, I was about to suggest ⍸⍣¯1 but thought it'd be silly.

dzaima

1:14 PM

@Adám it's able to utilize sortedness

Adám

Nice example of why / should be extended to imply trailing 0s like ⊂. Unfortunately, backwards compatibility prevents that.

dzaima

@Adám damn singletons

(though i would personally blame ⍸⍣¯1 on not being able to know information it should (i.e. the original length))

Adám

It (kind-of) did in Iverson Notation.

dzaima

@Adám how?

Adám

@dzaima Special vectors.

rak1507

1:23 PM

Wow, thought I'd found a better way to do something, timed it, 12000% increase in time, oh well

Adám

Just noticed that Iverson originally regarded all non-zero values as truthy.

Razetime

@rak1507 tends to happen here lol

rak1507

wow never seen a 204900% increase before, well now I have

Marshall

@dzaima I did actually write some O(n) code for integer comparison scans in Dyalog, but decided it wasn't worth the risk of introducing bugs. It works on basically the same principle as the boolean case: some left arguments give the same result regardless of the right argument, once the right argument is boolean.

Adám

1:46 PM

@Marshall I doubt anyone ever uses comparison scans for integers other than Booleans.

Marshall

@Adám Ah, that wasn't quite right: I implemented the reductions, not scans (the benefit being that reductions can shortcut and be sublinear). And these are used, but only on an axis of length 2.

Adám

@Marshall Wait, if they are only used on axes of length 2 (I agree on that), then there's nothing to shortcut, is there?

Marshall

@Adám You can stop after one comparison. Which is what you would be doing anyway. I think the shortcutting version came out to be about the same speed as the one Dyalog has now, but a dedicated length-2 reduction method would be much better than either.

Adám

2:02 PM

Announcement: Webinar on 18.0 extensions to X⊂Y and ↑[ax]Y in an hour on dyalog.tv.

Marshall

2:38 PM

@dzaima and anyone else interested: I've been thinking that characters should be treated as an affine space in BQN (like the points in a plane or line, which have relative position but no particular origin). That means you can add or subtract numbers from characters, but not add two characters or negate a character.

ngn

@Marshall what about subtracting two chars?

Marshall

Following a little-known but good way of thinking about affine spaces, a character is a number plus one "characterness" (which comes from an origin character, probably null). Characterness is linear and an operation is allowed if it results in a value with zero or one characterness. Negating a character gives -1 and adding two gives 2, so they aren't allowed. Of course a character result also has to be a valid code point.

@ngn Yes, that works too. In theory you could also do (a+b)÷2 where a and b are characters, but since the intermediate result a+b isn't valid you have to work around with a+(b-a)÷2.

This means you can get the alphabet with 'a'+↕26, and •UCS can be replaced by adding or subtracting the null character. Since you probably don't want the null character in your source code, there should probably be a primitive or system value for it.

TessellatingHeckler

If you subtract the characterness do you get the codepoint? 'a' - ? = 97

oh, yes; cool

Marshall

@TessellatingHeckler I guess you figured it out but characterness is a property and not an actual value: every character has one characterness so any one of them is equally valid as an origin point. If you've ever wondered about the distinction between points and vectors it is the same: a point has one pointness and a vector has none.

ngn

@Marshall following this logic: 'c'='c'*1 and 0='c'*0 :)

Marshall

2:53 PM

The theory would also imply 0×c and c÷∞ give 0 while 1×c and c÷1 give c. This kind of makes sense, and it's nice that 1 would be the identity element of × over all data values, but I'm not sure I'd require it of implementations.

Adám

@Marshall Shouldn't mix pad with null chars?

TessellatingHeckler

@Marshall can't say I have wondered about such a distinction; are you saying if you add pointness to a vector, you get ... a point?

Marshall

@Adám Actually this gives a reason why the pad doesn't have to be a null character, because it doesn't give any direct correspondence between numbers and characters. We can say null is the smallest valid character (but we could do that with TAO anyway), but we can't say it is like 0 in any way.

Adám

Webinar in 2 mins.

Marshall

@TessellatingHeckler If you add an origin point to a vector (which necessarily has one pointness), you get a point. You can't just add one pointness; there's no such thing.

dzaima

3:00 PM

@TessellatingHeckler a vector and a point require storing the same things - a single x and y position. The difference is that a point has a specific origin whereas a vector doesn't

TessellatingHeckler

and it turns a relative path into a fixed path, huh

ngn

this reminds of the two kinds of temporal types in k - cuando (when) vs cuanto (how long)

TessellatingHeckler

that would be a System.DateTime vs a System.TimeSpan in .Net?

ngn

@TessellatingHeckler no idea

Marshall

@ngn Yep. Time is a 1d affine space!

TessellatingHeckler

3:06 PM

in that you can add a datetime + timespan to get a new datetime, but you can't add two datetimes

ngn

@TessellatingHeckler yes, sounds right

it's also similar to the distinction between ordinal numbers (indices; affected by ⎕io) and cardinal numbers (lengths; immune to ⎕io)

Marshall

@ngn So it is. I hadn't thought about it that way before. That explains why ⎕IO←1 breaks mainly when you scale indices.

dzaima

@ngn beautiful

Marshall

In that interpretation the ⎕IO question is whether to use the earliest position in an array as the origin (0) or a virtual position just before it (1).

ngn

@Marshall for me there's no ⎕io question - always use 0 :)

dzaima

3:21 PM

@ngn now the BQN question will be what's the ⎕IO of characters :p

(also i wonder how'd APL look if ordinals and cardinals were different types)

Marshall

@dzaima There's no index operation, so no need to choose!

@dzaima This is exactly the pointer/index distinction from C, so a lot like that. I don't know how I missed that pointer/index is the same as point/vector. I've spent so much time with both. It's like finishing two entire halves of a jigsaw puzzle and I finally learned they go together.

dzaima

@Marshall oh wow

Marshall

"Oh, this brings me to another example of an affine space: The space of pointers in C"

In much greater depth

I guess I could just use ␀ as the literal null character. @ is also possible as ^@ sometimes represents null.

Marshall

4:40 PM

Javascript BQN now supports affine characters! + and - only, not × or ÷.

cannadayr

5:18 PM

@Marshall could you give an example of how this behavior is different? (the "how can I use this change?")

cannadayr

5:38 PM

ah so it seems like instead of a explicit list 0,1,2,3,4,5,6,7,8,9 its using a point & offset

does this effect anything outside of the compiler?

TessellatingHeckler

@cannadayr It should mean that you can do 'a' + 3 and get 'd' without having to do ⎕UCS 3+(⎕UCS 'a')

cannadayr

oh nice gotchya

TessellatingHeckler

hmm, presumably 'abc'+3 does scalar expansion(?) and becomes 'def'? and 'abc' + 1 2 3 becomes 'bdf'?

Marshall

All sorts of possibilities. Get the Greek alphabet (with both initial and final sigma) with 'α'+↕25; quick lowercasing for the latin one by adding 32; find the value of a digit by subtracting '0'.

@TessellatingHeckler Yes. Try it out here.

TessellatingHeckler

inb4 my favourite nitpick; ২ is a perfectly valid digit according to regex \d

cannadayr

5:49 PM

@TessellatingHeckler what regex engine? I tested grep on osx & linux and it didn't match

TessellatingHeckler

@Marshall Nice! mlochbaum.github.io/BQN/try.html#code=IjQ1NiItJzAn this has got to be one of the golfier ways to get the digits of a number.

@cannadayr my default regex engine, .Net (PowerShell / C#). It's also not PCRE compatible, so maybe that matters.

cannadayr

ahh yea i dont mess around w/ windows hah. there be dragons.

if I cant recompile my operating system, is it really mine?

3

TessellatingHeckler

PowerShell and .Net Core are MIT licensed, open source, and macOS / Linux compatible these days ;)

cannadayr

nah im good

TessellatingHeckler

just ... beware of the telemetry, because there always has to be a Microsoft catch

cannadayr

5:52 PM

dont trust microsoft

^ exactly

chromium is open source but that doesnt make it foss imo

Marshall

@TessellatingHeckler dzaima/BQN regex (•_R_) doesn't recognize it, but of course if you want to then there are ways.

TessellatingHeckler

6:08 PM

@Marshall not that I particularly want to, I merely nitpick when people use \d to validate Arabic numerals, not realising it (in .Net) also covers numerals from other number systems

Marshall

@TessellatingHeckler Ah, yeah, I can see how that could cause some problems.

TessellatingHeckler

mlochbaum.github.io/BQN/try.html#code=J+CnqCctJ+Cnpic= translation compared to Bengali-0 to the rescue to find the value :D

Marshall

Another cool property is that if you have a runtime that optimizes with 1-byte ints, but only signed ones (such as Dyalog), you can convert directly from one-byte characters (ÿ and earlier) to one-byte ints by subtracting 128+@ instead of @, where @ is the null character. In Dyalog you'd probably need ⎕DR to avoid going through 2-byte ints and wasting memory.

Adám

6:39 PM

@TessellatingHeckler With PCRE you have to turn UCP on to get that behaviour.

rak1507

7:17 PM

Oh no I missed the webinar :(

Adám

@rak1507 It is was recorded, and the slides are also available for download.

rak1507

Yeah, I'm watching it on youtube just now

Ooh that partitioned enclose thing is so cool

Adám

Yeah, I'm happy how that extension turned out.

rak1507

There are so many cool features in the primitives, I really need to read more docs

rak1507

7:33 PM

Explaining -style=max is pretty handy too

voidhawk

10:04 PM

Wow, just upgraded from 17.1 -> 18.0 and seeing around 25% speedup on average for my AoC answers

Planning to do a video on 2019 day 14 in the near future, 18.0 puts my part 2 solution at 140µs which is faster than anything I see on Reddit

Adám

@voidhawk looking forward.

ngn

@voidhawk including k?

voidhawk

Haven't checked yours :)

ngn

@voidhawk did you mean milliseconds (not micro-)?

voidhawk

Nope, micro

ngn

10:19 PM

@voidhawk dyalog can't even start in that amount of time :)

voidhawk

Yeah, I'm just using cmpx in RIDE, I guess it's not really a fair comparison

ngn

@voidhawk it's fair, i just have to use \t to measure in k, not end-to-end

voidhawk

For the entirety of p14 (read from disk, parse, p1, p2) cmpx gives me 770µs

ngn

@voidhawk is this your solution?

voidhawk

I made some changes, hold on

ngn

10:25 PM

no rush

voidhawk

gist.github.com/voidhawk42/398091adbf8339186712b5422edb7c63

ngn

@voidhawk thanks! i'll test in a moment

on my laptop cmpx says 8.8e¯4 for both parts. that's close to your measurement.

voidhawk

Nice, I tested on a desktop with a fairly recent processor

i7-8700 apparently

ngn

mine is an i5-7200U

my ngn/k solution takes ~64ms. my k9 solution takes ~6ms. (but my algorithm is probably bad)

i'll have to translate yours for a fair comparison

voidhawk

10:42 PM

Thanks, that'd be cool to see - aside from parsing I'm not really using any fancy primitives, just matrix indexing/math

I was surprised that ⌈/r in line 3 is faster than directly indexing with n⌷⍤0 1⊢r but apparently it is (??)

ngn

10:54 PM

@voidhawk on the second line, why do you have to enclose i⍳⊂'FUEL'? it's a simple scalar

voidhawk

Yeah, refresh

I mistyped it

ngn

11:10 PM

i'm moving too slowly, only a line and a half so far :)

voidhawk

Lol

Made some changes that get me down to 7.4E¯4

Might just be noise at this point

ngn

i suspect that after i get past r×⍤1 0 it will get easier..

ngn

11:38 PM

yay, i did part 1 (in k9)

voidhawk

Nice!

ngn

turned out the ×⍤1 0 is just * in k :) (in this particular case)

voidhawk

Oh neat, k has leading-axis agreement (think that's what it's called)?

ngn

@voidhawk i guess you could put it that way

k has only scalars and vectors. for matrices we use vectors of vectors.

Bubbler

@ngn If a vector of vectors can be jagged (non-rectangular), how does K deal with them when it is passed to a matrix function?

ngn

11:49 PM

@Bubbler i think the only interesting case is "flip" (i.e. transpose, monadic +). there are different opinions about what it should do - pad, repeat, or error.

@Bubbler can you think of another primitive that relies on the argument being a matrix?

Transcript for