The APL Orchard

« first day (443 days earlier) ← previous day next day → last day (2368 days later) »

caird coinheringaahing

1:59 PM

@Adám What does ^ do? Example

Adám

@cairdcoinheringaahing LCM

caird coinheringaahing

So Dyalog treats ∧ and ^ to be the same character?

Adám

@cairdcoinheringaahing Same function, not same character.

4 hours later…

J. Sallé

5:39 PM

Hey @Adám, how can I make a while-like structure in a Dfn? I tried using ⍺{⍵≢' ':doStuffTo⍵⋄what happens here is not important⋄call recursively with ⍺+1}⍵

Doesn't work though, it just exits after running once

Adám

@J.Sallé Either do⍣(~condition) or tail recursion.

@J.Sallé E.g. next higher multiple of 10:

⍞←{0=10|⍵:⍵ ⋄ ∇1+⍵}13

Dyalog APL

@Adám 20

Adám

⍞←1+⍣{0=10|⍺}13

Dyalog APL

@Adám 20

J. Sallé

@Adám ah, I see. I'll try this one

Actually I think I'll try the other one. This one is kinda confusing to do what I want

Adám

5:48 PM

@J.Sallé What's your code?

J. Sallé

@Adám 1{⍵≢(≢⍵)⍴' ':⎕←f←(⍺⊃⎕A)⎕R' '⊢⍵⋄(1+⍺)∇f}'TEST'

Purpose is to remove letters from the given string in alphabetical order

one at a time

Also it's still not gonna work as it should but I'm trying to go step by step

Adám

It doesn't match the CMC though, you should only remove one T the first time around, not all the Ts.

J. Sallé

@Adám that's why I said it's not gonna work as it should :p

I just wanted to try to do something with ⎕R/S to get a feel for it

Adám

@J.Sallé But the looping format is right.

J. Sallé

I'll fine tune it eventually

@Adám it doesn't loop though? At least it seems like it doesn't

Adám

5:55 PM

@J.Sallé Because your condition is reversed. It says: If ⍵ has non-spaces, terminate with the following result, else recurse.

⎕←1{⍵≡(≢⍵)⍴' ':⍵ ⋄ (1+⍺)∇ ⎕←(⍺⊃⎕A)⎕R' '⊢⍵}'TEST'

Dyalog APL

@Adám
TEST
TEST
TEST
TEST
T ST
T ST
T ST
T ST
T ST
T ST
T ST
T ST
T ST
T ST
T ST
T ST
T ST
T ST
T  T

J. Sallé

Aaaaah I see

Adám

@J.Sallé "⍵ has non-spaces" can be written as ×≢⍵∩⎕A.

J. Sallé

@Adám Okay, thanks! What's with the × there though?

Adám

@J.Sallé Only 1 is truthy in APL.

J. Sallé

6:02 PM

@Adám Ah, that's a doesn't match, not a tally

I get it now

⍞←1{×≢⍵∩⎕A:⍵⋄(1+⍺)∇⎕←(⍺⊃⎕A)⎕R' '⊢⍵}'TEST'

Dyalog APL

@J.Sallé TEST

J. Sallé

Doesn't seem to work though?

Adám

@J.Sallé ? No, it is a tally. The sign of the length. If the length of the collection of letters is positive, we have letters, but if the length of the collection of letters is zero, then we don't.

@J.Sallé Now you have reversed condition again.

J. Sallé

I think I get it

Okay I get it

Adám

@J.Sallé Also, you need ⎕← for multi-line output.

⎕←1{×≢⍵∩⎕A:(1+⍺)∇⎕←(⍺⊃⎕A)⎕R' '⊢⍵⋄⍵}'TEST'

Dyalog APL

6:05 PM

@Adám
TEST
TEST
TEST
TEST
T ST
T ST
T ST
T ST
T ST
T ST
T ST
T ST
T ST
T ST
T ST
T ST
T ST
T ST
T  T

J. Sallé

@Adám also I was reading through the ⎕R/S lesson transcript but I couldn't find anything about this: can I ⎕R just the first match?

Adám

@J.Sallé Only if you can specify that in the regex.

@J.Sallé I don't think regex is a good solution in this case anyway, as you only need to replace a single character each time.

J. Sallé

@Adám yeah, I'm starting to think the same

I'll use 'find' instead, I think

Adám

@J.Sallé The letter you need to replace is (⊢⍳⌊/)⎕A⍳⍵. Even shorter: ⊃⍋⎕A⍳⍵. Even shorter: ⊃⎕A⍋⍵.

J. Sallé

@Adám that's helpful already :D

Adám

6:14 PM

@J.Sallé Which primitive do you think you can use to replace a character at a specific position?

J. Sallé

@Adám I was thinking about using @ but I don't think that replaces?

Adám

@J.Sallé It sure does.

J. Sallé

Hm, I must be using it wrong then

I'll keep trying

Adám

⍞←'_'@3⊢'HELLO'

Dyalog APL

@Adám HE_LO

Adám

6:17 PM

@J.Sallé ^

J. Sallé

⍞←' '@(⊃⎕A⍋⊢)'TEST'

Dyalog APL

@J.Sallé RANK ERROR

J. Sallé

@Adám What am I doing wrong?

Adám

@J.Sallé No wait, that is a fn.

J. Sallé

' '@(⊃⎕A⍋⊢)⊢'TEST' also doesn't work >.>

Yeah that's what I thought, I can't use (⊃⎕A⍋⊢) with @ can I?

Adám

6:19 PM

@J.Sallé If ⍵⍵ is a fn (and thus doesn't need separation) it needs to return a Boolean.

⍞←{' '@(⊃⎕A⍋⍵)⊢⍵}'TEST'

Dyalog APL

@Adám T ST

J. Sallé

@Adám I was sure I'd tried that

Adám

⍞←' '@(⍳∘≢=∘⊃⎕A⍋⊢)'TEST'

J. Sallé

but I used a space instead of ⊢

Dyalog APL

@Adám T ST

J. Sallé

6:22 PM

⎕←1{×≢⍵∩⎕A:⍺∇⎕←' '@(⊃⎕A⍋⍵)⊢⍵⋄⍵}'TEST'

Dyalog APL

@J.Sallé
T ST
T  T
   T

J. Sallé

Seems to have worked

@Adám can I do the same as this for a lexical replacement? (non-alphabetic characters first, then capital letters then small letters?)

Idk if grade-up can do that

Adám

@J.Sallé Sure, just use ' '~⍨⎕UCS⍳256 as alphabet.

Or use monadic ⍋ but replace all spaces with a higher char.

Or if it is allowed to sort lowercase before upper, use ⎕AV~' '

@J.Sallé I've got to go now too. Sunset is coming…

J. Sallé

@Adám no problem, thanks a lot!

I'll try to use one of those

« first day (443 days earlier) ← previous day next day → last day (2368 days later) »

all rooms

Transcript for

Apr12

Apr '1813

Apr16

apl.chat ― Learn, teach, ask, code, golf, & discuss usage. See ...

apl array-manipulation j tips

join this room
about this room

00:00

06:00

12:00

18:00

all times are UTC