The APL Orchard

Uriel

12:16 AM

@Zacharý "Row Of Many Candles" seriously?

Adám

@Uriel Apparently 8 (or 9?) is many.

Zacharý

@Uriel Yeah, that'd be them trying to be inclusive of all religions or something.

Adám

2:29 PM

To participate in tonight's learning session without 20 Stack Exchange rep points, click lower-left giant avatar, then click "user profile" and there will be a number in the URL; that's your chat ID. Email your chat ID to adam@ with the domain being dyalog.com.

Feeds

3:20 PM

Adám is hosting the last informal APL learning session of the year tonight at 18:30 UTC in https://chat.stackexchange.com/rooms/52405/apl finishing up the "APL primitive functions' marathon". See https://chat.stackexchange.com/transcript/message/41299896 if you don't have 20 Stack Exchange rep points.

Tweeted by dyalogapl on December 20, 2017 at 2:33 PM

Erik the Outgolfer

6:24 PM

@Adám awake? ;) lesson starts in 6 minutes :P

Adám

@EriktheOutgolfer Sure I am.

Erik the Outgolfer

@Adám thanks, just checking I get to learn something new this time

Zacharý

@EriktheOutgolfer :)

DId this marathon cover functions and operators, or just functions?

Erik the Outgolfer

(btw I've never actually not learned anything at all, I always learn new tiny details)

@Zacharý functions

@Zacharý the operators are in previous lessons, you can read them up from here

Zacharý

Oh

Erik the Outgolfer

6:29 PM

(specifically lessons 3-6)

@Adám half a minute too early :D

Adám

Welcome to the APL learning session!

Let's try to finish the functions' marathon, beginning with ⍴.

We've met ⍴ (Greek Rho) in passing before. But now it is the actual subject.

⍴ is maybe the most fundamental function in an array language, as it allows the formation of multi-dimensional (high-rank) arrays.

Zacharý

IIRC, ⍴ is not actually greek rho in unicode,

Adám

@Zacharý Right, Dyalog APL only uses the special Unicode APL Rho.

@Zacharý Useful if we ever allow Greek identifiers.

Erik the Outgolfer

@Zacharý but it resembles one

Adám

The Greek letter Rho is has the sound of the letter R, and stands for Reshape.

The right argument of ⍴ is used in ravel order to fill an array with the dimensions given by the left argument.

The left argument must therefore be a vector (list) of dimension lengths. (Although for ease of use, we do allow a scalar instead of a one-element vector.)

Another way to look at it is that the left argument of ⍴ is the index of the last element in the resulting array (if you stick to the default ⎕IO of 1).

If you omit the shape (left argument) then the current shape is returned.

⍞←3⍴'a'

Dyalog APL

6:35 PM

@Adám aaa

Adám

⍞←3⍴'ab'

Dyalog APL

@Adám aba

Adám

⍞←3⍴'abcd'

Dyalog APL

@Adám abc

Adám

⎕←2 3⍴'abc'

Dyalog APL

6:36 PM

@Adám
abc
abc

Adám

That's two rows and three columns. The order of the left argument is the number of major cells first and of "leaf" cells last.

⎕←3 4 5∘.+10 20 30 40

Dyalog APL

@Adám
13 23 33 43
14 24 34 44
15 25 35 45

Adám

⍞←⍴3 4 5∘.+10 20 30 40

Dyalog APL

@Adám 3 4

Adám

A scalar doesn't have any dimensions, so the corresponding left argument is ⍬ (or 0⍴0)

⍞←⍬⍴3 4 5∘.+10 20 30 40

Dyalog APL

6:39 PM

@Adám 13

Adám

@all Good? Questions?

Zacharý

⎕←⍬⍬⍴3 4 5∘.+10 20 30 40

Dyalog APL

@Zacharý

Rebuilding user command cache... done
Was OFF -trains=box -fns=off
⍎DOMAIN ERROR
 __field_initialize_result_←(⎕NS ⍬).⍎'⎕CY''salt''⋄⎕SE.UCMD''box on -fns=on -trains=tree''⊣enableSALT' ⋄ ⎕←⍬ ⍬⍴3 4 5∘.+10 20 30 40
                                                                                                        ∧

Real time: 1.670 s
User time: 1.513 s
Sys. time: 0.059 s
CPU share: 94.11 %
Exit code: 0

Adám

@Zacharý You mean 0 0?

Zacharý

⎕←0 0⍴3 4 5∘.+10 20 30 40

Dyalog APL

6:41 PM

@Zacharý

Rebuilding user command cache... done
Was OFF -trains=box -fns=off

Real time: 1.304 s
User time: 1.118 s
Sys. time: 0.056 s
CPU share: 89.95 %
Exit code: 0

Erik the Outgolfer

yeah left argument must be a vector

Adám

@EriktheOutgolfer Simple vector, that is.

Erik the Outgolfer

@Adám you mean non-nested right

because ⍬⍬ is nested

Adám

Right, I didn't cover empty arrays. If one or more dimensions are 0, then the array doesn't have any elements, but it is still there. If it has rank 2 or higher, then it has an empty default display, and the chat bot instead shows the debug info.

@EriktheOutgolfer Yes, in APL lingo, simple means non-nested.

Erik the Outgolfer

⎕←0⍴1 2 3

Dyalog APL

6:43 PM

@EriktheOutgolfer

Erik the Outgolfer

⎕←0 0⍴1 2 3 4 5 6

Dyalog APL

@EriktheOutgolfer

Rebuilding user command cache... done
Was OFF -trains=box -fns=off

Real time: 1.174 s
User time: 1.102 s
Sys. time: 0.039 s
CPU share: 97.24 %
Exit code: 0

Adám

In Lesson 1 we covered prototypes, which are a feature of such empty arrays.

If an array has no elements, then ⍴ will uses its prototype to fill any array it needs to form:

RosLuP

⎕←⍬+⍬

Dyalog APL

@RosLuP

Adám

6:45 PM

⎕←2 3⍴⍬

Dyalog APL

@Adám
0 0 0
0 0 0

RosLuP

⎕←⍬+1

Dyalog APL

@RosLuP

Adám

Remember that ⍬ is just 0⍴0 so it being simple and numeric, its prototype is 0.

@RosLuP Here 1 gets paired with every element of ⍬, but there are non, so the result is still ⍬ and thus the bot gives you an empty line as result.

OK, I think we can move on now.

Monadic ⌽ is reverses the leaf rank-1 sub-arrays of an array. For a matrix, it means reversing each row (not the order of rows, we'll get there):

⎕←2 4⍴⍳8

Dyalog APL

@Adám
1 2 3 4
5 6 7 8

Adám

6:48 PM

⎕←⌽2 4⍴⍳8

Dyalog APL

@Adám
4 3 2 1
8 7 6 5

Adám

For a vector, it simply means reversing the vector:

⎕←⎕A ⋄ ⎕←⌽⎕A

Dyalog APL

@Adám
ABCDEFGHIJKLMNOPQRSTUVWXYZ
ZYXWVUTSRQPONMLKJIHGFEDCBA

Adám

Of course, it doesn't affect scalars.

It has a sibling, just like / and \ have ⌿ and ⍀, namely ⊖ which I usually call "Flip".

⊖ reverses the order of major cells, which for a matrix means reversing the order of the rows, i.e. flipping it upside down:

⎕←⊖2 4⍴⍳8

Dyalog APL

@Adám
5 6 7 8
1 2 3 4

Adám

6:52 PM

For vectors, it is the same as ⌽ and again it does nothing to scalars.

For a 3D array, it reverses the order of layers:

⎕←4 2 3⍴⎕A

Dyalog APL

@Adám
ABC
DEF

GHI
JKL

MNO
PQR

STU
VWX

Adám

⎕←⊖4 2 3⍴⎕A

Dyalog APL

@Adám
STU
VWX

MNO
PQR

GHI
JKL

ABC
DEF

Adám

Dyadic ⌽ and ⊖ do rotations instead of reversals:

⍞←3⌽⎕A

Dyalog APL

@Adám DEFGHIJKLMNOPQRSTUVWXYZABC

Adám

6:54 PM

⎕←1⊖4 2 3⍴⎕A

Dyalog APL

@Adám
GHI
JKL

MNO
PQR

STU
VWX

ABC
DEF

Adám

Negative rotation amounts just rotate to the other way:

⍞←¯3⌽⎕A

Dyalog APL

@Adám XYZABCDEFGHIJKLMNOPQRSTUVW

Adám

Here is a cool feature of ⌽ and ⊖: If you give them a vector of rotation amounts, they get distributed on the relevant cells:

⎕←3 4⍴⎕A

Dyalog APL

@Adám
ABCD
EFGH
IJKL

Adám

6:56 PM

⎕←1 0 2⌽3 4⍴⎕A

Dyalog APL

@Adám
BCDA
EFGH
KLIJ

Adám

⎕←1 0 ¯1 0⊖3 4⍴⎕A

Dyalog APL

@Adám
EBKD
IFCH
AJGL

Adám

⌽ and ⊖ also have a cousin named ⍉ (Transpose). The monadic function does not reverse the major cells or the rank-1 cells, but rather reverses the order of the indices. For matrices this is normal transposing:

⎕←3 4⍴⎕A

Dyalog APL

@Adám
ABCD
EFGH
IJKL

Adám

6:59 PM

⎕←⍉3 4⍴⎕A

Dyalog APL

@Adám
AEI
BFJ
CGK
DHL

Adám

But for arrays of rank higher than 2 it helps to think of the shape as being reversed:

⎕←2 3 4⍴⎕A

Dyalog APL

@Adám
ABCD
EFGH
IJKL

MNOP
QRST
UVWX

Adám

⎕←⍉2 3 4⍴⎕A

Dyalog APL

@Adám
AM
EQ
IU

BN
FR
JV

CO
GS
KW

DP
HT
LX

Adám

7:01 PM

If you look carefully, you can see that the runs like ABCD which originally spanned rows are now spanning layers. Look at the top left corner of each new layer.

So too are the layers now spanning rows. Look how the top left of the layers, A and M are now next to each other in a row.

While the column AEI is still a column, because reversing the shape 2 3 4 (layers, rows, columns) gives 4 3 2 (columns, rows, layers) so the runs spanning rows are in the same position, still spanning rows.

Now you know how to reverse the order of axes, but what if you want an entirely new order. That's what dyadic ⍉ does. The left argument is the indices of the axes in the desired order.

Therefore, if we reverse the indices of the rank, it is the same as monadic transpose:

⎕←3 2 1⍉2 3 4⍴⎕A

Dyalog APL

@Adám
AM
EQ
IU

BN
FR
JV

CO
GS
KW

DP
HT
LX

Adám

But now we can keep the layers and only reverse (i.e. transpose columns/rows):

Zacharý

And the number that the minimum number is depends on ⎕IO, correct>

Adám

⎕←1 3 2⍉2 3 4⍴⎕A

Dyalog APL

@Adám
AEI
BFJ
CGK
DHL

MQU
NRV
OSW
PTX

Adám

7:07 PM

@Zacharý Yes.

Here is a very cool thing: You can duplicate indices in the left argument. If so, APL will merge the indicated axes, taking only the elements that have equal indices along those two axes. This is the diagonal or diagonal plane, or diagonal 3D array (!), etc.

⎕←3 4⍴⎕A

Dyalog APL

@Adám
ABCD
EFGH
IJKL

Adám

⎕←1 1⍉3 4⍴⎕A

Dyalog APL

@Adám
AFK

Adám

⎕←1 1 1⍉2 3 4⍴⎕A

Dyalog APL

@Adám
AR

Adám

7:11 PM

⎕←1 1 2⍉2 3 4⍴⎕A

Dyalog APL

@Adám
ABCD
QRST

Adám

Here the layers and rows got merged, i.e. 1st row of 1st layer and 2nd row of 2nd layer, while the columns stayed as is.

⎕←1 2 1⍉2 3 4⍴⎕A

Dyalog APL

@Adám
AEI
NRV

Adám

Here we merged layers and columns, i.e. 1st column of 1st layer and second column of 2nd layer.

Erik the Outgolfer

@Adám yeah, it's out-worldly

Adám

7:15 PM

@all Quite a mouthful. Any questions? Any brain matter that needs mopping up from the floor?

6

Zacharý

@Adám "right left argument" ... I know what you mean, but still

Adám

Anyway, dyadic ⍉ is pretty advanced and quite rarely used, but when you need it (and can figure out the correct left argument — experiment!) it is really handy.

Right, now we move on to ⍎ then.

Zacharý

I can see something like 1 1 ⍉ (or 0 0⍉) gets used a lot

Adám

@Zacharý Yeah, diagonals are nifty.

CMC: If I give you a multiplication table, can you tell me what the original numbers were?

E.g. for 3 3⍴9 6 12 6 4 8 12 8 16 the original numbers were 3 2 4.

Erik the Outgolfer

⎕←3 3⍴9 6 12 6 4 8 12 8 16

Dyalog APL

7:21 PM

@EriktheOutgolfer
 9 6 12
 6 4  8
12 8 16

Zacharý

{.5*⍨1 1⍉⍵}

Leaky Nun

square root along the diag lol

Erik the Outgolfer

@LeakyNun that

Zacharý

@LeakyNun Ninja'd

Adám

@Zacharý Perfect.

Remember how ⊥ evaluates polynomials and mixed-radix numbers?

Erik the Outgolfer

7:24 PM

btw @Zacharý you can also do it in a more proper way, avoiding reciprocals (well, theoretically at the very least) leading to imprecision

{(*∘2⍣¯1)1 1⍉⍵}

RosLuP

⎕←{.5*⍨1 1⍉⍵}3 3⍴9 6 12 6 4 8 12 8 16

Dyalog APL

@RosLuP
3 2 4

Zacharý

If ∘.×⍨⍣¯1 works (I don't think it does), that would be amazing

RosLuP

⎕←{1 1⍉⍵}3 3⍴9 6 12 6 4 8 12 8 16

Adám

@Zacharý I've already requested this.

Dyalog APL

7:25 PM

@RosLuP
9 4 16

Adám

@EriktheOutgolfer Or {(×⍨⍣¯1)1 1⍉⍵}

Erik the Outgolfer

@Adám well, I'm trying to make my code readable :p

Zacharý

@EriktheOutgolfer That is pretty readable

Adám

Anyhow, ⍎ also evaluates, but rather than numbers, it evaluates a string representing a line of APL.

⍞←⍎'2+3'

Dyalog APL

@Adám 5

Adám

7:28 PM

It works with functions too:

⍞←2(⍎'+')3

Dyalog APL

@Adám 5

Adám

And with multiple statements:

⍞←⍎'a←2 ⋄ a←a+3 ⋄ a'

Dyalog APL

@Adám 5

Zacharý

So, does that mean when interpreting trains, ⍎ acts like reduce and scan?

Adám

@Zacharý What?

Zacharý

7:31 PM

Since ⍎ can evaluate functions, is it also an operator?

Erik the Outgolfer

huh

Adám

The result of ⍎ is the result of the last statement, if that has a result. If it doesn't (e.g. it is an empty statement or has a leading {}), then ⍎ doesn't have a result either.

@Zacharý You mean since it can return functions? No, normal tradfns can return functions too.

Zacharý

Oh, okay, that makes sense.

Adám

@Zacharý However, the result of ⍎ can be a monadic operator:

⍞←≢(⍎'¨')'abc' 'defg'

Dyalog APL

@Adám 3 4

Zacharý

7:33 PM

⍞←≢(⍎'⍎''¨''')'abc' 'defg'

Dyalog APL

@Zacharý 3 4

dzaima

@Zacharý I remember a while ago being "disappointed" that that doesn't work :p

Adám

@Zacharý Here we go; APL pornography.

Erik the Outgolfer

#APLporn

Zacharý

Um ... can you explain? Is this some sort of in-joke>

Adám

7:35 PM

@EriktheOutgolfer APLers call unreadable and/or hacky APL pornography.

Erik the Outgolfer

"porn" is an expression used to mean "pleasuring/extreme level/insane"

Zacharý

@Adám Sorry, I meant to type something else

Erik the Outgolfer

@Adám and PPCG right here is a large example :p

Adám

Even something like A←'abcd',0⍴D←1 2 3 4 could be considered pornographic.

Zacharý

⍞←≢((⍎'⍎')'¨')'abc' 'defg'

Dyalog APL

7:36 PM

@Zacharý 3 4

Uriel

@Adám what is the problem with the train (1 1∘⍉,1↑(⍉,⊢))? I get LENGTH ERROR

⍞←(1 1∘⍉,1↑(⍉,⊢))4 4⍴1 2 2 2 2 1 0 0 3 0 1 0 4 0 0 1

Dyalog APL

@Uriel ERROR: Use ⎕← for a full error report

Adám

@Zacharý Yes yes, ⍎ has all the features of a line of APL. You can run your entire program from ⍎. Indeed, when a workspace is loaded, APL automatically does ⍎⎕LX to bootstrap your application.

This is what causes the greeting message when you load a workspace like dfns.

Erik the Outgolfer

those flags from over russian SO are tiring me...

Adám

@Uriel 1↑ returns a 1-row matrix, not a vector.

Erik the Outgolfer

7:39 PM

anyways

@Adám

⎕←⎕LX

Dyalog APL

@EriktheOutgolfer

Erik the Outgolfer

from RIDE

Dyalog APL/S-64 Version 16.0.30863
Unicode Edition
Wed Dec 20 21:40:08 2017
      ⎕LX

looks like ⎕LX is emptied out after printing the greeting?

Adám

@EriktheOutgolfer It is empty in a clear workspace.

The ⎕LX of dfns.

Erik the Outgolfer

@Adám but how do you explain the above? does it have a self-emptying statement in it?

Adám

@EriktheOutgolfer No, you just didn't load a workspace that had ⎕LX ≢ ''

dzaima

7:43 PM

@EriktheOutgolfer I'm guessing that message is some built-in, separate from ⎕LX

RosLuP

⎕←DISPLAY '1234567', 9,3

Dyalog APL

@RosLuP

Rebuilding user command cache... done
Was OFF -trains=box -fns=off
⍎VALUE ERROR
 __field_initialize_result_←(⎕NS ⍬).⍎'⎕CY''salt''⋄⎕SE.UCMD''box on -fns=on -trains=tree''⊣enableSALT' ⋄ ⎕←DISPLAY'1234567',9,3
                                                                                                         ∧

Real time: 1.091 s
User time: 1.015 s
Sys. time: 0.042 s
CPU share: 96.92 %
Exit code: 0

Adám

@dzaima @EriktheOutgolfer Oh, that's what you mean. That banner is always printed when not in scripting or runtime mode.

RosLuP

⎕←⎕FMT '1234' , 9

Dyalog APL

@RosLuP
1234 9

Adám

7:44 PM

@RosLuP You can't use the DISPLAY function if you have not defined it or copied it from somewhere else.

Dyadic ⍎ is exactly like the monadic, but executes the expression in the namespace named in the left argument.

⎕←0 0⍴a←'base' ⋄ ns←⎕NS⍬ ⋄ ns.a←'sub' ⋄ ⍎'a' ⋄ 'ns'⍎'a'

Dyalog APL

@Adám
base

Adám

⎕←0 0⍴a←'base' ⋄ ns←⎕NS⍬ ⋄ ns.a←'sub' ⋄ ⎕←⍎'a' ⋄ ⎕←'ns'⍎'a'

Dyalog APL

@Adám
base
sub

Adám

So here I first set a to 'base' in # (the root namespace), then created the empty namespace ns, populated it there, then evaluated a here (in #) and then in ns.

So monadic ⍎ is the same as dyadic ⍎ but with the default left argument of ⎕THIS (this current namespace).

Nowadays, we usually "dot into" namespaces to evaluate there:

⎕←0 0⍴a←'base' ⋄ ns←⎕NS⍬ ⋄ ns.a←'sub' ⋄ ⎕←⍎'a' ⋄ ⎕←ns.⍎'a'

Dyalog APL

@Adám
base
sub

Adám

7:51 PM

Same as before, but here I used the "value" of ⍎ inside ns instead of ⍎'s value here.

RosLuP

⎕←]display '1234567', 9,3

Dyalog APL

@RosLuP

Rebuilding user command cache... done
Was OFF -trains=box -fns=off
⍎VALUE ERROR
 __field_initialize_result_←(⎕NS ⍬).⍎'⎕CY''salt''⋄⎕SE.UCMD''box on -fns=on -trains=tree''⊣enableSALT' ⋄ ⎕←]display'1234567',9,3
                                                                                                          ∧

Real time: 0.976 s
User time: 0.911 s
Sys. time: 0.033 s
CPU share: 96.70 %
Exit code: 0

Adám

Usually it doesn't matter which "definition" of primitives you pick up, if they have an implicit argument, then it does.

Erik the Outgolfer

@Adám w...oah?

what special syntax is that

Adám

@RosLuP You can't call user commands from within code (which is what the chat bot uses).

RosLuP

7:52 PM

]display '1234567', 9,676

Adám

@RosLuP And no, Stack Exchange chat isn't an APL interpreter. There's just a bot here which looks for incoming messages beginning with ⎕← or ⍞←.

@RosLuP Here you go! However, I would recommend getting a full desktop APL installed.

@EriktheOutgolfer You mean the . syntax? That's OO like in C# and Java. But that'll be for another time.

Let's finish up by covering ⍕.

Erik the Outgolfer

@Adám I mean how ⍎ can get in there...

Adám

@EriktheOutgolfer It doesn't. You're using the ⍎ that's already in there.

Erik the Outgolfer

⎕←⍎←+

Dyalog APL

@EriktheOutgolfer

Rebuilding user command cache... done
Was OFF -trains=box -fns=off
⍎SYNTAX ERROR
 __field_initialize_result_←(⎕NS ⍬).⍎'⎕CY''salt''⋄⎕SE.UCMD''box on -fns=on -trains=tree''⊣enableSALT' ⋄ ⎕←⍎←+
                                                                                                         ∧

Real time: 1.047 s
User time: 0.990 s
Sys. time: 0.030 s
CPU share: 97.46 %
Exit code: 0

Adám

7:58 PM

⍕ is really quite simple. It returns a simple character vector or matrix which displays exactly as if its argument had been displayed:

⍞←1 2 3 4

Dyalog APL

@Adám 1 2 3 4

Adám

⍞←⍕1 2 3 4

Dyalog APL

@Adám 1 2 3 4

Adám

⍞←≢1 2 3 4

Dyalog APL

@Adám 4

Adám

7:59 PM

⍞←≢⍕1 2 3 4

Dyalog APL

@Adám 7

RosLuP

⎕← x←]display '1234567', 9,676

Dyalog APL

@RosLuP

Rebuilding user command cache... done
Was OFF -trains=box -fns=off
⍎VALUE ERROR
 __field_initialize_result_←(⎕NS ⍬).⍎'⎕CY''salt''⋄⎕SE.UCMD''box on -fns=on -trains=tree''⊣enableSALT' ⋄ ⎕←x←]display'1234567',9,676
                                                                                                            ∧

Real time: 1.035 s
User time: 0.966 s
Sys. time: 0.034 s
CPU share: 96.61 %
Exit code: 0

Adám

@RosLuP You still can't use user commands (those that begin with ]) here. Use the link to TIO that I gave you.

Erik the Outgolfer

@RosLuP on top of that, you can't assign variables to user commands

Zacharý

8:01 PM

⎕→((⎕NS⍬).⍎'⎕CY''salt''⋄enableSALT')']display ''1234567'', 9,3'

Adám

@RosLuP Or if you really want:

⎕←⎕SE.UCMD'display ''1234567'', 9,676'

Dyalog APL

@Adám
┌→────────────┐
│1234567 9 676│
└+────────────┘

Zacharý

⎕←((⎕NS⍬).⍎'⎕CY''salt''⋄enableSALT')']display ''1234567'', 9,3

Dyalog APL

@Zacharý
line(1,135) : error AC0607: unbalanced quotes detected "(⎕NS⍬).⍎'⎕CY''salt''⋄⎕SE.UCMD''box on -fns=on -trains=tree''⊣enableSALT'⋄⎕←((⎕NS⍬).⍎'⎕CY''salt''⋄enableSALT')']display ''1234567'', 9,3"
                                                                                                                                                                                               ^
Complete: 1 error.
DOMAIN ERROR: There were errors processing the script
 '#'⎕NS ⎕FIX'file:///home/runner/.bin.tio.dyalog'

Zacharý

⎕←((⎕NS⍬).⍎'⎕CY''salt''⋄enableSALT')']display ''1234567'', 9,3'

Dyalog APL

8:02 PM

@Zacharý
┌────────────────────────┬───────────────────────┐
│SALT is already enabled!│]display '1234567', 9,3│
└────────────────────────┴───────────────────────┘

Adám

@EriktheOutgolfer You mean capture the result of user commands? Yes you can, with x←⎕SE.UCMD or ]x←command

If you give ⍕ a left argument, it will display numeric values with that many decimals, rounding 5 up:

⍞←4⍕2÷3

Dyalog APL

@Adám  0.6667

Adám

⍞←4⍕1 2 3÷3

Dyalog APL

@Adám  0.3333 0.6667 1.0000

Adám

And if you give it two values as left argument, it will use the first as "field width" and the second as decimals:

⍞←20 4⍕1 2 3÷3

Dyalog APL

8:05 PM

@Adám               0.3333              0.6667              1.0000

Leaky Nun

in The Nineteenth Byte, 2 hours ago, by DJMcMayhem

CMC: (possibly to main later) A simple number, is a number whose only prime factors are 2 and/or 3. For example, 4, 8, 9, and 12 are all simple, but 10, 15, 17, and 21 are not. Given an integer n>=2, return the distance to the nearest simple number.

Adám

You can also use twice as many elements on the left as there are leaf cells on the right, and it will pair each two on the left to each one on the right:

⍞←10 4 20 0 15 1⍕1 2 3÷3

Dyalog APL

@Adám     0.3333                   1            1.0

Adám

@LeakyNun Wrong room?

@all I think that covers it. Any questions?

Erik the Outgolfer

well, that matter would take some time to get correctly, but no questions

Adám

8:08 PM

@EriktheOutgolfer Which matter?

Leaky Nun

@Adám no

Erik the Outgolfer

@Adám well, I get the same feeling as if I had to study subject matter for school exams

Adám

OK, this concludes the lesson, and our APL functions' marathon. Thank you all for participating.

@all Is there interest for continuing next year with more advanced subjects, like OO or other things?

Erik the Outgolfer

um, sure

H.PWiz

I'll always attend, but it wouldn't be the end of the world if these stopped happening.

dzaima

8:12 PM

I'd really like to know how to properly use APL :p

Erik the Outgolfer

@H.PWiz and I wish the same holds for everybody else ;p

Adám

Shall we preliminarily schedule Wednesday Jan 3rd or 10th?

Zacharý

3rd

Erik the Outgolfer

no opinion over here

Zacharý

@Adám For me, yes, especially for OOP.

Erik the Outgolfer

8:15 PM

@Adám or ⎕... stuff (both operators and functions)

dzaima

3rd, as soon as possible :p

RosLuP

thank you... I think ]display (or the functions print type and dimensions recursively) is a good command for know what really happen

Adám

@EriktheOutgolfer Ah, right, that may be a more generally useful subject.

@RosLuP In a normal APL session (not the chat bot!) you can turn ]display on for all results (i.e. so you don't have to insert ]display in front) by entering ]box on -style=max into the session.

@LeakyNun So you want an APL solution to that?

Leaky Nun

@Adám ya

Adám

OK, let's say the 3rd.

Erik the Outgolfer

8:18 PM

@LeakyNun challenging

Feeds

Adám has added an event to this room's schedule.

Adám

@EriktheOutgolfer Nah, you just need to use pco from dfns.

Erik the Outgolfer

@Adám it says to calculate the distance

Starts on Jan 3 '18 at 18:30 (in your timezone, that's 20:30 on Wednesday), lasts 90 minutes. This is a regular event, happening every 7 days.[forgets the "until..." part]

dzaima

@EriktheOutgolfer that contains an "in your timezone" thing? :O

Erik the Outgolfer

@dzaima well, without that part we'd have to schedule every week

dzaima

8:24 PM

@EriktheOutgolfer I usually just wait until it starts :p

Erik the Outgolfer

APl learning session

mmm APl is nice

dzaima

is there a more APLy way to stop a dfn from stopping upon a line which isn't variable assignment than prepending _←?

actually, why do dfns stop on a non-assignment line at all?

Adám

@LeakyNun Not golfed, but I believe {s⊃⍨(⊢⍳⌊/)|⍵-s←c/⍨∧/¨∊∘2 3¨3 pco¨c←¯7+⍵+⍳13} will do the trick.

@dzaima Yes, use the value in further computations. Dfns are intended for functional programming where there shouldn't be side effects, so if a result isn't used why did you compute it? (I know why, but that isn't functional programming.)

dzaima

@Adám ah, didn't know that dfns are only for functional programming

Adám

@dzaima E.g. {result⊣sideeffect} "uses" the result of sideeffect without assignment.

dzaima

8:35 PM

so how do I do tradfns?

Adám

@dzaima Well, you're free to use them as you see fit (a strength of APL) but some things are not well suited for dfns.

@dzaima Have you looked at Lesson 2?

@dzaima I think it is to discourage non-functional programming, but IMHO the user should be allowed to do what he wants with the tools we give him.

dzaima

@Adám oh, it's that simple

how would I nest tradfns though?

Adám

@dzaima You can't have a literal tradfn inside another, but you don't need to either, as they have dynamic scoping, so a tradfn can call its siblings.

@dzaima The only reason to define one tradfn inside another is if you need its actual code content to depend on something, in which case you can use ⎕FX to fix a character array into a function. This works for dfns too, btw.

dzaima

the thing is I have ~10 dfns that shouldn't be dfns and just cluttering the main workspace isn't nice

let me write an example

Adám

@dzaima Maybe use TIO to show me?

dzaima

8:44 PM

@Adám that's what I'm doing

here's an example of something alike of what I'm doing

Adám

@dzaima Firstly, you don't need the dummy 1s if the last line of the dfns have an assignment. The result of the assignment will be the result of the dfn.

dzaima

@Adám but then it screams errors

Adám

@dzaima Really?

dzaima

@Adám :o those newlines make a difference?

Adám

9:00 PM

@dzaima Yes, since the "last" statement was an assignment, the dfn continues, and the "current" and last statements are therefore empty and thus have no value. Then the dfn as a whole doesn't have a result value either.

dzaima

@Adám ah, makes sense

Adám

@dzaima Tradfn translation.

dzaima

@Adám ah, that's what I was looking for. Much nicer looking. Loses the nested functions being nested though

Adám

@dzaima Hybrid tradfn/dfn approach.

@dzaima You don't need them to be. Only dfns have lexical scoping (i.e. names refer to where they are defined).

dzaima

@Adám I'd really not like cluttering the main workspace with ~10 random helper functions though. But that behaviour of variable-half-scoping is interestingly nice

Adám

9:11 PM

@dzaima Oh, I've seen workspaces with thousands of functions! However, for production code you should keep your functions grouped in namespaces.

@dzaima … Say you have five main functions and each of them has a bunch of helper functions. They also have some general utility functions that they all use. I'd keep each main function in a namespace with its helpers, and keep the utilities in a separate namespace. This way there is no risk of name clashes between the helpers for each main.

dzaima

@Adám so how would my example code look with addToArr in some namespace?

Adám

@dzaima As a general utility or as a helper function specific to f?

dzaima

@Adám it's specific to f as f would have many other functions for manipulating arr

(in my actual code that arr is an "entity" array and there are functions that add an entity at (x; y), deleting the previous entity if there is one)

Adám

@dzaima Something like this.

… In fact, namespaces can "see" their siblings, so you don't even need to write ##. but it is clearer if you do.

dzaima

9:32 PM

@Adám how would I run that in the REPL?

Adám

@dzaima You open the editor on a namespace with )ed ⍟name.

dzaima

@Adám oh wow that even has a tree view of the methods :o

(I'm new to the whole different namespace thing in APL)

Adám

@dzaima Yes, and you can collapse structures in the editing pane too.

dzaima

@Adám mhm, noticed that too

Adám

@dzaima Use :Section for no-op structure.

dzaima

9:40 PM

@Adám :o

Adám

@dzaima These are scripted namespaces (which I prefer), but you can also create an unscripted namespace (i.e. it cannot be edited in the editor) with myns←⎕NS ⍬ and then populate it piece-by-piece, as myns.name←something or myns.⎕ED 'foo' or copy existing items into it with 'myns' ⎕NS ListOfThingsToCopy.

Uriel

@Zacharý @EriktheOutgolfer can you delete your comments on my answer?

Zacharý

Of course!

dzaima

for a moment, before errors were screaming at me, I thought I could move that section inside f. Even if just for aesthetics

Adám

@dzaima You can also create one giant namespace script which contains all the container namespaces.

Zacharý

9:47 PM

This is becoming ... N-Seption ... (NS for namespace)

Adám

@dzaima No, you can't have tradfns inside tradfns, but you can have :Sections inside tradfns so you can structure a monolithic program.

Zacharý

So, :Section is like a function within a function?

Adám

@Zacharý No, :Section is like a section within a function ;-)

Zacharý

Of course

dzaima

These tradfns are way less scary than I thought. Thanks for helping me :D

Zacharý

9:56 PM

Now, they can get confusing

dzaima

now the question is whether I want to port my strange non-functional dfns to tradfns

Adám

@dzaima Any time (except Sabbath and Jewish holidays).

@Zacharý I find them less confusing than dfns. But then again, I grew up on tradfns (dfns didn't exist yet).

Zacharý

I learned APL the other way around, dfns first, then tradfns (for a restricted-source problem, came in handy for the student competition)

Transcript for